# Copyright (c) 2021 Bestechnic (Shanghai) Co., Ltd. All rights reserved.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

declare_args() {
  bes_fs_test = true
  bes_histreamer_test = false
  bes_ui_test = false
  bes_ability_test = true
  bes_wifi_test = true
  bes_rpc_test = false
  bes_dsoftbus_test = false
}

static_library("example") {
  sources = [
    "app.cpp",
    "example.c",
  ]
  defines = []
  deps = [ "//base/hiviewdfx/hilog_lite/frameworks/featured:hilog_static" ]

  include_dirs = [ "//commonlibrary/utils_lite/include" ]

  if (bes_histreamer_test) {
    deps += [ "histreamer:histreamer_test" ]
    defines += [ "HISTREAMER_TEST" ]
  }

  if (bes_fs_test) {
    deps += [ "fs:fs_test" ]
    defines += [ "FS_TEST" ]
    include_dirs += [ "fs" ]
  }

  if (bes_ui_test) {
    deps += [ "ui:ui_test" ]
    defines += [ "UI_TEST" ]
    include_dirs += [ "ui" ]
  } else if (bes_ability_test) {
    deps += [ "ability:ability_test" ]
    defines += [ "ABILITY_TEST" ]
    include_dirs += [ "ability" ]
  }

  if (bes_wifi_test) {
    deps += [ "wifi:wifi_test" ]
    defines += [ "WIFI_TEST" ]
  }

  if (bes_rpc_test) {
    deps += [ "rpc:rpc_test" ]
    defines += [ "RPC_TEST" ]
  }

  if (bes_dsoftbus_test) {
    deps += [ "dsoftbus:dsoftbus_test" ]
    defines += [ "DSOFTBUS_TEST" ]
  }
}