• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1/* SPDX-License-Identifier: GPL-2.0-only */
2/*
3 * GNU linker script for the VDSO library.
4*
5 * Copyright (C) 2012 ARM Limited
6 *
7 * Author: Will Deacon <will.deacon@arm.com>
8 * Heavily based on the vDSO linker scripts for other archs.
9 */
10
11#include <linux/const.h>
12#include <asm/page.h>
13#include <asm/vdso.h>
14
15OUTPUT_FORMAT("elf64-littleaarch64", "elf64-bigaarch64", "elf64-littleaarch64")
16OUTPUT_ARCH(aarch64)
17
18SECTIONS
19{
20	PROVIDE(_vdso_data = . - __VVAR_PAGES * PAGE_SIZE);
21#ifdef CONFIG_TIME_NS
22	PROVIDE(_timens_data = _vdso_data + PAGE_SIZE);
23#endif
24	. = VDSO_LBASE + SIZEOF_HEADERS;
25
26	.hash		: { *(.hash) }			:text
27	.gnu.hash	: { *(.gnu.hash) }
28	.dynsym		: { *(.dynsym) }
29	.dynstr		: { *(.dynstr) }
30	.gnu.version	: { *(.gnu.version) }
31	.gnu.version_d	: { *(.gnu.version_d) }
32	.gnu.version_r	: { *(.gnu.version_r) }
33
34	/*
35	 * Discard .note.gnu.property sections which are unused and have
36	 * different alignment requirement from vDSO note sections.
37	 */
38	/DISCARD/	: {
39		*(.note.GNU-stack .note.gnu.property)
40	}
41	.note		: { *(.note.*) }		:text	:note
42
43	. = ALIGN(16);
44
45	.text		: { *(.text*) }			:text	=0xd503201f
46	PROVIDE (__etext = .);
47	PROVIDE (_etext = .);
48	PROVIDE (etext = .);
49
50	.eh_frame_hdr	: { *(.eh_frame_hdr) }		:text	:eh_frame_hdr
51	.eh_frame	: { KEEP (*(.eh_frame)) }	:text
52
53	.dynamic	: { *(.dynamic) }		:text	:dynamic
54
55	.rodata		: { *(.rodata*) }		:text
56
57	_end = .;
58	PROVIDE(end = .);
59
60	/DISCARD/	: {
61		*(.data .data.* .gnu.linkonce.d.* .sdata*)
62		*(.bss .sbss .dynbss .dynsbss)
63	}
64}
65
66/*
67 * We must supply the ELF program headers explicitly to get just one
68 * PT_LOAD segment, and set the flags explicitly to make segments read-only.
69 */
70PHDRS
71{
72	text		PT_LOAD		FLAGS(5) FILEHDR PHDRS; /* PF_R|PF_X */
73	dynamic		PT_DYNAMIC	FLAGS(4);		/* PF_R */
74	note		PT_NOTE		FLAGS(4);		/* PF_R */
75	eh_frame_hdr	PT_GNU_EH_FRAME;
76}
77
78/*
79 * This controls what symbols we export from the DSO.
80 */
81VERSION
82{
83	LINUX_2.6.39 {
84	global:
85		__kernel_rt_sigreturn;
86		__kernel_gettimeofday;
87		__kernel_clock_gettime;
88		__kernel_clock_getres;
89	local: *;
90	};
91}
92
93/*
94 * Make the sigreturn code visible to the kernel.
95 */
96VDSO_sigtramp		= __kernel_rt_sigreturn;
97