# Copyright (c) 2021 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/appexecfwk/standard/appexecfwk.gni")

config("tools_fm_config") {
  include_dirs = [
    "${aafwk_path}/interfaces/innerkits/want/include",
    "${aafwk_path}/interfaces/innerkits/base/include",
    "${aafwk_path}/services/common/include",
    "${aafwk_path}/tools/aa/include",
    "${appexecfwk_path}/common/log/include",
    "${appexecfwk_path}/interfaces/innerkits/libeventhandler/include",
    "//foundation/distributedschedule/samgr/interfaces/innerkits/samgr_proxy/include",
    "//utils/native/base/include",
    "//utils/system/safwk/native/include",
    "include",
  ]
}

ohos_source_set("tools_fm_source_set") {
  sources = [
    "${aafwk_path}/tools/aa/src/shell_command.cpp",
    "src/fms_command.cpp",
    "src/main.cpp",
  ]

  defines = [
    "APP_LOG_TAG = \"FmsTool\"",
    "LOG_DOMAIN = 0xD001152",
  ]

  public_configs = [ ":tools_fm_config" ]

  cflags = []
  if (target_cpu == "arm") {
    cflags += [ "-DBINDER_IPC_32BIT" ]
  }

  deps = [
    "${aafwk_path}/interfaces/innerkits/want:want",
    "${appexecfwk_path}/common:libappexecfwk_common",
    "${appexecfwk_path}/interfaces/innerkits/appexecfwk_base:appexecfwk_base",
    "${appexecfwk_path}/interfaces/innerkits/appexecfwk_core:appexecfwk_core",
    "//foundation/distributedschedule/samgr/interfaces/innerkits/samgr_proxy:samgr_proxy",
    "//utils/native/base:utils",
  ]

  external_deps = [
    "hiviewdfx_hilog_native:libhilog",
    "ipc:ipc_core",
  ]
}

ohos_executable("fm") {
  deps = [ ":tools_fm_source_set" ]

  install_enable = true

  subsystem_name = "appexecfwk"
  part_name = "appexecfwk_standard"
}

group("tools_fm") {
  deps = [ ":fm" ]
}