# Copyright (C) 2022-2023 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//base/location/config.gni")
import("//build/ohos.gni")

if (location_feature_with_gnss) {
  ohos_shared_library("lbsservice_gnss") {
    sources = [
      "$LOCATION_GNSS_ROOT/source/agnss_event_callback.cpp",
      "$LOCATION_GNSS_ROOT/source/gnss_ability.cpp",
      "$LOCATION_GNSS_ROOT/source/gnss_ability_skeleton.cpp",
      "$LOCATION_GNSS_ROOT/source/gnss_event_callback.cpp",
      "$LOCATION_LOCATOR_ROOT/source/subability_common.cpp",
      "$LOCATION_LOCATOR_ROOT/source/work_record.cpp",
    ]

    include_dirs = [
      "$LOCATION_ROOT_DIR/interfaces/inner_api/include",
      "$LOCATION_GNSS_ROOT/include",
      "$LOCATION_LOCATOR_ROOT/include",
    ]

    deps = [
      "$LOCATION_ROOT_DIR/frameworks/location_common/common:lbsservice_common",
    ]

    external_deps = [
      "access_token:libaccesstoken_sdk",
      "c_utils:utils",
      "common_event_service:cesfwk_innerkits",
      "eventhandler:libeventhandler",
      "hdf_core:libhdi",
      "hdf_core:libpub_utils",
      "hilog:libhilog",
      "ipc:ipc_core",
      "safwk:system_ability_fwk",
      "samgr:samgr_proxy",
    ]

    defines = []

    if (telephony_core_service_enable) {
      external_deps += [ "core_service:tel_core_service_api" ]
      defines += [ "TEL_CORE_SERVICE_ENABLE" ]
    }

    if (telephony_cellular_data_enable) {
      external_deps += [ "cellular_data:tel_cellular_data_api" ]
      defines += [ "TEL_CELLULAR_DATA_ENABLE" ]
    }

    if (hdf_drivers_interface_location_agnss_enable) {
      external_deps +=
          [ "drivers_interface_location_agnss:liblocation_agnss_proxy_1.0" ]
      defines += [ "HDF_DRIVERS_INTERFACE_AGNSS_ENABLE" ]
    }

    if (location_feature_with_gnss &&
        hdf_drivers_interface_location_gnss_enable) {
      external_deps +=
          [ "drivers_interface_location_gnss:liblocation_gnss_proxy_1.0" ]
      defines += [ "FEATURE_GNSS_SUPPORT" ]
    }

    if (location_feature_with_passive) {
      defines += [ "FEATURE_PASSIVE_SUPPORT" ]
    }

    part_name = "location"
    subsystem_name = "location"
  }
} else {
  ohos_shared_library("lbsservice_gnss") {
    part_name = "location"
    subsystem_name = "location"
  }
}