# Copyright (c) 2022 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("../../os_account.gni")

config("account_iam_innnerkits_config") {
  visibility = [ ":*" ]

  cflags = []
  if (target_cpu == "arm") {
    cflags += [ "-DBINDER_IPC_32BIT" ]
  }

  cflags += [ "-pipe" ]
  cflags_cc = [
    "-Wdate-time",
    "-Wformat=2",
    "-Wfloat-equal",
    "-Wshadow",
  ]

  defines = [
    "ACCOUNT_LOG_TAG = \"AccountIAMFwk\"",
    "LOG_DOMAIN = 0xD001B00",
  ]
}

config("account_iam_innerkits_public_config") {
  visibility = [ ":*" ]

  include_dirs = [
    "${account_iam_interfaces_native_path}/include",
    "${common_path}/utils/include",
    "${innerkits_common}/include",
  ]
}

ohos_shared_library("account_iam_innerkits") {
  branch_protector_ret = "pac_ret"

  sanitize = {
    cfi = true
    cfi_cross_dso = true
    debug = false
  }

  sources = [
    "${account_iam_framework_path}/src/account_iam_callback_service.cpp",
    "${account_iam_framework_path}/src/account_iam_callback_stub.cpp",
    "${account_iam_framework_path}/src/account_iam_client.cpp",
    "${account_iam_framework_path}/src/account_iam_mgr_proxy.cpp",
  ]

  configs = [
    ":account_iam_innnerkits_config",
    "${account_coverage_config_path}:coverage_flags",
  ]

  public_configs = [ ":account_iam_innerkits_public_config" ]

  deps = [
    "${common_path}:libaccount_common",
    "${domain_account_framework_path}:domain_account_innerkits",
    "${innerkits_native_path}:libaccountkits",
    "${os_account_innerkits_native_path}:os_account_innerkits",
  ]

  external_deps = [
    "access_token:libaccesstoken_sdk",
    "c_utils:utils",
    "hilog:libhilog",
    "ipc:ipc_single",
    "samgr:samgr_proxy",
  ]

  if (ohos_indep_compiler_enable) {
    external_deps += [ "ability_base:want" ]
  }

  cflags_cc = []
  if (has_pin_auth_part) {
    cflags_cc += [ "-DHAS_PIN_AUTH_PART" ]
    external_deps += [ "pin_auth:pinauth_framework" ]
  }

  if (has_user_auth_part) {
    cflags_cc += [ "-DHAS_USER_AUTH_PART" ]
    external_deps += [ "user_auth_framework:userauth_client" ]
  }

  innerapi_tags = [ "platformsdk_indirect" ]
  subsystem_name = "account"
  part_name = "os_account"
}