# Copyright (c) 2021-2022 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

declare_args() {
  drivers_peripheral_light_feature_model = false
}

if (defined(ohos_lite)) {
  import("//build/lite/config/component/lite_component.gni")
  import("//build/lite/config/test.gni")

  lite_component("hdf_test_light") {
    # add hdf subsystem unittest
    if (ohos_build_type == "debug") {
      if (ohos_kernel_type == "linux" && board_name == "hispark_taurus") {
        deps = [ "unittest:hdf_peripheral_test_light" ]
      } else if (ohos_kernel_type == "liteos_a" &&
                 board_name == "hispark_taurus") {
        deps = [ "unittest:hdf_peripheral_test_light" ]
      }
    }
    features = []
  }
} else {
  import("//build/ohos.gni")

  group("hdf_test_light") {
    testonly = true
    deps = [ "unittest/hdi:hdf_unittest_hdi_light_common" ]
    if (drivers_peripheral_light_feature_model) {
      deps += [
        # "benchmarktest:hdf_light_benchmark_test",
        "fuzztest/light_fuzzer:hdf_fuzztest_light",
        "unittest:hdf_unittest_light",
      ]
    }

    HDI_LIGHT_UNITTEST_PATH =
        rebase_path("//device/soc/${device_company}/common/hal/light/test")
    cmd = "if [ -f ${HDI_LIGHT_UNITTEST_PATH}/BUILD.gn ]; then echo true; else echo false; fi"
    HAVE_LIGHT_UNITTEST =
        exec_script("//build/lite/run_shell_cmd.py", [ cmd ], "value")

    if (HAVE_LIGHT_UNITTEST) {
      deps += [ "${HDI_LIGHT_UNITTEST_PATH}:light_hdi_unittest" ]
    } else {
      deps += [ "unittest/hdi:hdf_unittest_hdi_light" ]
    }
  }
}