• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1#***************************************************************************
2#                                  _   _ ____  _
3#  Project                     ___| | | |  _ \| |
4#                             / __| | | | |_) | |
5#                            | (__| |_| |  _ <| |___
6#                             \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
13#
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
17#
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
20#
21# SPDX-License-Identifier: curl
22#
23###########################################################################
24include(CheckCSourceCompiles)
25
26option(CURL_HIDDEN_SYMBOLS "Set to ON to hide libcurl internal symbols (=hide all symbols that aren't officially external)." ON)
27mark_as_advanced(CURL_HIDDEN_SYMBOLS)
28
29if(WIN32 AND ENABLE_CURLDEBUG)
30  # We need to export internal debug functions (e.g. curl_dbg_*), so disable
31  # symbol hiding for debug builds.
32  set(CURL_HIDDEN_SYMBOLS OFF)
33endif()
34
35if(CURL_HIDDEN_SYMBOLS)
36  set(SUPPORTS_SYMBOL_HIDING FALSE)
37
38  if(CMAKE_C_COMPILER_ID MATCHES "Clang" AND NOT MSVC)
39    set(SUPPORTS_SYMBOL_HIDING TRUE)
40    set(_SYMBOL_EXTERN "__attribute__ ((__visibility__ (\"default\")))")
41    set(_CFLAG_SYMBOLS_HIDE "-fvisibility=hidden")
42  elseif(CMAKE_COMPILER_IS_GNUCC)
43    if(NOT CMAKE_C_COMPILER_VERSION VERSION_LESS 3.4)
44      # note: this is considered buggy prior to 4.0 but the autotools don't care, so let's ignore that fact
45      set(SUPPORTS_SYMBOL_HIDING TRUE)
46      set(_SYMBOL_EXTERN "__attribute__ ((__visibility__ (\"default\")))")
47      set(_CFLAG_SYMBOLS_HIDE "-fvisibility=hidden")
48    endif()
49  elseif(CMAKE_C_COMPILER_ID MATCHES "SunPro" AND NOT CMAKE_C_COMPILER_VERSION VERSION_LESS 8.0)
50    set(SUPPORTS_SYMBOL_HIDING TRUE)
51    set(_SYMBOL_EXTERN "__global")
52    set(_CFLAG_SYMBOLS_HIDE "-xldscope=hidden")
53  elseif(CMAKE_C_COMPILER_ID MATCHES "Intel" AND NOT CMAKE_C_COMPILER_VERSION VERSION_LESS 9.0)
54    # note: this should probably just check for version 9.1.045 but I'm not 100% sure
55    #       so let's do it the same way autotools do.
56    set(SUPPORTS_SYMBOL_HIDING TRUE)
57    set(_SYMBOL_EXTERN "__attribute__ ((__visibility__ (\"default\")))")
58    set(_CFLAG_SYMBOLS_HIDE "-fvisibility=hidden")
59    check_c_source_compiles("#include <stdio.h>
60        int main (void) { printf(\"icc fvisibility bug test\"); return 0; }" _no_bug)
61    if(NOT _no_bug)
62      set(SUPPORTS_SYMBOL_HIDING FALSE)
63      set(_SYMBOL_EXTERN "")
64      set(_CFLAG_SYMBOLS_HIDE "")
65    endif()
66  elseif(MSVC)
67    set(SUPPORTS_SYMBOL_HIDING TRUE)
68  endif()
69
70  set(HIDES_CURL_PRIVATE_SYMBOLS ${SUPPORTS_SYMBOL_HIDING})
71elseif(MSVC)
72  if(NOT CMAKE_VERSION VERSION_LESS 3.7)
73    set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS TRUE) #present since 3.4.3 but broken
74    set(HIDES_CURL_PRIVATE_SYMBOLS FALSE)
75  else()
76    message(WARNING "Hiding private symbols regardless CURL_HIDDEN_SYMBOLS being disabled.")
77    set(HIDES_CURL_PRIVATE_SYMBOLS TRUE)
78  endif()
79else()
80  set(HIDES_CURL_PRIVATE_SYMBOLS FALSE)
81endif()
82
83set(CURL_CFLAG_SYMBOLS_HIDE ${_CFLAG_SYMBOLS_HIDE})
84set(CURL_EXTERN_SYMBOL ${_SYMBOL_EXTERN})
85