• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1# Copyright 2014 The Chromium Authors. All rights reserved.
2# Use of this source code is governed by a BSD-style license that can be
3# found in the LICENSE file.
4
5import("//third_party/WebKit/Source/modules/modules.gni")
6import("//third_party/WebKit/Source/bindings/core/core.gni")
7import("//third_party/WebKit/Source/bindings/modules/modules.gni")
8import("//third_party/WebKit/Source/bindings/scripts/scripts.gni")
9import("//third_party/WebKit/Source/build/scripts/scripts.gni")
10
11visibility = [ "//third_party/WebKit/*" ]
12
13# GYP version: Source/bindings/modules/generated.gyp:bindings_modules_generated
14group("bindings_modules_generated") {
15  deps = [
16    ":modules_bindings_generated_event_interfaces",
17    ":bindings_modules_generated_event_modules_factory",
18    ":bindings_modules_generated_event_modules_names",
19    ":bindings_modules_generated_event_target_modules_names",
20  ]
21}
22
23# GYP version: event_interfaces action in bindings_modules_generated
24generate_event_interfaces("modules_bindings_generated_event_interfaces") {
25  sources = modules_event_idl_files
26  output_file = "EventModulesInterfaces.in"
27  suffix = "Modules"
28}
29
30# GYP version: EventModulesFactory action in bindings_modules_generated
31make_event_factory("bindings_modules_generated_event_modules_factory") {
32  in_files = [
33    "$root_gen_dir/blink/EventModulesInterfaces.in",
34  ]
35  outputs = [
36    "$blink_modules_output_dir/EventModules.cpp",
37    "$blink_modules_output_dir/EventModulesHeaders.h",
38  ]
39}
40
41# GYP version: EventModulesNames action in bindings_modules_generated
42make_names("bindings_modules_generated_event_modules_names") {
43  in_files = [
44    "$root_gen_dir/blink/EventModulesInterfaces.in",
45  ]
46  outputs = [
47    "$blink_modules_output_dir/EventModulesNames.cpp",
48    "$blink_modules_output_dir/EventModulesNames.h",
49  ]
50}
51
52# GYP version: EventTargetModulesNames action in bindings_modules_generated
53make_names("bindings_modules_generated_event_target_modules_names") {
54  in_files = [
55    "../../modules/EventTargetModulesFactory.in",
56  ]
57  outputs = [
58    "$blink_modules_output_dir/EventTargetModulesNames.cpp",
59    "$blink_modules_output_dir/EventTargetModulesNames.h",
60  ]
61}
62
63# ------------------------------------------------------------------------------
64
65# GYP version: Source/bindings/modules/generated.gyp:interfaces_info_individual_modules
66compute_interfaces_info_individual("interfaces_info_individual_modules") {
67  sources_static = modules_static_idl_files
68  # No generated files currently, will add with constructors
69  sources_generated = []
70  output_file =
71    "$bindings_modules_output_dir/InterfacesInfoModulesIndividual.pickle"
72}
73
74# GYP version: Source/bindings/modules/generated.gyp:interfaces_info
75action("interfaces_info") {
76  script = "$bindings_scripts_dir/compute_interfaces_info_overall.py"
77
78  inputs = [
79    "$bindings_core_output_dir/InterfacesInfoCoreIndividual.pickle",
80    "$bindings_modules_output_dir/InterfacesInfoModulesIndividual.pickle",
81  ]
82  outputs = [
83    "$bindings_modules_output_dir/InterfacesInfoModules.pickle",
84  ]
85
86  args = [
87    "--write-file-only-if-changed=1",
88    "--",
89    rebase_path(
90        "$bindings_core_output_dir/InterfacesInfoCoreIndividual.pickle",
91        root_build_dir),
92    rebase_path(
93        "$bindings_modules_output_dir/InterfacesInfoModulesIndividual.pickle",
94        root_build_dir),
95    rebase_path(
96        "$bindings_modules_output_dir/InterfacesInfoModules.pickle",
97        root_build_dir),
98  ]
99
100  deps = [
101    ":interfaces_info_individual_modules",
102    "//third_party/WebKit/Source/bindings/core:interfaces_info_individual_core",
103  ]
104}
105