• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1intel_hw_metrics = [
2  'hsw',
3  'bdw', 'chv',
4  'sklgt2', 'sklgt3', 'sklgt4',
5  'kblgt2', 'kblgt3',
6  'cflgt2', 'cflgt3',
7  'bxt', 'glk',
8  'icl', 'ehl',
9  'tglgt1', 'tglgt2', 'rkl', 'dg1', 'adl',
10  'acmgt1', 'acmgt2', 'acmgt3',
11  'mtlgt2', 'mtlgt3',
12  'arlgt1', 'arlgt2',
13  'lnl',
14  'bmg',
15]
16
17intel_hw_metrics_xml_files = []
18foreach hw : intel_hw_metrics
19  intel_hw_metrics_xml_files += 'oa-@0@.xml'.format(hw)
20endforeach
21
22intel_perf_sources = [
23  'i915/intel_perf.c',
24  'i915/intel_perf.h',
25  'xe/intel_perf.c',
26  'xe/intel_perf.h',
27  'intel_perf_common.c',
28  'intel_perf_common.h',
29  'intel_perf.c',
30  'intel_perf_query.c',
31  'intel_perf_mdapi.c',
32]
33
34intel_perf_sources += custom_target(
35  'intel-perf-sources',
36  input : intel_hw_metrics_xml_files,
37  output : [ 'intel_perf_metrics.c', 'intel_perf_metrics.h' ],
38  command : [
39    prog_python, files('gen_perf.py'),
40    '--code', '@OUTPUT0@', '--header', '@OUTPUT1@',
41    '@INPUT@',
42  ],
43)
44
45libintel_perf = static_library(
46  'intel_perf',
47  intel_perf_sources,
48  include_directories : [
49    inc_include, inc_src, inc_intel,
50  ],
51  c_args : [no_override_init_args, sse2_arg],
52  cpp_args : [sse2_arg],
53  gnu_symbol_visibility : 'hidden',
54  dependencies : [idep_intel_dev],
55)
56
57if with_intel_tools
58  intel_perf_query_layout = executable(
59    'intel_perf_query_layout',
60    files('intel_perf_query_layout.c'),
61    dependencies : [idep_mesautil, dep_dl, dep_thread, dep_m, idep_intel_dev],
62    include_directories : [inc_include, inc_src, inc_intel],
63    link_with : [libintel_common, libintel_perf],
64    c_args : [no_override_init_args],
65    gnu_symbol_visibility : 'hidden',
66    install : false
67  )
68endif
69