• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1# Copyright (c) 2022 Huawei Device Co., Ltd.
2# Licensed under the Apache License, Version 2.0 (the "License");
3# you may not use this file except in compliance with the License.
4# You may obtain a copy of the License at
5#
6#     http://www.apache.org/licenses/LICENSE-2.0
7#
8# Unless required by applicable law or agreed to in writing, software
9# distributed under the License is distributed on an "AS IS" BASIS,
10# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
11# See the License for the specific language governing permissions and
12# limitations under the License.
13import("//build/config/clang/clang.gni")
14
15declare_args() {
16  # Enable the config that variables are automatically initialized by default.
17  enable_auto_var_init = false
18  support_stack_protector_ret = false
19}
20
21using_security_flag = enable_auto_var_init
22
23if (!is_ohos) {
24  using_security_flag = false
25}
26
27# support_stack_protector_ret = true if clang support -fstack-protector-ret-all
28clang_bin = rebase_path("${default_clang_base_path}/bin/clang", root_build_dir)
29cmd = "${clang_bin} --help | grep fstack-protector-ret-all | wc -l"
30
31# exec_script returns 1 if grep -fstack-protector-ret-all failed, indicating -fstack-protector-ret-all not supported
32res = exec_script("//build/scripts/run_shell_cmd.py", [ cmd ], "value")
33if (target_cpu == "arm64" && res == 1 && is_ohos && is_standard_system &&
34    !is_mingw) {
35  support_stack_protector_ret = true
36} else {
37  support_stack_protector_ret = false
38}
39
40assert(
41    !using_security_flag || is_clang,
42    "automatic variable initialization requires setting is_clang = true in 'gn args'")
43
44template("ohos_auto_initialize_config") {
45  config(target_name) {
46    forward_variables_from(invoker, [ "auto_var_init" ])
47
48    configs = []
49
50    # Currently, only the clang compiler and standard system support automatic variable initialization.
51    if (is_clang && is_standard_system) {
52      if (defined(auto_var_init)) {
53        assert(
54            auto_var_init == "pattern" || auto_var_init == "zero" ||
55                auto_var_init == "uninit",
56            "auto_var_init can only be set to pattern, zero or uninit, for example, auto_var_init = \"pattern\"")
57
58        if (auto_var_init == "pattern") {
59          configs += [ "//build/config/security:auto_var_pattern_init_config" ]
60        } else if (auto_var_init == "zero") {
61          configs += [ "//build/config/security:auto_var_zero_init_config" ]
62        } else if (auto_var_init == "uninit") {
63          configs += [ "//build/config/security:auto_var_uninit_config" ]
64        }
65      } else {
66        configs += [ "//build/config/security:auto_var_zero_init_config" ]
67      }
68    }
69  }
70}
71
72template("ohos_security_config") {
73  config(target_name) {
74    configs = []
75    _auto_initialize_config_target = "${target_name}__auto_initialize_config"
76    ohos_auto_initialize_config(_auto_initialize_config_target) {
77      forward_variables_from(invoker, [ "auto_var_init" ])
78    }
79
80    configs += [ ":$_auto_initialize_config_target" ]
81  }
82}
83