• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1# CMake definitions for libprotobuf_lite (the "lite" C++ protobuf runtime).
2
3include(${protobuf_SOURCE_DIR}/src/file_lists.cmake)
4include(${protobuf_SOURCE_DIR}/cmake/protobuf-configure-target.cmake)
5
6add_library(libprotobuf-lite ${protobuf_SHARED_OR_STATIC}
7  ${libprotobuf_lite_srcs}
8  ${libprotobuf_lite_hdrs}
9  ${protobuf_version_rc_file})
10if(protobuf_HAVE_LD_VERSION_SCRIPT)
11  if(${CMAKE_VERSION} VERSION_GREATER 3.13 OR ${CMAKE_VERSION} VERSION_EQUAL 3.13)
12    target_link_options(libprotobuf-lite PRIVATE -Wl,--version-script=${protobuf_SOURCE_DIR}/src/libprotobuf-lite.map)
13  elseif(protobuf_BUILD_SHARED_LIBS)
14    target_link_libraries(libprotobuf-lite PRIVATE -Wl,--version-script=${protobuf_SOURCE_DIR}/src/libprotobuf-lite.map)
15  endif()
16  set_target_properties(libprotobuf-lite PROPERTIES
17    LINK_DEPENDS ${protobuf_SOURCE_DIR}/src/libprotobuf-lite.map)
18endif()
19target_link_libraries(libprotobuf-lite PRIVATE ${CMAKE_THREAD_LIBS_INIT})
20if(protobuf_LINK_LIBATOMIC)
21  target_link_libraries(libprotobuf-lite PRIVATE atomic)
22endif()
23if(${CMAKE_SYSTEM_NAME} STREQUAL "Android")
24  target_link_libraries(libprotobuf-lite PRIVATE log)
25endif()
26target_include_directories(libprotobuf-lite PUBLIC
27  $<BUILD_INTERFACE:${protobuf_SOURCE_DIR}/src>
28  $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
29)
30target_link_libraries(libprotobuf-lite PUBLIC ${protobuf_ABSL_USED_TARGETS})
31protobuf_configure_target(libprotobuf-lite)
32protobuf_configure_unity_target(libprotobuf-lite)
33if(protobuf_BUILD_SHARED_LIBS)
34  target_compile_definitions(libprotobuf-lite
35    PUBLIC  PROTOBUF_USE_DLLS
36    PRIVATE LIBPROTOBUF_EXPORTS)
37endif()
38set_target_properties(libprotobuf-lite PROPERTIES
39    VERSION ${protobuf_VERSION}
40    OUTPUT_NAME ${LIB_PREFIX}protobuf-lite
41    DEBUG_POSTFIX "${protobuf_DEBUG_POSTFIX}"
42    # For -fvisibility=hidden and -fvisibility-inlines-hidden
43    C_VISIBILITY_PRESET hidden
44    CXX_VISIBILITY_PRESET hidden
45    VISIBILITY_INLINES_HIDDEN ON
46)
47add_library(protobuf::libprotobuf-lite ALIAS libprotobuf-lite)
48
49target_link_libraries(libprotobuf-lite PRIVATE utf8_validity)
50