# Copyright (c) 2022 Huawei Device Co., Ltd. All rights reserved.
#
# Redistribution and use in source and binary forms, with or without modification,
# are permitted provided that the following conditions are met:
#
# 1. Redistributions of source code must retain the above copyright notice, this list of
#    conditions and the following disclaimer.
#
# 2. Redistributions in binary form must reproduce the above copyright notice, this list
#    of conditions and the following disclaimer in the documentation and/or other materials
#    provided with the distribution.
#
# 3. Neither the name of the copyright holder nor the names of its contributors may be used
#    to endorse or promote products derived from this software without specific prior written
#    permission.
#
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
# THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
# PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR
# CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
# EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
# PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
# OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
# WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
# OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
# ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

import("//kernel/uniproton/uniproton.gni")

static_library("board_config") {
  sources = [
    "board.c",
    "dprintf.c",
  ]
  configs += [
    "lwip:lwip_config",
    "common:stm32_config",
    "driver:driver_config",
  ]
  if (defined(DRIVERS_HDF)) {
    configs += [ "//drivers/hdf_core/adapter/khdf/uniproton:hdf_config" ]
  }
}

group("board") {
  deps = [
    ":board_config",
    "common",
    "driver",
    "fs",
    "lwip",
  ]
}

config("public") {
  include_dirs = [
    ".",
    "//third_party/musl/porting/uniproton/kernel/include",
  ]
  include_dirs +=
      KERNEL_LWIP_INCLUDE_DIRS + [ "//third_party/lwip/src/include" ]
  ldflags = [
    "-Wl,-T" + rebase_path("rtos.ld"),
    "-Wl,-Llibs",
    "--specs=nosys.specs",
  ]

  if (defined(LOSCFG_DRIVERS_HDF_TESTS_ENABLE)) {
    include_dirs +=
        [ "//drivers/hdf_core/framework/core/common/include/manager" ]
  }
  product_cfg = read_file("${product_config_path}/config.json", "json")
  foreach(product_config, product_cfg.bin_list) {
    ldflags += [ "-Wl,--whole-archive" ]
    foreach(force_link_lib, product_config.force_link_libs) {
      ldflags += [ "-l${force_link_lib}" ]
    }
    ldflags += [ "-Wl,--no-whole-archive" ]
  }

  libs = [
    "nosys",
    "gcc",
  ]
}