# Copyright (C) 2021-2023 HiHope Open Source Organization .
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//device/soc/rockchip/rk3568/hardware/omx_il/rk_omx.gni")
import("//drivers/hdf_core/adapter/uhdf2/uhdf.gni")

ohos_shared_library("libomxvpu_dec") {
  sources = [
    "Rkvpu_OMX_Vdec.c",
    "Rkvpu_OMX_VdecControl.c",
    "library_register.c",
  ]
  include_dirs = [
    ".",
    "//device/soc/rockchip/rk3568/hardware/omx_il/osal",
    "//device/soc/rockchip/rk3568/hardware/omx_il/include/khronos",
    "//device/soc/rockchip/rk3568/hardware/omx_il/include/rockchip",
    "//device/soc/rockchip/rk3568/hardware/omx_il/component/common",
    "//device/soc/rockchip/rk3568/hardware/omx_il/core",
    "//device/hihope/rk3568/hardware/rga/include",
    "//device/soc/rockchip/rk3568/hardware/omx_il/include/librkvpu",
    "//device/soc/rockchip/rk3568/hardware/mpp/mpp/legacy",
    "//device/soc/rockchip/rk3568/hardware/mpp/include",
    "//device/soc/rockchip/rk3568/hardware/rga/include",
    "//drivers/peripheral/base",
    "//drivers/peripheral/codec/interfaces/include",
    "//drivers/peripheral/display/interfaces/include",
    "//third_party/libdrm/include/drm",
    "//third_party/openmax/api/1.1.2",
  ]
  defines = [ "AVS100" ]
  cflags = [
    "-Wno-unused-variable",
    "-Wno-implicit-function-declaration",
    "-Wno-switch",
  ]

  if (USE_DRM) {
    defines += [ "USE_DRM" ]
  }

  if (USE_AFBC) {
    defines += [ "SUPPORT_AFBC" ]
  }

  if (USE_GPU) {
    defines += [ "ROCKCHIP_GPU_LIB_ENABLE" ]
  }

  if (USE_RGA) {
    defines += [ "SUPPORT_RGA" ]
  }

  if (USE_HEVC_DEC) {
    defines += [ "SUPPORT_HEVC" ]
  }

  if (USE_VP9_DEC) {
    defines += [ "SUPPORT_VP9" ]
  }

  if (USE_AVS80) {
    defines += [ "AVS80" ]
  }
  defines += [ "OHOS_BUFFER_HANDLE" ]

  deps = [
    "//device/soc/rockchip/rk3568/hardware/omx_il/component/common:RkOMX_Basecomponent",
    "//device/soc/rockchip/rk3568/hardware/omx_il/component/common:libRkOMX_Resourcemanager",
    "//device/soc/rockchip/rk3568/hardware/omx_il/osal:RkOMX_OSAL",
    "//device/soc/rockchip/rk3568/hardware/rga:librga",
  ]
  external_deps = [
    "c_utils:utils",
    "hilog:libhilog",
  ]

  innerapi_tags = [ "passthrough_indirect" ]
  install_images = [ chipset_base_dir ]
  subsystem_name = "hdf"
  part_name = "rockchip_products"
}