# Copyright (c) 2021 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//base/hiviewdfx/faultloggerd/faultloggerd.gni")

if (defined(ohos_lite)) {
  import("//build/lite/config/component/lite_component.gni")
  import("//build/lite/config/test.gni")

  if (ohos_build_type == "debug") {
    unittest("test_processdump") {
      output_extension = "bin"
      output_dir = "$root_out_dir/test/unittest/faultloggerd"

      include_dirs = [
        "include/",
        "mock/",
        "//commonlibrary/c_utils/base/include",
        "$faultloggerd_path/common",
        "$faultloggerd_path/tools/process_dump/test/mock/include/",
        "$faultloggerd_path/tools/process_dump",
        "$faultloggerd_path/utils",
        "//third_party/libunwind/include/",
        "//third_party/googletest/googlemock/include",
        "$hilog_lite_include_path",
      ]

      sources = [
        "//base/hiviewdfx/faultloggerd/utils/directory_ex.cpp",
        "src/dfx_base_test.cpp",
        "src/dfx_maps_test.cpp",
        "src/dfx_processdump_test.cpp",
        "src/multithread_constructor.c",
        "src/process_dfx_test.cpp",
        "src/process_dump_test.cpp",
        "src/process_frames_test.cpp",
      ]

      deps = [
        "$faultloggerd_path/common/util:dfx_cutil",
        "$faultloggerd_path/tools/process_dump:process_info_src",
        "//base/hiviewdfx/hilog_lite/frameworks/featured:hilog_shared",
        "//third_party/libunwind:libunwind",
      ]
    }
  }

  group("unittest") {
    deps = [ ":test_processdump" ]
  }
} else {
  import("//build/config/features.gni")
  import("//build/test.gni")

  config("module_private_config") {
    visibility = [ ":*" ]

    include_dirs = [
      "include/",
      "mock/",
      "//commonlibrary/c_utils/base/include",
      "$faultloggerd_path/common",
      "$faultloggerd_path/tools/process_dump/test/mock/include/",
      "$faultloggerd_path/tools/process_dump",
      "//third_party/libunwind/include/",
    ]
  }

  module_output_path = "faultloggerd/process_dump"

  ohos_unittest("test_processdump") {
    module_out_path = module_output_path
    sources = [
      "src/dfx_base_test.cpp",
      "src/dfx_maps_test.cpp",
      "src/dfx_processdump_test.cpp",
      "src/multithread_constructor.c",
      "src/process_dfx_test.cpp",
      "src/process_dump_test.cpp",
      "src/process_frames_test.cpp",
    ]

    configs = [ ":module_private_config" ]

    defines = [ "UNITTEST" ]

    deps = [
      "$faultloggerd_path/common/util:dfx_cutil",
      "$faultloggerd_path/tools/process_dump:process_info_src",
      "//third_party/googletest:gmock_main",
      "//third_party/googletest:gtest_main",
      "//third_party/libunwind:libunwind",
    ]
    external_deps = [ "c_utils:utils" ]
  }

  group("unittest") {
    testonly = true
    deps = [ ":test_processdump" ]
  }
}