# Copyright (c) 2020 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/lite/config/component/lite_component.gni")
import("//build/lite/ndk/ndk.gni")
declare_args() {
  ohos_hiviewdfx_disable_privacy_feature = false
}

hilog_sources = [
  "hilog.cpp",
  "hiview_log.c",
]

config("hilog_config") {
  include_dirs = [
    "//base/hiviewdfx/hilog_lite/interfaces/native/innerkits/hilog",
    "//base/hiviewdfx/hilog_lite/interfaces/native/innerkits",
    "//third_party/bounds_checking_function/include",
  ]
  if (ohos_hiviewdfx_disable_privacy_feature) {
    defines = [ "DISABLE_HILOG_PRIVACY" ]
  }
  if (ohos_kernel_type != "liteos_m") {
    cflags = [
      "-Wall",
      "-fno-common",
      "-fno-strict-aliasing",
      "-O2",
    ]
  }
}

lite_library("hilog_static") {
  target_type = "static_library"
  sources = hilog_sources
  public_configs = [ ":hilog_config" ]
  public_deps = [ "//third_party/bounds_checking_function:libsec_static" ]
}

lite_library("hilog_shared") {
  target_type = "shared_library"
  sources = hilog_sources
  public_configs = [ ":hilog_config" ]
  public_deps = [ "//third_party/bounds_checking_function:libsec_shared" ]
}

ndk_lib("hilog_ndk") {
  lib_extension = ".so"
  deps = [ ":hilog_shared" ]
  head_files = [
    "//base/hiviewdfx/hilog_lite/interfaces/native/kits/hilog",
    "//third_party/bounds_checking_function/include",
  ]
}