• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1gst_net_sources = files(
2  'gstnetaddressmeta.c',
3  'gstnetclientclock.c',
4  'gstnetcontrolmessagemeta.c',
5  'gstnettimepacket.c',
6  'gstnettimeprovider.c',
7  'gstptpclock.c',
8  'gstntppacket.c',
9  'gstnetutils.c',
10)
11
12gst_net_headers = files(
13 'gstnet.h',
14 'gstnetaddressmeta.h',
15 'gstnetclientclock.h',
16 'gstnetcontrolmessagemeta.h',
17 'gstnettimepacket.h',
18 'gstnettimeprovider.h',
19 'gstnetutils.h',
20 'gstptpclock.h',
21 'net-prelude.h',
22 'net.h',
23)
24install_headers(gst_net_headers, subdir : 'gstreamer-1.0/gst/net/')
25
26gst_net_gen_sources = []
27gst_net = library('gstnet-@0@'.format(apiversion),
28  gst_net_sources,
29  c_args : gst_c_args + ['-DBUILDING_GST_NET', '-DG_LOG_DOMAIN="GStreamer-Net"'],
30  include_directories : [configinc, libsinc],
31  version : libversion,
32  soversion : soversion,
33  darwin_versions : osxversion,
34  install : true,
35  dependencies : [gio_dep, gst_base_dep],
36)
37
38library_def = {'lib': gst_net}
39pkg_name = 'gstreamer-net-1.0'
40pkgconfig.generate(gst_net,
41  libraries : [libgst],
42  variables : pkgconfig_variables,
43  subdirs : pkgconfig_subdirs,
44  name : pkg_name,
45  description : 'Network-enabled GStreamer plug-ins and clocking',
46)
47
48if build_gir
49  gst_gir_extra_args = gir_init_section + [ '--c-include=gst/net/net.h' ]
50  gir = {
51    'sources' : gst_net_sources + gst_net_headers,
52    'namespace' : 'GstNet',
53    'nsversion' : apiversion,
54    'identifier_prefix' : 'Gst',
55    'symbol_prefix' : 'gst',
56    'export_packages' : pkg_name,
57    'dependencies' : [gst_base_dep],
58    'include_directories' : [configinc, libsinc],
59    'includes' : ['GLib-2.0', 'GObject-2.0', 'GModule-2.0', 'Gio-2.0', 'Gst-1.0'],
60    'install' : true,
61    'extra_args' : gst_gir_extra_args,
62  }
63  library_def += {'gir': [gir]}
64  if not static_build
65    gst_net_gir = gnome.generate_gir(gst_net, kwargs: gir)
66    gst_net_gen_sources += [gst_net_gir]
67  endif
68endif
69libraries += [[pkg_name, library_def]]
70
71gst_net_dep = declare_dependency(link_with : gst_net,
72  include_directories : [libsinc],
73  sources: gst_net_gen_sources,
74  dependencies : [gst_base_dep])
75
76meson.override_dependency(pkg_name, gst_net_dep)
77