• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1# Copyright (c) 2015-2016 The Khronos Group Inc.
2#
3# Licensed under the Apache License, Version 2.0 (the "License");
4# you may not use this file except in compliance with the License.
5# You may obtain a copy of the License at
6#
7#     http://www.apache.org/licenses/LICENSE-2.0
8#
9# Unless required by applicable law or agreed to in writing, software
10# distributed under the License is distributed on an "AS IS" BASIS,
11# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
12# See the License for the specific language governing permissions and
13# limitations under the License.
14
15if (NOT ${SPIRV_SKIP_EXECUTABLES})
16 add_subdirectory(lesspipe)
17endif()
18add_subdirectory(emacs)
19
20# Add a SPIR-V Tools command line tool. Signature:
21#   add_spvtools_tool(
22#     TARGET target_name
23#     SRCS   src_file1.cpp src_file2.cpp
24#     LIBS   lib_target1 lib_target2
25#   )
26function(add_spvtools_tool)
27  set(one_value_args TARGET)
28  set(multi_value_args SRCS LIBS)
29  cmake_parse_arguments(
30    ARG "" "${one_value_args}" "${multi_value_args}" ${ARGN})
31
32  add_executable(${ARG_TARGET} ${ARG_SRCS})
33  spvtools_default_compile_options(${ARG_TARGET})
34  target_link_libraries(${ARG_TARGET} PRIVATE ${ARG_LIBS})
35  target_include_directories(${ARG_TARGET} PRIVATE
36    ${spirv-tools_SOURCE_DIR}
37    ${spirv-tools_BINARY_DIR}
38  )
39  set_property(TARGET ${ARG_TARGET} PROPERTY FOLDER "SPIRV-Tools executables")
40endfunction()
41
42set(COMMON_TOOLS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/util/flags.cpp")
43
44if (NOT ${SPIRV_SKIP_EXECUTABLES})
45  add_spvtools_tool(TARGET spirv-diff SRCS ${COMMON_TOOLS_SRCS} diff/diff.cpp util/cli_consumer.cpp io.cpp LIBS SPIRV-Tools-diff SPIRV-Tools-opt ${SPIRV_TOOLS_FULL_VISIBILITY})
46  add_spvtools_tool(TARGET spirv-dis  SRCS ${COMMON_TOOLS_SRCS} dis/dis.cpp io.cpp LIBS ${SPIRV_TOOLS_FULL_VISIBILITY})
47  add_spvtools_tool(TARGET spirv-val  SRCS ${COMMON_TOOLS_SRCS} val/val.cpp util/cli_consumer.cpp io.cpp LIBS ${SPIRV_TOOLS_FULL_VISIBILITY})
48  add_spvtools_tool(TARGET spirv-opt  SRCS ${COMMON_TOOLS_SRCS} opt/opt.cpp util/cli_consumer.cpp io.cpp LIBS SPIRV-Tools-opt ${SPIRV_TOOLS_FULL_VISIBILITY})
49  if(NOT (${CMAKE_SYSTEM_NAME} STREQUAL "iOS")) # iOS does not allow std::system calls which spirv-reduce requires
50    add_spvtools_tool(TARGET spirv-reduce SRCS ${COMMON_TOOLS_SRCS} reduce/reduce.cpp util/cli_consumer.cpp io.cpp LIBS SPIRV-Tools-reduce ${SPIRV_TOOLS_FULL_VISIBILITY})
51  endif()
52  add_spvtools_tool(TARGET spirv-link SRCS ${COMMON_TOOLS_SRCS} link/linker.cpp io.cpp LIBS SPIRV-Tools-link ${SPIRV_TOOLS_FULL_VISIBILITY})
53  add_spvtools_tool(TARGET spirv-lint SRCS ${COMMON_TOOLS_SRCS} lint/lint.cpp util/cli_consumer.cpp io.cpp LIBS SPIRV-Tools-lint SPIRV-Tools-opt ${SPIRV_TOOLS_FULL_VISIBILITY})
54  add_spvtools_tool(TARGET spirv-as
55                    SRCS as/as.cpp
56                         io.cpp
57                         ${COMMON_TOOLS_SRCS}
58                    LIBS ${SPIRV_TOOLS_FULL_VISIBILITY})
59  target_include_directories(spirv-as PRIVATE ${spirv-tools_SOURCE_DIR}
60                                              ${SPIRV_HEADER_INCLUDE_DIR})
61  add_spvtools_tool(TARGET spirv-cfg
62                    SRCS cfg/cfg.cpp
63                         cfg/bin_to_dot.h
64                         cfg/bin_to_dot.cpp
65                         io.cpp
66                         ${COMMON_TOOLS_SRCS}
67                    LIBS ${SPIRV_TOOLS_FULL_VISIBILITY})
68  target_include_directories(spirv-cfg PRIVATE ${spirv-tools_SOURCE_DIR}
69                                               ${SPIRV_HEADER_INCLUDE_DIR})
70  set(SPIRV_INSTALL_TARGETS spirv-as spirv-dis spirv-val spirv-opt
71                            spirv-cfg spirv-link spirv-lint)
72
73  if(NOT (${CMAKE_SYSTEM_NAME} STREQUAL "Android"))
74    add_spvtools_tool(TARGET spirv-objdump
75                      SRCS objdump/objdump.cpp
76                           objdump/extract_source.cpp
77                           util/cli_consumer.cpp
78                           io.cpp
79                           ${COMMON_TOOLS_SRCS}
80                      LIBS ${SPIRV_TOOLS_FULL_VISIBILITY})
81    target_include_directories(spirv-objdump PRIVATE ${spirv-tools_SOURCE_DIR}
82                                                     ${SPIRV_HEADER_INCLUDE_DIR})
83    set(SPIRV_INSTALL_TARGETS ${SPIRV_INSTALL_TARGETS} spirv-objdump)
84  endif()
85
86  if(NOT (${CMAKE_SYSTEM_NAME} STREQUAL "iOS"))
87    set(SPIRV_INSTALL_TARGETS ${SPIRV_INSTALL_TARGETS} spirv-reduce)
88  endif()
89
90  if(SPIRV_BUILD_FUZZER)
91    add_spvtools_tool(TARGET spirv-fuzz SRCS fuzz/fuzz.cpp util/cli_consumer.cpp io.cpp LIBS SPIRV-Tools-fuzz ${SPIRV_TOOLS_FULL_VISIBILITY})
92    set(SPIRV_INSTALL_TARGETS ${SPIRV_INSTALL_TARGETS} spirv-fuzz)
93  endif(SPIRV_BUILD_FUZZER)
94
95  if(ENABLE_SPIRV_TOOLS_INSTALL)
96    install(TARGETS ${SPIRV_INSTALL_TARGETS} EXPORT SPIRV-Tools-toolsTargets)
97    export(EXPORT SPIRV-Tools-toolsTargets FILE SPIRV-Tools-toolsTargets.cmake)
98
99    spvtools_config_package_dir(SPIRV-Tools-tools PACKAGE_DIR)
100    install(EXPORT SPIRV-Tools-toolsTargets FILE SPIRV-Tools-toolsTargets.cmake
101            DESTINATION ${PACKAGE_DIR})
102
103    file(WRITE ${CMAKE_BINARY_DIR}/SPIRV-Tools-toolsConfig.cmake
104      "include(CMakeFindDependencyMacro)\n"
105      "find_dependency(${SPIRV_TOOLS})\n"
106      "include(\${CMAKE_CURRENT_LIST_DIR}/SPIRV-Tools-toolsTargets.cmake)\n"
107      )
108
109    install(FILES ${CMAKE_BINARY_DIR}/SPIRV-Tools-toolsConfig.cmake DESTINATION ${PACKAGE_DIR})
110  endif(ENABLE_SPIRV_TOOLS_INSTALL)
111endif()
112