• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1set(_harfbuzz_libdir "@libdir@")
2set(_harfbuzz_includedir "@includedir@")
3
4# Extract version information from libtool.
5set(_harfbuzz_version_info "@HB_LIBTOOL_VERSION_INFO@")
6string(REPLACE ":" ";" _harfbuzz_version_info "${_harfbuzz_version_info}")
7list(GET _harfbuzz_version_info 0
8  _harfbuzz_current)
9list(GET _harfbuzz_version_info 1
10  _harfbuzz_revision)
11list(GET _harfbuzz_version_info 2
12  _harfbuzz_age)
13unset(_harfbuzz_version_info)
14
15if (APPLE)
16  set(_harfbuzz_lib_suffix ".0${CMAKE_SHARED_LIBRARY_SUFFIX}")
17elseif (UNIX)
18  set(_harfbuzz_lib_suffix "${CMAKE_SHARED_LIBRARY_SUFFIX}.0.${_harfbuzz_current}.${_harfbuzz_revision}")
19else ()
20  # Unsupported.
21  set(harfbuzz_FOUND 0)
22endif ()
23
24# Add the libraries.
25add_library(harfbuzz::harfbuzz SHARED IMPORTED)
26set_target_properties(harfbuzz::harfbuzz PROPERTIES
27  INTERFACE_INCLUDE_DIRECTORIES "${_harfbuzz_includedir}/harfbuzz"
28  IMPORTED_LOCATION "${_harfbuzz_libdir}/libharfbuzz${_harfbuzz_lib_suffix}")
29
30add_library(harfbuzz::icu SHARED IMPORTED)
31set_target_properties(harfbuzz::icu PROPERTIES
32  INTERFACE_INCLUDE_DIRECTORIES "${_harfbuzz_includedir}/harfbuzz"
33  INTERFACE_LINK_LIBRARIES "harfbuzz::harfbuzz"
34  IMPORTED_LOCATION "${_harfbuzz_libdir}/libharfbuzz-icu${_harfbuzz_lib_suffix}")
35
36add_library(harfbuzz::subset SHARED IMPORTED)
37set_target_properties(harfbuzz::subset PROPERTIES
38  INTERFACE_INCLUDE_DIRECTORIES "${_harfbuzz_includedir}/harfbuzz"
39  INTERFACE_LINK_LIBRARIES "harfbuzz::harfbuzz"
40  IMPORTED_LOCATION "${_harfbuzz_libdir}/libharfbuzz-subset${_harfbuzz_lib_suffix}")
41
42# Only add the gobject library if it was built.
43set(_harfbuzz_have_gobject "@have_gobject@")
44if (_harfbuzz_have_gobject)
45  add_library(harfbuzz::gobject SHARED IMPORTED)
46  set_target_properties(harfbuzz::gobject PROPERTIES
47    INTERFACE_INCLUDE_DIRECTORIES "${_harfbuzz_includedir}/harfbuzz"
48    INTERFACE_LINK_LIBRARIES "harfbuzz::harfbuzz"
49    IMPORTED_LOCATION "${_harfbuzz_libdir}/libharfbuzz-gobject${_harfbuzz_lib_suffix}")
50endif ()
51
52# Clean out variables we used in our scope.
53unset(_harfbuzz_lib_suffix)
54unset(_harfbuzz_current)
55unset(_harfbuzz_revision)
56unset(_harfbuzz_age)
57unset(_harfbuzz_includedir)
58unset(_harfbuzz_libdir)
59