• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1# Copyright (c) 2022 Huawei Device Co., Ltd.
2# Licensed under the Apache License, Version 2.0 (the "License");
3# you may not use this file except in compliance with the License.
4# You may obtain a copy of the License at
5#
6#     http://www.apache.org/licenses/LICENSE-2.0
7#
8# Unless required by applicable law or agreed to in writing, software
9# distributed under the License is distributed on an "AS IS" BASIS,
10# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
11# See the License for the specific language governing permissions and
12# limitations under the License.
13
14import("//build/ohos.gni")
15import("//foundation/arkui/ace_engine/ace_config.gni")
16
17template("napi_animator_static") {
18  forward_variables_from(invoker, "*")
19
20  ohos_source_set(target_name) {
21    defines += invoker.defines
22    cflags_cc += invoker.cflags_cc
23    if (is_mac) {
24      cflags_cc += [ "-O0" ]
25    }
26
27    include_dirs = [
28      "//foundation/arkui",
29      "$ace_root",
30      "$ace_root/frameworks",
31    ]
32
33    sources = [ "js_animator.cpp" ]
34
35    deps = []
36    external_deps = []
37    if (platform != "" && is_arkui_x) {
38      deps += [ "//plugins/libs/napi:napi_$platform" ]
39    } else {
40      external_deps += [ "napi:ace_napi" ]
41    }
42    if (defined(config.libace_target)) {
43      deps += [ config.libace_target ]
44    }
45
46    if (platform != "ohos" || is_asan) {
47      if (frame_trace_support) {
48        sources +=
49            [ "$ace_root/adapter/ohos/osal/frame_trace_adapter_impl.cpp" ]
50        external_deps += [
51          "frame_aware_sched:frame_trace_intf",
52          "init:libbegetutil",
53        ]
54      } else {
55        sources +=
56            [ "$ace_root/adapter/ohos/osal/frame_trace_adapter_fake_impl.cpp" ]
57      }
58    }
59
60    deps += [ "../utils:napi_utils_static_${platform}" ]
61
62    subsystem_name = ace_engine_subsystem
63    part_name = ace_engine_part
64  }
65}
66
67foreach(item, ace_platforms) {
68  napi_animator_static("animator_static_" + item.name) {
69    defines = []
70    cflags_cc = []
71    config = {
72    }
73    platform = item.name
74
75    if (defined(item.config)) {
76      config = item.config
77    }
78
79    if (defined(config.defines)) {
80      defines = config.defines
81    }
82
83    if (defined(config.cflags_cc)) {
84      cflags_cc = config.cflags_cc
85    }
86  }
87}
88