• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1# Copyright 2017 The Chromium Authors
2# Use of this source code is governed by a BSD-style license that can be
3# found in the LICENSE file.
4
5import("//build/compiled_action.gni")
6import("//net/features.gni")
7
8# Generates a header file based on the real preload list.
9compiled_action("generate_transport_security_state") {
10  tool = "//net/tools/transport_security_state_generator"
11
12  # Inputs in order expected by the command line of the tool.
13  inputs = [
14    "transport_security_state_static.json",
15    "transport_security_state_static_pins.json",
16    "transport_security_state_static.pins",
17    "transport_security_state_static.template",
18  ]
19  outputs = [ "$target_gen_dir/transport_security_state_static.h" ]
20  args =
21      rebase_path(inputs, root_build_dir) + rebase_path(outputs, root_build_dir)
22}
23
24# Generates a header file for use in unittests.
25compiled_action("transport_security_state_unittest_data_default") {
26  tool = "//net/tools/transport_security_state_generator"
27
28  # Inputs in order expected by the command line of the tool.
29  inputs = [
30    "transport_security_state_static_unittest_default.json",
31    "transport_security_state_static_unittest_default_pins.json",
32    "transport_security_state_static_unittest_default.pins",
33    "transport_security_state_static_unittest.template",
34  ]
35  outputs =
36      [ "$target_gen_dir/transport_security_state_static_unittest_default.h" ]
37  args =
38      rebase_path(inputs, root_build_dir) + rebase_path(outputs, root_build_dir)
39}
40
41# Generates a number of header files that are used by integration tests for the
42# generation process and preload format.
43compiled_action_foreach("transport_security_state_unittest_data") {
44  tool = "//net/tools/transport_security_state_generator"
45  sources = [
46    "transport_security_state_static_unittest1.json",
47    "transport_security_state_static_unittest2.json",
48    "transport_security_state_static_unittest3.json",
49  ]
50
51  # extra_args in order expected by the command line of the tool.
52  extra_args = [
53    "transport_security_state_static_unittest.pins",
54    "transport_security_state_static_unittest.template",
55  ]
56
57  inputs = [
58    "transport_security_state_static_unittest1_pins.json",
59    "transport_security_state_static_unittest2_pins.json",
60    "transport_security_state_static_unittest3_pins.json",
61  ] + extra_args
62  outputs = [ "$target_gen_dir/{{source_name_part}}.h" ]
63  args =
64      [ rebase_path("{{source_name_part}}.json", root_build_dir) ] +
65      [ rebase_path("{{source_name_part}}_pins.json", root_build_dir) ] +
66      rebase_path(extra_args, root_build_dir) + rebase_path(outputs, root_build_dir)
67}
68
69# This has separated source_set not to let other compiles wait for the
70# generate_transport_security_state task to complete.
71source_set("transport_security_state_generated_files") {
72  # Do not publicize any header to remove build dependency.
73  public = []
74
75  sources = [
76    "transport_security_state.cc",
77
78    # transport_security_state.h is intentionally specified in net/BUILD.gn
79    # rather than in this source_set. See this review comment thread for
80    # details:
81    # https://chromium-review.googlesource.com/c/chromium/src/+/1460639/comment/b781034b_5794ab47/
82
83    "transport_security_state_ct_policies.inc",
84  ]
85
86  deps = [
87    "//build:branding_buildflags",
88    "//net:net_deps",
89    "//net:net_public_deps",
90    "//net/dns",
91  ]
92
93  if (include_transport_security_state_preload_list) {
94    deps += [ ":generate_transport_security_state" ]
95  }
96}
97