• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1cmake_minimum_required(VERSION 3.10)
2
3# Detect if we are the top level CMakeLists.txt or are we included in some
4# other project
5if(NOT DEFINED PROJECT_NAME)
6    set(IS_TOP_PROJECT TRUE)
7endif()
8
9if(IS_TOP_PROJECT)
10    # Turn this on in order to build elfio examples
11    option(ELFIO_BUILD_EXAMPLES "Build ELFIO examples" ON)
12
13    # Turns this on in order to build tests
14    option(ELFIO_BUILD_TESTS "Build ELFIO tests" OFF)
15endif()
16
17# Read version from header file
18set(version_header "elfio/elfio_version.hpp")
19file(READ ${version_header} ver)
20string(REGEX MATCH "#define ELFIO_VERSION \"([0-9\.]+)\"" _ ${ver})
21
22if(NOT CMAKE_MATCH_1)
23    message(FATAL_ERROR "Unable to parse version from ${version_header}")
24endif()
25
26set(version ${CMAKE_MATCH_1})
27
28# Use configure_file to make configure step depend on elfio_version.hpp
29configure_file(${version_header} ${CMAKE_CURRENT_BINARY_DIR}/elfio_version.hpp.copy COPYONLY)
30
31project(elfio VERSION ${version} LANGUAGES C CXX)
32
33include(GNUInstallDirs)
34
35# Create a header only CMake target for elfio
36add_library(elfio INTERFACE)
37add_library(elfio::elfio ALIAS elfio)
38
39target_include_directories(
40    elfio
41    INTERFACE
42    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
43    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)
44
45# If this is the top level project, add in logic to install elfio
46if(IS_TOP_PROJECT)
47    # Enable C++11 for examples and tests
48    if(ELFIO_BUILD_EXAMPLES OR ELFIO_BUILD_TESTS)
49        set(CMAKE_CXX_STANDARD 14)
50    endif()
51
52    if(ELFIO_BUILD_EXAMPLES)
53        # set (CMAKE_CXX_FLAGS "-Wall")
54        add_subdirectory(examples)
55    endif()
56
57    if(ELFIO_BUILD_TESTS AND IS_TOP_PROJECT)
58        # set (CMAKE_CXX_FLAGS "-Wall")
59        enable_testing()
60        add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND} USES_TERMINAL)
61        add_subdirectory(tests)
62    endif()
63
64    include(CMakePackageConfigHelpers)
65
66    # Create a file that includes the current project version. This will be
67    # installed with the elfio CMake package.
68    write_basic_package_version_file(
69        "${PROJECT_NAME}ConfigVersion.cmake"
70        VERSION
71        ${PROJECT_VERSION}
72        COMPATIBILITY
73        SameMajorVersion)
74
75    # Create the default ${PROJECT_NAME}Config.cmake file which will be
76    # installed and found by calls to `find_package(elfio)`.
77    configure_package_config_file(
78        "${PROJECT_SOURCE_DIR}/cmake/${PROJECT_NAME}Config.cmake.in"
79        "${PROJECT_BINARY_DIR}/${PROJECT_NAME}Config.cmake"
80        INSTALL_DESTINATION
81        ${CMAKE_INSTALL_DATAROOTDIR}/${PROJECT_NAME}/cmake)
82
83    # Install the previously generated "config" and "version" files
84    install(
85        FILES
86        "${PROJECT_BINARY_DIR}/${PROJECT_NAME}Config.cmake"
87        "${PROJECT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake"
88        DESTINATION
89        ${CMAKE_INSTALL_DATAROOTDIR}/${PROJECT_NAME}/cmake)
90
91    # Install the entire local `elfio` directory to the include directory
92    install(
93        DIRECTORY
94        elfio
95        DESTINATION
96        ${CMAKE_INSTALL_INCLUDEDIR})
97
98    # Create a ${PROJECT_NAME}Targets.cmake file that is referenced by the
99    # ${PROJECT_NAME}Config.cmake file and includes the target information
100    # needed to compile/link against all targets exported under the
101    # ${PROJECT_NAME}_Targets export
102    install(
103        EXPORT
104        ${PROJECT_NAME}_Targets
105        FILE
106        ${PROJECT_NAME}Targets.cmake
107        NAMESPACE
108        ${PROJECT_NAME}::
109        DESTINATION
110        ${CMAKE_INSTALL_DATAROOTDIR}/${PROJECT_NAME}/cmake)
111
112    # Add the elfio target to the ${PROJECT_NAME}_Targets export
113    install(
114        TARGETS
115        elfio
116        EXPORT
117        ${PROJECT_NAME}_Targets)
118
119    # cmake -B build; cmake --build build; cpack --config build/CPackSourceConfig.cmake
120    # cmake -B build -D ELFIO_BUILD_EXAMPLES=ON -DELFIO_BUILD_TESTS=ON -G Ninja; cmake --build build; cpack --config build/CPackSourceConfig.cmake
121    set(_fmt TGZ)
122
123    if(WIN32)
124        set(_fmt ZIP)
125    endif()
126
127    set(CPACK_GENERATOR ${_fmt})
128    set(CPACK_SOURCE_GENERATOR ${_fmt})
129    set(CPACK_PACKAGE_VENDOR "ELFIO")
130    set(CPACK_PACKAGE_CONTACT "Serge Lamikhov-Center")
131    set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.txt")
132    set(CPACK_RESOURCE_FILE_README "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
133    set(CPACK_OUTPUT_FILE_PREFIX "${CMAKE_CURRENT_BINARY_DIR}/package")
134    set(CPACK_PACKAGE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
135    string(TOLOWER ${CMAKE_SYSTEM_NAME} _sys)
136    string(TOLOWER ${PROJECT_NAME} _project_lower)
137    set(CPACK_PACKAGE_FILE_NAME "${_project_lower}-${_sys}")
138    set(CPACK_SOURCE_PACKAGE_FILE_NAME "${_project_lower}-${PROJECT_VERSION}")
139
140    set(CPACK_SOURCE_IGNORE_FILES "/.git/;/.github/;/.vscode/;/build;/.clang-format;/.gitignore;/.travis.yml;/doc/images/;/doc/site;/doc/elfio.docx;/examples/sudo_gdb.sh;/tests")
141
142    install(FILES ${CPACK_RESOURCE_FILE_README} ${CPACK_RESOURCE_FILE_LICENSE}
143        DESTINATION share/docs/${PROJECT_NAME})
144
145    include(CPack)
146endif()
147