• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1/*
2 * Copyright (c) 2020, Google Inc. All rights reserved
3 *
4 * Permission is hereby granted, free of charge, to any person obtaining
5 * a copy of this software and associated documentation files
6 * (the "Software"), to deal in the Software without restriction,
7 * including without limitation the rights to use, copy, modify, merge,
8 * publish, distribute, sublicense, and/or sell copies of the Software,
9 * and to permit persons to whom the Software is furnished to do so,
10 * subject to the following conditions:
11 *
12 * The above copyright notice and this permission notice shall be
13 * included in all copies or substantial portions of the Software.
14 *
15 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
16 * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
17 * MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
18 * IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
19 * CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
20 * TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
21 * SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
22 */
23
24#include <asm.h>
25#include <arch/asm_macros.h>
26
27.macro smc8_hvc8, instr
28    /*
29     * Save x8 (return value ptr) and lr. The SMC calling convention says el3
30     * does not need to preserve x8. The normal ABI does not require either x8
31     * or lr to be preserved.
32     */
33    push    x8, lr
34    \instr  #0
35    pop     x8, lr
36
37    /* Copy 8-register smc return value to struct smc_ret8 return value */
38    stp     x0, x1, [x8], #16
39    stp     x2, x3, [x8], #16
40    stp     x4, x5, [x8], #16
41    stp     x6, x7, [x8], #16
42
43    ret
44.endm
45
46FUNCTION(smc8)
47    smc8_hvc8 smc
48
49FUNCTION(hvc8)
50    smc8_hvc8 hvc
51
52.macro smc8_hvc8_ret18, instr
53    /*
54     * Save x19 and lr. The SMC calling convention says el3 does not need to
55     * preserve x8 (return value ptr). The aarch64 calling convention (AAPCS64)
56     * says x8 is caller-saved even when used as the return value pointer.
57     */
58    push    x19, lr
59    mov     x19, x8 /* preserve return value pointer in x19  */
60
61    mov     x8,  xzr
62    mov     x9,  xzr
63    mov     x10, xzr
64    mov     x11, xzr
65    mov     x12, xzr
66    mov     x13, xzr
67    mov     x14, xzr
68    mov     x15, xzr
69    mov     x16, xzr
70    mov     x17, xzr
71
72    \instr  #0
73
74    /* Copy 8-register smc return value plus x8-x17 into struct smc_ret18 */
75    stp     x0,  x1,  [x19], #16
76    stp     x2,  x3,  [x19], #16
77    stp     x4,  x5,  [x19], #16
78    stp     x6,  x7,  [x19], #16
79    stp     x8,  x9,  [x19], #16
80    stp     x10, x11, [x19], #16
81    stp     x12, x13, [x19], #16
82    stp     x14, x15, [x19], #16
83    stp     x16, x17, [x19], #16
84
85    pop     x19, lr
86
87    ret
88.endm
89
90FUNCTION(smc8_ret18)
91    smc8_hvc8_ret18 smc
92
93FUNCTION(hvc8_ret18)
94    smc8_hvc8_ret18 hvc
95
96.macro smc18_hvc18, instr
97    push x19, lr
98    mov  x19, x8
99
100    ldp x8,  x9,  [sp, #16]
101    ldp x10, x11, [sp, #32]
102    ldp x12, x13, [sp, #48]
103    ldp x14, x15, [sp, #64]
104    ldp x16, x17, [sp, #80]
105
106    \instr  #0
107
108    stp     x0,  x1,  [x19], #16
109    stp     x2,  x3,  [x19], #16
110    stp     x4,  x5,  [x19], #16
111    stp     x6,  x7,  [x19], #16
112    stp     x8,  x9,  [x19], #16
113    stp     x10, x11, [x19], #16
114    stp     x12, x13, [x19], #16
115    stp     x14, x15, [x19], #16
116    stp     x16, x17, [x19], #16
117
118    pop     x19, lr
119
120    ret
121.endm
122
123FUNCTION(smc18)
124    smc18_hvc18 smc
125
126FUNCTION(hvc18)
127    smc18_hvc18 hvc
128