• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1#***************************************************************************
2#                                  _   _ ____  _
3#  Project                     ___| | | |  _ \| |
4#                             / __| | | | |_) | |
5#                            | (__| |_| |  _ <| |___
6#                             \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
13#
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
17#
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
20#
21# SPDX-License-Identifier: curl
22#
23###########################################################################
24# Find the mbedTLS library
25#
26# Input variables:
27#
28# - `MBEDTLS_INCLUDE_DIR`:   The mbedTLS include directory.
29# - `MBEDTLS_LIBRARY`:       Path to `mbedtls` library.
30# - `MBEDX509_LIBRARY`:      Path to `mbedx509` library.
31# - `MBEDCRYPTO_LIBRARY`:    Path to `mbedcrypto` library.
32#
33# Result variables:
34#
35# - `MBEDTLS_FOUND`:         System has mbedTLS.
36# - `MBEDTLS_INCLUDE_DIRS`:  The mbedTLS include directories.
37# - `MBEDTLS_LIBRARIES`:     The mbedTLS library names.
38# - `MBEDTLS_LIBRARY_DIRS`:  The mbedTLS library directories.
39# - `MBEDTLS_PC_REQUIRES`:   The mbedTLS pkg-config packages.
40# - `MBEDTLS_CFLAGS`:        Required compiler flags.
41# - `MBEDTLS_VERSION`:       Version of mbedTLS.
42
43if(DEFINED MBEDTLS_INCLUDE_DIRS AND NOT DEFINED MBEDTLS_INCLUDE_DIR)
44  message(WARNING "MBEDTLS_INCLUDE_DIRS is deprecated, use MBEDTLS_INCLUDE_DIR instead.")
45  set(MBEDTLS_INCLUDE_DIR "${MBEDTLS_INCLUDE_DIRS}")
46  unset(MBEDTLS_INCLUDE_DIRS)
47endif()
48
49set(MBEDTLS_PC_REQUIRES "mbedtls")
50
51if(CURL_USE_PKGCONFIG AND
52   NOT DEFINED MBEDTLS_INCLUDE_DIR AND
53   NOT DEFINED MBEDTLS_LIBRARY AND
54   NOT DEFINED MBEDX509_LIBRARY AND
55   NOT DEFINED MBEDCRYPTO_LIBRARY)
56  find_package(PkgConfig QUIET)
57  pkg_check_modules(MBEDTLS ${MBEDTLS_PC_REQUIRES})
58  pkg_check_modules(MBEDX509 "mbedx509")
59  pkg_check_modules(MBEDCRYPTO "mbedcrypto")
60endif()
61
62if(MBEDTLS_FOUND AND MBEDX509_FOUND AND MBEDCRYPTO_FOUND)
63  list(APPEND MBEDTLS_LIBRARIES ${MBEDX509_LIBRARIES} ${MBEDCRYPTO_LIBRARIES})
64  list(REVERSE MBEDTLS_LIBRARIES)
65  list(REMOVE_DUPLICATES MBEDTLS_LIBRARIES)
66  list(REVERSE MBEDTLS_LIBRARIES)
67  string(REPLACE ";" " " MBEDTLS_CFLAGS "${MBEDTLS_CFLAGS}")
68  message(STATUS "Found MbedTLS (via pkg-config): ${MBEDTLS_INCLUDE_DIRS} (found version \"${MBEDTLS_VERSION}\")")
69else()
70  set(MBEDTLS_PC_REQUIRES "")  # Depend on pkg-config only when found via pkg-config
71
72  find_path(MBEDTLS_INCLUDE_DIR NAMES "mbedtls/ssl.h")
73  find_library(MBEDTLS_LIBRARY NAMES "mbedtls" "libmbedtls")
74  find_library(MBEDX509_LIBRARY NAMES "mbedx509" "libmbedx509")
75  find_library(MBEDCRYPTO_LIBRARY NAMES "mbedcrypto" "libmbedcrypto")
76
77  unset(MBEDTLS_VERSION CACHE)
78  if(MBEDTLS_INCLUDE_DIR)
79    if(EXISTS "${MBEDTLS_INCLUDE_DIR}/mbedtls/build_info.h")  # 3.x
80      set(_version_header "${MBEDTLS_INCLUDE_DIR}/mbedtls/build_info.h")
81    elseif(EXISTS "${MBEDTLS_INCLUDE_DIR}/mbedtls/version.h")  # 2.x
82      set(_version_header "${MBEDTLS_INCLUDE_DIR}/mbedtls/version.h")
83    else()
84      unset(_version_header)
85    endif()
86    if(_version_header)
87      set(_version_regex "#[\t ]*define[\t ]+MBEDTLS_VERSION_STRING[\t ]+\"([0-9.]+)\"")
88      file(STRINGS "${_version_header}" _version_str REGEX "${_version_regex}")
89      string(REGEX REPLACE "${_version_regex}" "\\1" _version_str "${_version_str}")
90      set(MBEDTLS_VERSION "${_version_str}")
91      unset(_version_regex)
92      unset(_version_str)
93      unset(_version_header)
94    endif()
95  endif()
96
97  include(FindPackageHandleStandardArgs)
98  find_package_handle_standard_args(MbedTLS
99    REQUIRED_VARS
100      MBEDTLS_INCLUDE_DIR
101      MBEDTLS_LIBRARY
102      MBEDX509_LIBRARY
103      MBEDCRYPTO_LIBRARY
104    VERSION_VAR
105      MBEDTLS_VERSION
106  )
107
108  if(MBEDTLS_FOUND)
109    set(MBEDTLS_INCLUDE_DIRS ${MBEDTLS_INCLUDE_DIR})
110    set(MBEDTLS_LIBRARIES    ${MBEDTLS_LIBRARY} ${MBEDX509_LIBRARY} ${MBEDCRYPTO_LIBRARY})
111  endif()
112
113  mark_as_advanced(MBEDTLS_INCLUDE_DIR MBEDTLS_LIBRARY MBEDX509_LIBRARY MBEDCRYPTO_LIBRARY)
114endif()
115