• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1# Copyright 2017 gRPC authors.
2#
3# Licensed under the Apache License, Version 2.0 (the "License");
4# you may not use this file except in compliance with the License.
5# You may obtain a copy of the License at
6#
7#     http://www.apache.org/licenses/LICENSE-2.0
8#
9# Unless required by applicable law or agreed to in writing, software
10# distributed under the License is distributed on an "AS IS" BASIS,
11# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
12# See the License for the specific language governing permissions and
13# limitations under the License.
14
15# The CMakeLists.txt for re2 doesn't propagate include directories
16# transitively so `_gRPC_RE2_INCLUDE_DIR` should be set for gRPC
17# to find header files.
18
19if(gRPC_RE2_PROVIDER STREQUAL "module")
20  if(NOT RE2_ROOT_DIR)
21    set(RE2_ROOT_DIR ${CMAKE_CURRENT_SOURCE_DIR}/third_party/re2)
22  endif()
23  if(EXISTS "${RE2_ROOT_DIR}/CMakeLists.txt")
24    include_directories("${RE2_ROOT_DIR}")
25    add_subdirectory(${RE2_ROOT_DIR} third_party/re2)
26
27    if(TARGET re2)
28      set(_gRPC_RE2_LIBRARIES re2)
29      set(_gRPC_RE2_INCLUDE_DIR "${RE2_ROOT_DIR}" "${CMAKE_CURRENT_BINARY_DIR}/third_party/re2")
30      if(gRPC_INSTALL AND _gRPC_INSTALL_SUPPORTED_FROM_MODULE)
31        install(TARGETS re2 EXPORT gRPCTargets
32          RUNTIME DESTINATION ${gRPC_INSTALL_BINDIR}
33          LIBRARY DESTINATION ${gRPC_INSTALL_LIBDIR}
34          ARCHIVE DESTINATION ${gRPC_INSTALL_LIBDIR})
35      endif()
36    endif()
37  else()
38    message(WARNING "gRPC_RE2_PROVIDER is \"module\" but RE2_ROOT_DIR(${RE2_ROOT_DIR}) is wrong")
39  endif()
40  if(gRPC_INSTALL AND NOT _gRPC_INSTALL_SUPPORTED_FROM_MODULE)
41    message(WARNING "gRPC_INSTALL will be forced to FALSE because gRPC_RE2_PROVIDER is \"module\"  and CMake version (${CMAKE_VERSION}) is less than 3.13.")
42    set(gRPC_INSTALL FALSE)
43  endif()
44elseif(gRPC_RE2_PROVIDER STREQUAL "package")
45  find_package(re2 REQUIRED CONFIG)
46
47  if(TARGET re2::re2)
48    set(_gRPC_RE2_LIBRARIES re2::re2)
49  else()
50    set(_gRPC_RE2_LIBRARIES ${RE2_LIBRARIES})
51  endif()
52  set(_gRPC_RE2_INCLUDE_DIR ${RE2_INCLUDE_DIRS})
53  set(_gRPC_FIND_RE2 "if(NOT re2_FOUND)\n  find_package(re2)\nendif()")
54endif()
55