# Copyright (c) 2022 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//arkcompiler/ets_frontend/ets_frontend_config.gni")
import("//arkcompiler/ets_runtime/js_runtime_config.gni")
import("../../../toolchain.gni")

print("root_out_dir=$root_out_dir")
print("root_build_dir=$root_build_dir")
print("root_gen_dir=$root_gen_dir")
print("default_toolchain=$default_toolchain")
print("current_toolchain=$current_toolchain")
print("host_toolchain=$host_toolchain")
print("current_os=$current_os,   current_cpu=$current_cpu")
print("host_os=$host_os,      host_cpu=$host_cpu")
print("target_os=$target_os,    target_cpu=$target_cpu")

print()

group("default") {
  if (host_os != "mac") {
    deps = [
      ":ets_frontend",
      ":ets_runtime",
      ":runtime_core",
      ":toolchain",
    ]
  }
}

group("unittest_packages") {
  testonly = true
  if (host_os != "mac") {
    deps = [ "$toolchain_root:ark_js_host_unittest" ]
  }
}

group("ets_runtime") {
  deps = [
    "$js_root:libark_jsruntime",
    "$js_root/ecmascript/js_vm:ark_js_vm",
    "$js_root/ecmascript/quick_fix:quick_fix",
  ]
  if ((target_os == "linux" && target_cpu == "x64") ||
      (target_cpu == "arm64" && target_os == "ohos")) {
    deps += [
      "$js_root/ecmascript/compiler:ark_aot_compiler",
      "$js_root/ecmascript/compiler:ark_stub_compiler",
    ]
  }
}

group("ets_frontend") {
  if ((target_os == "linux" && target_cpu == "x64") || target_os == "mingw") {
    deps = [
      "$ets_frontend_root/es2panda:es2panda",
      "$ets_frontend_root/merge_abc:merge_abc",
    ]
  }
}

group("runtime_core") {
  deps = [
    "$ark_root/assembler:ark_asm",
    "$ark_root/disassembler:ark_disasm",
  ]
}

group("toolchain") {
  if (target_cpu != "mipsel") {
    deps = [
      "$toolchain_root/inspector:ark_debugger",
      "$toolchain_root/inspector:connectserver_debugger",
      "$toolchain_root/tooling:libark_ecma_debugger",
    ]
  }
}