# Copyright (c) 2021-2022 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/ability/ability_runtime/ability_runtime.gni")

config("napi_common_public_config") {
  include_dirs = [ "./" ]
}

ohos_shared_library("napi_common") {
  branch_protector_ret = "pac_ret"

  include_dirs = [ "${ability_runtime_napi_path}/featureAbility" ]

  public_configs = [
    ":napi_common_public_config",
    "${ability_runtime_native_path}/ability/native:ability_public_config",
    "${ability_runtime_innerkits_path}/runtime:runtime_public_config",
    "${ability_runtime_innerkits_path}/wantagent:wantagent_innerkits_public_config",
  ]

  sources = [
    "napi_common_configuration.cpp",
    "napi_common_execute_param.cpp",
    "napi_common_execute_result.cpp",
    "napi_common_start_options.cpp",
    "napi_common_util.cpp",
    "napi_common_want.cpp",
    "open_link/napi_common_open_link_options.cpp",
  ]

  deps = [
    "${ability_runtime_innerkits_path}/ability_manager:ability_manager",
    "${ability_runtime_innerkits_path}/ability_manager:ability_start_options",
    "${ability_runtime_innerkits_path}/ability_manager:process_options",
    "${ability_runtime_innerkits_path}/ability_manager:start_window_option",
    "${ability_runtime_innerkits_path}/app_manager:app_manager",
    "${ability_runtime_innerkits_path}/runtime:runtime",
  ]

  external_deps = [
    "ability_base:base",
    "ability_base:session_info",
    "ability_base:want",
    "access_token:libtokenid_sdk",
    "c_utils:utils",
    "common_event_service:cesfwk_innerkits",
    "eventhandler:libeventhandler",
    "hilog:libhilog",
    "ipc:ipc_core",
    "ipc:ipc_napi",
    "json:nlohmann_json_static",
    "libuv:uv",
    "napi:ace_napi",
    "samgr:samgr_proxy",
    "window_manager:window_animation_utils",
  ]

  public_external_deps = [
    "ability_base:configuration",
    "bundle_framework:appexecfwk_base",
    "bundle_framework:appexecfwk_core",
    "input:libmmi-client",
  ]

  if (ability_runtime_child_process) {
    sources += [ "napi_common_child_process_param.cpp" ]
  }

  if (ability_runtime_graphics) {
    defines = [
      "SUPPORT_GRAPHICS",
      "SUPPORT_SCREEN",
    ]
    public_external_deps += [
      "form_fwk:form_manager",
      "graphic_2d:EGL",
      "window_manager:libdm",
      "window_manager:libwm_lite",
    ]
  }

  if (ability_runtime_graphics &&
      ability_runtime_start_window_options_with_pixelmap) {
    defines += [ "START_WINDOW_OPTIONS_WITH_PIXELMAP" ]
    external_deps += [ "image_framework:image" ]
  }

  innerapi_tags = [ "platformsdk" ]
  subsystem_name = "ability"
  part_name = "ability_runtime"
}