• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1gstplayer_sources = files([
2  'gstplayer.c',
3  'gstplayer-signal-dispatcher.c',
4  'gstplayer-video-renderer.c',
5  'gstplayer-media-info.c',
6  'gstplayer-g-main-context-signal-dispatcher.c',
7  'gstplayer-video-overlay-video-renderer.c',
8  'gstplayer-wrapped-video-renderer.c',
9  'gstplayer-visualization.c',
10])
11
12gstplayer_headers = files([
13  'player.h',
14  'player-prelude.h',
15  'gstplayer.h',
16  'gstplayer-types.h',
17  'gstplayer-signal-dispatcher.h',
18  'gstplayer-video-renderer.h',
19  'gstplayer-media-info.h',
20  'gstplayer-g-main-context-signal-dispatcher.h',
21  'gstplayer-video-overlay-video-renderer.h',
22  'gstplayer-visualization.h',
23])
24
25install_headers(gstplayer_headers, subdir : 'gstreamer-' + api_version + '/gst/player/')
26
27gstplayer = library('gstplayer-' + api_version,
28  gstplayer_sources,
29  c_args : gst_plugins_bad_args + ['-DBUILDING_GST_PLAYER', '-DG_LOG_DOMAIN="GStreamer-Player"'],
30  include_directories : [configinc, libsinc],
31  version : libversion,
32  soversion : soversion,
33  darwin_versions : osxversion,
34  install : true,
35  dependencies : [gstbase_dep, gstvideo_dep, gstaudio_dep, gstplay_dep,
36                  gsttag_dep, gstpbutils_dep],
37)
38
39library_def = {'lib': gstplayer}
40pkg_name = 'gstreamer-player-1.0'
41pkgconfig.generate(gstplayer,
42  libraries : [gst_dep, gstvideo_dep],
43  variables : pkgconfig_variables,
44  subdirs : pkgconfig_subdirs,
45  name : 'gstreamer-player-1.0',
46  description : 'GStreamer Player convenience library',
47)
48
49gen_sources = []
50if build_gir
51  gir = {
52    'sources' : gstplayer_sources + gstplayer_headers,
53    'namespace' : 'GstPlayer',
54    'nsversion' : api_version,
55    'identifier_prefix' : 'Gst',
56    'symbol_prefix' : 'gst',
57    'export_packages' : pkg_name,
58    'includes' : ['Gst-1.0', 'GstPbutils-1.0', 'GstBase-1.0', 'GstVideo-1.0',
59      'GstAudio-1.0', 'GstTag-1.0'],
60    'install' : true,
61    'extra_args' : gir_init_section + ['-DGST_USE_UNSTABLE_API'] + ['--c-include=gst/player/player.h'],
62    'dependencies' : [gstbase_dep, gstvideo_dep, gstaudio_dep, gstplay_dep,
63                      gsttag_dep, gstpbutils_dep]
64  }
65  library_def = {'lib': library_def['lib'], 'gir': [gir]}
66  if not static_build
67    player_gir = gnome.generate_gir(gstplayer, kwargs: gir)
68    gen_sources += player_gir
69  endif
70endif
71libraries += [[pkg_name, library_def]]
72
73gstplayer_dep = declare_dependency(link_with : gstplayer,
74  include_directories : [libsinc],
75  sources: gen_sources,
76  dependencies : [gstbase_dep, gstvideo_dep, gstaudio_dep, gstplay_dep,
77                  gsttag_dep, gstpbutils_dep])
78
79meson.override_dependency(pkg_name, gstplayer_dep)
80