• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1if get_option('client')
2  pacat_sources = [
3    'pacat.c',
4  ]
5
6  pacat_aliases = [
7    'pamon',
8    'paplay',
9    'parec',
10    'parecord',
11  ]
12
13  executable('pacat',
14    pacat_sources,
15    install: true,
16    install_rpath : privlibdir,
17    include_directories : [configinc, topinc],
18    link_with : [libpulsecommon, libpulse],
19    dependencies : [sndfile_dep, libintl_dep],
20    c_args : pa_c_args,
21  )
22
23  # Windows doesn't support symbolic links.
24  if host_machine.system() != 'windows'
25    foreach alias : pacat_aliases
26      dst = join_paths(bindir, alias)
27      cmd = 'ln -fs @0@ $DESTDIR@1@'.format('pacat', dst)
28      meson.add_install_script('sh', '-c', cmd)
29    endforeach
30  endif
31
32  pactl_sources = [
33    'pactl.c',
34  ]
35
36  executable('pactl',
37    pactl_sources,
38    install: true,
39    install_rpath : privlibdir,
40    include_directories : [configinc, topinc],
41    link_with : [libpulsecommon, libpulse],
42    dependencies : [sndfile_dep, libintl_dep],
43    c_args : pa_c_args,
44  )
45endif
46
47if get_option('daemon')
48  if host_machine.system() != 'windows'
49    pasuspender_sources = [
50      'pasuspender.c',
51    ]
52
53    executable('pasuspender',
54      pasuspender_sources,
55      install: true,
56      install_rpath : privlibdir,
57      include_directories : [configinc, topinc],
58      dependencies: [libintl_dep, libpulsecommon_dep, libpulse_dep],
59      c_args : pa_c_args,
60    )
61
62    pacmd_sources = [
63      'pacmd.c',
64    ]
65
66    executable('pacmd',
67      pacmd_sources,
68      install: true,
69      install_rpath : privlibdir,
70      include_directories : [configinc, topinc],
71      dependencies: [libintl_dep, libpulsecommon_dep, libpulse_dep],
72      c_args : pa_c_args,
73    )
74  endif
75
76  if dbus_dep.found() and fftw_dep.found()
77    install_data('qpaeq', install_dir : bindir)
78  endif
79endif
80
81if get_option('client')
82  if x11_dep.found()
83    pax11publish_sources = [
84      'pax11publish.c',
85    ]
86
87    executable('pax11publish',
88      pax11publish_sources,
89      install: true,
90      install_rpath : privlibdir,
91      include_directories : [configinc, topinc],
92      link_with : [libpulsecommon, libpulse],
93      dependencies : [x11_dep, libintl_dep],
94      c_args : pa_c_args,
95    )
96  endif
97
98  if cdata.has('HAVE_OSS_WRAPPER')
99    libpulsecommon_sources = [
100      'padsp.c',
101    ]
102
103    libpulsedsp = shared_library('pulsedsp',
104      libpulsecommon_sources,
105      install: true,
106      install_dir : padsplibdir,
107      install_rpath : privlibdir,
108      include_directories : [configinc, topinc],
109      link_with : [libpulsecommon, libpulse],
110      link_args : [nodelete_link_args],
111      dependencies: [thread_dep, dl_dep],
112      c_args : [pa_c_args, '-Wno-nonnull-compare']
113    )
114
115    configure_file(
116      input : 'padsp.in',
117      output : 'padsp',
118      configuration : cdata,
119      install : true,
120      install_dir : bindir,
121    )
122  endif
123
124  install_data('pa-info', install_dir : bindir)
125endif
126