# Copyright (c) 2021-2021 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#

group("plugin_file_source") {
  deps = [ ":histreamer_plugin_FileSource" ]
}

source_set("filesource") {
  sources = [ "file_source_plugin.cpp" ]
  public_deps = [
    "//foundation/multimedia/histreamer/engine/foundation:histreamer_foundation",
    "//foundation/multimedia/histreamer/engine/plugin:histreamer_plugin_intf",
    "//foundation/multimedia/histreamer/engine/utils:histreamer_utils",
  ]
  cflags = [
    "-fPIC",
    "-Wall",
  ]
  if (!defined(ohos_lite)) {
    configs -= [
      "//build/config/compiler:no_rtti",
      "//build/config/compiler:no_exceptions",
    ]
    cflags += [
      "-frtti",
      "-fexceptions",
    ]
  }
  cflags_cc = cflags
}

if (defined(ohos_lite)) {
  # lite
  import("//build/lite/config/component/lite_component.gni")
  lite_library("histreamer_plugin_FileSource") {
    if (ohos_kernel_type == "liteos_m") {
      target_type = "static_library"
    } else {
      target_type = "shared_library"
    }
    sources = []
    deps = [ ":filesource" ]
  }
} else {
  # standard
  import("//build/ohos.gni")
  ohos_shared_library("histreamer_plugin_FileSource") {
    deps = [ ":filesource" ]
    relative_install_dir = "media/histreamer_plugins"
    subsystem_name = "multimedia"
    part_name = "multimedia_histreamer"
  }
}