• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1directsoundsrc_sources = [
2  'gstdirectsoundsrc.c',
3  'gstdirectsounddevice.c',
4  'gstdirectsoundplugin.c',
5]
6
7directsoundsrc_device_flags = [
8  '-DGstDirectSoundDeviceProvider=GstDirectSoundSrcDeviceProvider',
9  '-DGstDirectSoundDeviceProviderClass=GstDirectSoundSrcDeviceProviderClass',
10  '-DGstDirectSoundDevice=GstDirectSoundSrcDevice',
11  '-DGstDirectSoundDeviceClass=GstDirectSoundSrcDeviceClass',
12  '-DGST_DIRECTSOUND_SRC_DEVICE_PROVIDER=1'
13]
14
15if host_system != 'windows' or get_option('directsound').disabled()
16  subdir_done()
17endif
18
19dsound_dep = cc.find_library('dsound', required : get_option('directsound'))
20winmm_dep = cc.find_library('winmm', required : get_option('directsound'))
21ole32_dep = cc.find_library('ole32', required : get_option('directsound'))
22have_dsound_h = cc.has_header('dsound.h')
23if not have_dsound_h and get_option('directsound').enabled()
24  error('directsound plugin enabled but dsound.h not found')
25endif
26
27if dsound_dep.found() and winmm_dep.found() and ole32_dep.found() and have_dsound_h
28  gstdirectsoundsrc = library('gstdirectsoundsrc',
29    directsoundsrc_sources,
30    c_args : gst_plugins_bad_args + directsoundsrc_device_flags,
31    include_directories : [configinc],
32    dependencies : [gstaudio_dep, dsound_dep, winmm_dep, ole32_dep],
33    install : true,
34    install_dir : plugins_install_dir)
35  pkgconfig.generate(gstdirectsoundsrc, install_dir : plugins_pkgconfig_install_dir)
36endif
37