# Copyright (c) 2021 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
import("//build/ohos.gni")
import("//drivers/adapter/uhdf2/uhdf.gni")

ohos_shared_library("libcodec_client") {
  include_dirs = [
    "//drivers/adapter/uhdf2/include/hdi",
    "//drivers/peripheral/codec/interfaces/include/",
  ]
  sources = [
    "codec_proxy/codec_callback_proxy.c",
    "codec_proxy/codec_proxy.c",
    "codec_proxy/proxy_msgproc.c",
  ]

  deps = [
    "//drivers/adapter/uhdf2/hdi:libhdi",
    "//drivers/adapter/uhdf2/host:libhdf_host",
    "//drivers/adapter/uhdf2/ipc:libhdf_ipc_adapter",
    "//drivers/adapter/uhdf2/osal:libhdf_utils",
  ]

  if (is_standard_system) {
    external_deps = [ "hiviewdfx_hilog_native:libhilog" ]
  } else {
    external_deps = [ "hilog:libhilog" ]
  }

  subsystem_name = "hdf"
  part_name = "hdf"
}

group("codec_client") {
  deps = [ ":libcodec_client" ]
}

ohos_shared_library("libcodec_server") {
  include_dirs = [
    "//drivers/peripheral/codec/interfaces/include/",
    "//drivers/peripheral/codec/hdi_service/codec_proxy/",
  ]
  sources = [
    "codec_service_stub/codec_callback_service.c",
    "codec_service_stub/codec_callback_stub.c",
    "codec_service_stub/codec_host.c",
    "codec_service_stub/codec_stub.c",
    "codec_service_stub/stub_msgproc.c",
  ]
  CODEC_LIB_PATH =
      "//device/hisilicon/hardware/media/hal/codec/hi3516dv300/llvm/ext/libs"
  CODEC_LIB_REAL_PATH = rebase_path("$CODEC_LIB_PATH")
  ldflags = [ "-L$CODEC_LIB_REAL_PATH" ]
  ldflags += [ "-lcodec" ]

  deps = [
    "//drivers/adapter/uhdf2/hdi:libhdi",
    "//drivers/adapter/uhdf2/host:libhdf_host",
    "//drivers/adapter/uhdf2/ipc:libhdf_ipc_adapter",
    "//drivers/adapter/uhdf2/osal:libhdf_utils",
    "//drivers/peripheral/codec/hdi_service:codec_client",
  ]

  if (is_standard_system) {
    external_deps = [ "hiviewdfx_hilog_native:libhilog" ]
  } else {
    external_deps = [ "hilog:libhilog" ]
  }

  subsystem_name = "hdf"
  part_name = "hdf"
}

group("codec_service") {
  if (target_cpu == "arm") {
    deps = [ ":libcodec_server" ]
  }
}