• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1# Copyright (c) 2021-2022 Huawei Device Co., Ltd.
2# Licensed under the Apache License, Version 2.0 (the "License");
3# you may not use this file except in compliance with the License.
4# You may obtain a copy of the License at
5#
6#     http://www.apache.org/licenses/LICENSE-2.0
7#
8# Unless required by applicable law or agreed to in writing, software
9# distributed under the License is distributed on an "AS IS" BASIS,
10# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
11# See the License for the specific language governing permissions and
12# limitations under the License.
13
14import("//build/ohos.gni")
15import("//foundation/arkui/ace_engine/ace_config.gni")
16import("//foundation/arkui/ace_engine/build/ace_lib.gni")
17
18# generate libace_engine and libace_debug targets
19foreach(item, ace_platforms) {
20  platform = item.name
21  engine_config = {
22  }
23  engine_config = item.config
24  support_engines = []
25  support_engines = engine_config.js_engines
26
27  # generate libace_static lib
28  libace_static("libace_static_" + item.name) {
29    platform = item.name
30    config = {
31    }
32
33    if (defined(item.config)) {
34      config = item.config
35    }
36  }
37
38  # generate separated libace_engine lib
39  if (current_os == "ohos") {
40    build_in_engine = defined(engine_config.use_build_in_js_engine) &&
41                      engine_config.use_build_in_js_engine
42    foreach(engine, support_engines) {
43      if (!build_in_engine) {
44        # generate libace_engine
45        ace_bridge_engine("libace_engine_${engine.engine_name}_${platform}") {
46          platform = item.name
47          engine_name = engine.engine_name
48          build_type = "engine"
49          use_js_debug = false
50        }
51
52        # generate libace_engine_debug
53        if (defined(engine.have_debug) && engine.have_debug) {
54          ace_bridge_engine(
55              "libace_engine_${engine.engine_name}_debug_${platform}") {
56            platform = item.name
57            engine_name = engine.engine_name
58            build_type = "engine"
59            use_js_debug = true
60          }
61        }
62
63        # generate libace_engine_declarative
64        ace_bridge_engine(
65            "libace_engine_declarative_${engine.engine_name}_${platform}") {
66          platform = item.name
67          engine_name = engine.engine_name
68          build_type = "engine_declarative"
69        }
70      }
71
72      # generate libace_engine_pa
73      if (defined(engine_config.js_pa_support) && engine_config.js_pa_support &&
74          platform != "ohos_ng") {
75        ace_bridge_engine("libace_engine_pa_${engine.engine_name}") {
76          platform = item.name
77          engine_name = engine.engine_name
78          build_type = "engine_pa"
79          pa_engine_path = engine_config.pa_engine_path
80        }
81      }
82    }
83  }
84}
85
86# Config for reduceing eh_frame section on aosp platform to save rom size.
87config("reduce_eh_frame_config") {
88  if (!use_mingw_win && !use_mac && !use_linux) {
89    cflags = [
90      "-fno-unwind-tables",
91      "-fomit-frame-pointer",
92    ]
93    cflags_cc = cflags
94  }
95}
96
97ohos_shared_library("libace_compatible") {
98  if (is_ohos) {
99    sanitize = {
100      integer_overflow = true
101      boundary_sanitize = true
102      debug = ace_sanitize_debug
103    }
104    deps = [ "$ace_root/build:libace_static_ohos" ]
105    version_script = "libace.map"
106    innerapi_tags = [ "platformsdk" ]
107    configs = [ "$ace_root:ace_coverage_config" ]
108  } else if (use_mingw_win) {
109    deps = [ "$ace_root/build:libace_static_windows" ]
110  } else if (use_mac) {
111    deps = [ "$ace_root/build:libace_static_mac" ]
112  } else if (use_linux) {
113    deps = [ "$ace_root/build:libace_static_linux" ]
114  }
115
116  part_name = ace_engine_part
117  subsystem_name = ace_engine_subsystem
118}
119
120if (!is_asan) {
121  ohos_shared_library("libace") {
122    if (is_ohos) {
123      sanitize = {
124        integer_overflow = true
125        boundary_sanitize = true
126        debug = ace_sanitize_debug
127      }
128      deps = [ "$ace_root/build:libace_static_ohos_ng" ]
129      version_script = "libace.map"
130      innerapi_tags = [ "platformsdk" ]
131      configs = [ "$ace_root:ace_coverage_config" ]
132    } else if (use_mingw_win) {
133      deps = [ "$ace_root/build:libace_static_windows" ]
134    } else if (use_mac) {
135      deps = [ "$ace_root/build:libace_static_mac" ]
136    } else if (use_linux) {
137      deps = [ "$ace_root/build:libace_static_linux" ]
138    }
139
140    part_name = ace_engine_part
141    subsystem_name = ace_engine_subsystem
142  }
143} else {
144  group("libace") {
145    # fake target for asan
146  }
147}
148