# Copyright (c) 2022 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")

# sa lib
if (defined(ohos_lite)) {
  ohos_static_library("service_sa_static") {
    sources = [ "common/dslm_rpc_process.c" ]

    include_dirs = [
      "common",
      "../dslm",
      "../include",
      "../../common/include",
      "../../interfaces/inner_api/include",
    ]

    deps = [
      "../../baselib/utils:utils_static",
      "../common:service_common_obj",
      "../dslm:service_dslm_obj",
      "../msg:service_msg_obj",
      "//base/hiviewdfx/hilog_lite/frameworks/featured:hilog_shared",
      "//build/lite/config/component/cJSON:cjson_shared",
      "//foundation/systemabilitymgr/samgr_lite/samgr:samgr",
      "//third_party/bounds_checking_function:libsec_shared",
    ]

    configs = [ "../../common:common_configs" ]

    part_name = "device_security_level"
    subsystem_name = "security"
  }

  if (ohos_kernel_type == "liteos_a" || ohos_kernel_type == "linux") {
    ohos_executable("dslm_server") {
      sources = [
        "lite/dslm_ipc_process.c",
        "lite/dslm_service.c",
        "lite/dslm_service_feature.c",
        "lite/dslm_service_main.c",
      ]

      include_dirs = [
        "common",
        "../include",
        "../../baselib/utils/include",
        "../../interfaces/inner_api/include",
      ]

      deps = [
        ":service_sa_static",
        "../../oem_property/ohos/lite:dslm_ohos_cred_obj",
        "//base/hiviewdfx/hilog_lite/frameworks/featured:hilog_shared",
        "//build/lite/config/component/cJSON:cjson_shared",
        "//foundation/communication/ipc/interfaces/innerkits/c/ipc:ipc_single",
        "//foundation/systemabilitymgr/samgr_lite/samgr:samgr",
        "//third_party/bounds_checking_function:libsec_shared",
      ]
    }
  }
} else {
  ohos_static_library("service_sa_static") {
    sources = [
      "common/dslm_rpc_process.c",
      "standard/dslm_callback_proxy.cpp",
      "standard/dslm_ipc_process.cpp",
      "standard/dslm_service.cpp",
    ]

    include_dirs = [
      "common",
      "../dslm",
      "../include",
      "../../common/include",
      "../../interfaces/inner_api/include",
    ]

    deps = [
      "../../baselib/utils:utils_static",
      "../common:service_common_obj",
      "../dfx:dslm_extension_dfx",
      "../dslm:service_dslm_obj",
      "../msg:service_msg_obj",
    ]

    external_deps = [
      "c_utils:utils",
      "hilog:libhilog",
      "ipc:ipc_core",
      "safwk:system_ability_fwk",
      "samgr:samgr_proxy",
    ]

    configs = [ "../../common:common_configs" ]

    part_name = "device_security_level"
    subsystem_name = "security"
  }
}