# Copyright (c) 2023 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("../gn/config.gni")

config("myconfig") {
  cflags = [ "-std=c++17" ]
}

ohos_source_set("mock_rich") {
  cflags = [ "-std=c++17" ]

  include_dirs = [
    ".",
    "../util/",
    "../cli/",
    "../jsapp/rich",
    "../jsapp",
  ]
  include_dirs += os_include_dirs

  deps = [
    "../jsapp:jsapp_rich",
    "../util:util_rich",
    "//third_party/libjpeg-turbo:turbojpeg_static",
    "//third_party/libwebsockets:websockets_static",
  ]
  sources = [
    "KeyInput.cpp",
    "LanguageManager.cpp",
    "MouseInput.cpp",
    "MouseWheel.cpp",
    "SystemCapability.cpp",
    "VirtualMessage.cpp",
    "VirtualScreen.cpp",
    "rich/KeyInputImpl.cpp",
    "rich/LanguageManagerImpl.cpp",
    "rich/MouseInputImpl.cpp",
    "rich/MouseWheelImpl.cpp",
    "rich/VirtualMessageImpl.cpp",
    "rich/VirtualScreenImpl.cpp",
  ]

  include_dirs += [
    "./rich/",
    "//third_party/jsoncpp/include/json/",
  ]
  part_name = "previewer"
  subsystem_name = "ide"
}

ohos_source_set("mock_lite") {
  configs = [ ":myconfig" ]
  include_dirs = [
    ".",
    "../util/",
  ]

  deps = [
    "../util:util_lite",
    "//base/global/i18n_lite/interfaces/kits/js/builtin:nativeapi_locale_simulator",
    "//base/global/resource_management_lite/frameworks/resmgr_lite:global_resmgr_simulator",
    "//base/powermgr/powermgr_lite/interfaces/kits/battery/js/builtin:libnativeapi_battery_simulator",
    "//base/startup/init/simulator:sysparam_simulator",
    "//commonlibrary/utils_lite/js/builtin/simulator:ace_kit_common_simulator",
    "//commonlibrary/utils_lite/js/builtin/simulator:ace_kit_deviceinfo_simulator",
    "//commonlibrary/utils_lite/js/builtin/simulator:ace_kit_file_simulator",
    "//commonlibrary/utils_lite/js/builtin/simulator:ace_kit_kvstore_simulator",
    "//foundation/arkui/ace_engine_lite/frameworks/targets/simulator:ace_lite",
    "//third_party/libjpeg-turbo:turbojpeg_static",
    "//third_party/libwebsockets:websockets_static",
  ]

  sources = [
    "KeyInput.cpp",
    "LanguageManager.cpp",
    "MouseInput.cpp",
    "MouseWheel.cpp",
    "SystemCapability.cpp",
    "VirtualMessage.cpp",
    "VirtualScreen.cpp",
    "lite/AblityKit.cpp",
    "lite/AsyncWorkManager.cpp",
    "lite/BatteryModuleImpl.cpp",
    "lite/HalSysParam.cpp",
    "lite/JsAsyncWork.cpp",
    "lite/KeyInputImpl.cpp",
    "lite/LanguageManagerImpl.cpp",
    "lite/MouseInputImpl.cpp",
    "lite/MouseWheelImpl.cpp",
    "lite/NativeTimer.cpp",
    "lite/VirtualMessageImpl.cpp",
    "lite/VirtualScreenImpl.cpp",
  ]

  include_dirs += [
    "./lite/",
    "//foundation/arkui/ui_lite/interfaces/innerkits/dock/",
    "//third_party/jsoncpp/include/json/",
    "//foundation/arkui/ui_lite/interfaces/innerkits/",
    "//foundation/arkui/ui_lite/frameworks/",
    "//foundation/arkui/ui_lite/frameworks/dock/",
    "//foundation/arkui/ui_lite/interfaces/kits/",
    "//foundation/graphic/graphic_utils_lite/interfaces/kits/",
    "//foundation/graphic/graphic_utils_lite/interfaces/innerkits/",
  ]

  if (build_lite_full) {
    deps += [
      "//base/location/interfaces/kits/geo_lite/js/builtin:nativeapi_location_simulator",
      "//base/sensors/sensorjs_lite/miscdevice_lite/interfaces/js/builtin:nativeapi_miscdevice",
      "//base/sensors/sensorjs_lite/sensor_lite/interfaces/js/builtin:nativeapi_sensor",
      "//foundation/arkui/ui_ext_lite/tools/ide/brightness_lite/js/builtin:nativeapi_brightness_static",
    ]
    sources += [
      "lite/GeoLocation.cpp",
      "lite/SensorModuleImpl.cpp",
      "lite/VibratorModuleImpl.cpp",
      "lite/VirtualLocation.cpp",
    ]
    include_dirs += [ "//foundation/arkui/ui_ext_lite/tools/ide/brightness_lite/js/builtin/include/" ]
  }

  part_name = "previewer"
  subsystem_name = "ide"
}