• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1cmake_minimum_required(VERSION 3.10)
2
3# Detect if we are the top level CMakeLists.txt or are we included in some
4# other project
5if(NOT DEFINED PROJECT_NAME)
6    set(IS_TOP_PROJECT TRUE)
7endif()
8
9if(IS_TOP_PROJECT)
10    # Turn this on in order to build elfio examples
11    option(ELFIO_BUILD_EXAMPLES "Build ELFIO examples" ON)
12
13    # Turns this on in order to build tests
14    option(ELFIO_BUILD_TESTS "Build ELFIO tests" OFF)
15
16    # Generate output of compile commands during generation
17    set(CMAKE_EXPORT_COMPILE_COMMANDS, ON)
18endif()
19
20# Read version from header file
21set(version_header "elfio/elfio_version.hpp")
22file(READ ${version_header} ver)
23string(REGEX MATCH "#define ELFIO_VERSION \"([0-9\.]+)\"" _ ${ver})
24
25if(NOT CMAKE_MATCH_1)
26    message(FATAL_ERROR "Unable to parse version from ${version_header}")
27endif()
28
29set(version ${CMAKE_MATCH_1})
30
31# Use configure_file to make configure step depend on elfio_version.hpp
32configure_file(${version_header} ${CMAKE_CURRENT_BINARY_DIR}/elfio_version.hpp.copy COPYONLY)
33
34project(elfio VERSION ${version} LANGUAGES C CXX)
35
36include(GNUInstallDirs)
37
38# Create a header only CMake target for elfio
39add_library(elfio INTERFACE)
40add_library(elfio::elfio ALIAS elfio)
41
42target_include_directories(
43    elfio
44    INTERFACE
45    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
46    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)
47
48# If this is the top level project, add in logic to install elfio
49if(IS_TOP_PROJECT)
50    # Enable C++14 for examples and tests
51    if(ELFIO_BUILD_EXAMPLES OR ELFIO_BUILD_TESTS)
52        set(CMAKE_CXX_STANDARD 17)
53    endif()
54
55    if(ELFIO_BUILD_EXAMPLES)
56        # set (CMAKE_CXX_FLAGS "-Wall")
57        add_subdirectory(examples)
58    endif()
59
60    if(ELFIO_BUILD_TESTS)
61        # set (CMAKE_CXX_FLAGS "-Wall")
62        enable_testing()
63        add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND} USES_TERMINAL)
64        add_subdirectory(tests)
65    endif()
66
67    include(CMakePackageConfigHelpers)
68
69    # Create a file that includes the current project version. This will be
70    # installed with the elfio CMake package.
71    write_basic_package_version_file(
72        "${PROJECT_NAME}ConfigVersion.cmake"
73        VERSION
74        ${PROJECT_VERSION}
75        COMPATIBILITY
76        SameMajorVersion)
77
78    # Create the default ${PROJECT_NAME}Config.cmake file which will be
79    # installed and found by calls to `find_package(elfio)`.
80    configure_package_config_file(
81        "${PROJECT_SOURCE_DIR}/cmake/${PROJECT_NAME}Config.cmake.in"
82        "${PROJECT_BINARY_DIR}/${PROJECT_NAME}Config.cmake"
83        INSTALL_DESTINATION
84        ${CMAKE_INSTALL_DATAROOTDIR}/${PROJECT_NAME}/cmake)
85
86    # Install the previously generated "config" and "version" files
87    install(
88        FILES
89        "${PROJECT_BINARY_DIR}/${PROJECT_NAME}Config.cmake"
90        "${PROJECT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake"
91        DESTINATION
92        ${CMAKE_INSTALL_DATAROOTDIR}/${PROJECT_NAME}/cmake)
93
94    # Install the entire local `elfio` directory to the include directory
95    install(
96        DIRECTORY
97        elfio
98        DESTINATION
99        ${CMAKE_INSTALL_INCLUDEDIR})
100
101    # Create a ${PROJECT_NAME}Targets.cmake file that is referenced by the
102    # ${PROJECT_NAME}Config.cmake file and includes the target information
103    # needed to compile/link against all targets exported under the
104    # ${PROJECT_NAME}_Targets export
105    install(
106        EXPORT
107        ${PROJECT_NAME}_Targets
108        FILE
109        ${PROJECT_NAME}Targets.cmake
110        NAMESPACE
111        ${PROJECT_NAME}::
112        DESTINATION
113        ${CMAKE_INSTALL_DATAROOTDIR}/${PROJECT_NAME}/cmake)
114
115    # Add the elfio target to the ${PROJECT_NAME}_Targets export
116    install(
117        TARGETS
118        elfio
119        EXPORT
120        ${PROJECT_NAME}_Targets)
121
122    # cmake -B build; cmake --build build; cpack --config build/CPackSourceConfig.cmake
123    # cmake -B build -D ELFIO_BUILD_EXAMPLES=ON -DELFIO_BUILD_TESTS=ON -G Ninja; cmake --build build; cpack --config build/CPackSourceConfig.cmake
124    set(_fmt TGZ)
125
126    if(WIN32)
127        set(_fmt ZIP)
128    endif()
129
130    set(CPACK_GENERATOR ${_fmt})
131    set(CPACK_SOURCE_GENERATOR ${_fmt})
132    set(CPACK_PACKAGE_VENDOR "ELFIO")
133    set(CPACK_PACKAGE_CONTACT "Serge Lamikhov-Center")
134    set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.txt")
135    set(CPACK_RESOURCE_FILE_README "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
136    set(CPACK_OUTPUT_FILE_PREFIX "${CMAKE_CURRENT_BINARY_DIR}/package")
137    set(CPACK_PACKAGE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
138    string(TOLOWER ${CMAKE_SYSTEM_NAME} _sys)
139    string(TOLOWER ${PROJECT_NAME} _project_lower)
140    set(CPACK_PACKAGE_FILE_NAME "${_project_lower}-${_sys}")
141    set(CPACK_SOURCE_PACKAGE_FILE_NAME "${_project_lower}-${PROJECT_VERSION}")
142
143    set(CPACK_SOURCE_IGNORE_FILES "/.git/;/.github/;/.vscode/;/build;/.clang-format;/.gitignore;/.travis.yml;/doc/images/;/doc/site;/doc/elfio.docx;/examples/sudo_gdb.sh;/tests")
144
145    install(FILES ${CPACK_RESOURCE_FILE_README} ${CPACK_RESOURCE_FILE_LICENSE}
146        DESTINATION share/docs/${PROJECT_NAME})
147
148    include(CPack)
149endif()
150