# Copyright (c) 2021-2022 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//arkcompiler/runtime_core/ark_config.gni")
import("//build/ohos.gni")

config("arkaot_public_config") {
  include_dirs = [
    "$target_gen_dir/generated",
    "$ark_root/compiler/aot",
    "$ark_root/compiler",
    get_label_info(
        "$ark_root/cross_values:cross_values_getters_generate(${default_toolchain})",
        "target_gen_dir"),
  ]
}

ark_gen_file("arkcompiler_options_h") {
  template_file = "$ark_root/templates/options/options.h.erb"
  data_file = "paoc.yaml"
  requires = [ "$ark_root/templates/common.rb" ]
  output_file = "$target_gen_dir/generated/paoc_options.h"
}

ohos_executable("ark_aot") {
  sources = [ "paoc.cpp" ]

  configs = [
    ":arkaot_public_config",
    "$ark_root:ark_config",
    "$ark_root/runtime:arkruntime_public_config",
    "$ark_root/libpandabase:arkbase_public_config",
    "$ark_root/libpandafile:arkfile_public_config",
    "$ark_root/compiler:arkcompiler_public_config",
    "$ark_root/compiler/aot/aot_builder:aotbuilder_public_config",
    "$ark_root/compiler/optimizer/code_generator:arkencoder_config",
    sdk_libc_secshared_config,
  ]

  deps = [
    ":arkcompiler_options_h",
    "$ark_root/compiler:libarkcompiler",
    "$ark_root/compiler/aot:libarkaotmanager",
    "$ark_root/compiler/aot/aot_builder:aotbuilder",
    "$ark_root/compiler/optimizer/code_generator:libarkencoder",
    "$ark_root/cross_values:cross_values_getters_generate(${default_toolchain})",
    "$ark_root/libpandabase:libarkbase",
    "$ark_root/libpandafile:libarkfile",
    "$ark_root/runtime:libarkruntime",
  ]

  install_enable = true
  subsystem_name = "ark_aot"
}