# Copyright (c) 2021-2021 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#
import("//foundation/multimedia/histreamer/config.gni")
group("plugin_file_source") {
  deps = [ ":histreamer_plugin_FileSource" ]
}

group("plugin_file_fd_source") {
  deps = [ ":histreamer_plugin_FileFdSource" ]
}

source_set("filesource") {
  sources = [ "file_source_plugin.cpp" ]
  public_deps = [
    "//foundation/multimedia/histreamer/engine/foundation:histreamer_foundation",
    "//foundation/multimedia/histreamer/engine/plugin:histreamer_plugin_intf",
  ]
  public_configs = [ "//foundation/multimedia/histreamer:histreamer_presets" ]
}

source_set("filefdsource") {
  sources = [ "file_fd_source_plugin.cpp" ]
  public_deps = [
    "//foundation/multimedia/histreamer/engine/foundation:histreamer_foundation",
    "//foundation/multimedia/histreamer/engine/plugin:histreamer_plugin_intf",
  ]
  public_configs = [ "//foundation/multimedia/histreamer:histreamer_presets" ]
}

if (hst_is_lite_sys) {
  # lite
  import("//build/lite/config/component/lite_component.gni")
  lite_library("histreamer_plugin_FileSource") {
    if (ohos_kernel_type == "liteos_m") {
      target_type = "static_library"
    } else {
      target_type = "shared_library"
    }
    sources = []
    deps = [ ":filesource" ]
  }
  lite_library("histreamer_plugin_FileFdSource") {
    if (ohos_kernel_type == "liteos_m") {
      target_type = "static_library"
    } else {
      target_type = "shared_library"
    }
    sources = []
    deps = [ ":filefdsource" ]
  }
} else {
  # standard
  import("//build/ohos.gni")
  ohos_shared_library("histreamer_plugin_FileSource") {
    sanitize = {
      cfi = true
      debug = false
    }
    deps = [ ":filesource" ]
    relative_install_dir = "media/histreamer_plugins"
    subsystem_name = "multimedia"
    part_name = "multimedia_histreamer"
  }
  ohos_shared_library("histreamer_plugin_FileFdSource") {
    sanitize = {
      cfi = true
      debug = false
    }
    deps = [ ":filefdsource" ]
    relative_install_dir = "media/histreamer_plugins"
    subsystem_name = "multimedia"
    part_name = "multimedia_histreamer"
  }
}