• Home
  • Line#
  • Scopes#
  • Navigate#
  • Raw
  • Download
1#!/usr/bin/env perl
2# SPDX-License-Identifier: GPL-2.0
3
4use warnings;
5use strict;
6
7## Copyright (c) 1998 Michael Zucchi, All Rights Reserved        ##
8## Copyright (C) 2000, 1  Tim Waugh <twaugh@redhat.com>          ##
9## Copyright (C) 2001  Simon Huggins                             ##
10## Copyright (C) 2005-2012  Randy Dunlap                         ##
11## Copyright (C) 2012  Dan Luedtke                               ##
12## 								 ##
13## #define enhancements by Armin Kuster <akuster@mvista.com>	 ##
14## Copyright (c) 2000 MontaVista Software, Inc.			 ##
15## 								 ##
16## This software falls under the GNU General Public License.     ##
17## Please read the COPYING file for more information             ##
18
19# 18/01/2001 - 	Cleanups
20# 		Functions prototyped as foo(void) same as foo()
21# 		Stop eval'ing where we don't need to.
22# -- huggie@earth.li
23
24# 27/06/2001 -  Allowed whitespace after initial "/**" and
25#               allowed comments before function declarations.
26# -- Christian Kreibich <ck@whoop.org>
27
28# Still to do:
29# 	- add perldoc documentation
30# 	- Look more closely at some of the scarier bits :)
31
32# 26/05/2001 - 	Support for separate source and object trees.
33#		Return error code.
34# 		Keith Owens <kaos@ocs.com.au>
35
36# 23/09/2001 - Added support for typedefs, structs, enums and unions
37#              Support for Context section; can be terminated using empty line
38#              Small fixes (like spaces vs. \s in regex)
39# -- Tim Jansen <tim@tjansen.de>
40
41# 25/07/2012 - Added support for HTML5
42# -- Dan Luedtke <mail@danrl.de>
43
44sub usage {
45    my $message = <<"EOF";
46Usage: $0 [OPTION ...] FILE ...
47
48Read C language source or header FILEs, extract embedded documentation comments,
49and print formatted documentation to standard output.
50
51The documentation comments are identified by "/**" opening comment mark. See
52Documentation/doc-guide/kernel-doc.rst for the documentation comment syntax.
53
54Output format selection (mutually exclusive):
55  -man			Output troff manual page format. This is the default.
56  -rst			Output reStructuredText format.
57  -none			Do not output documentation, only warnings.
58
59Output format selection modifier (affects only ReST output):
60
61  -sphinx-version	Use the ReST C domain dialect compatible with an
62			specific Sphinx Version.
63			If not specified, kernel-doc will auto-detect using
64			the sphinx-build version found on PATH.
65
66Output selection (mutually exclusive):
67  -export		Only output documentation for symbols that have been
68			exported using EXPORT_SYMBOL() or EXPORT_SYMBOL_GPL()
69                        in any input FILE or -export-file FILE.
70  -internal		Only output documentation for symbols that have NOT been
71			exported using EXPORT_SYMBOL() or EXPORT_SYMBOL_GPL()
72                        in any input FILE or -export-file FILE.
73  -function NAME	Only output documentation for the given function(s)
74			or DOC: section title(s). All other functions and DOC:
75			sections are ignored. May be specified multiple times.
76  -nosymbol NAME	Exclude the specified symbols from the output
77		        documentation. May be specified multiple times.
78
79Output selection modifiers:
80  -no-doc-sections	Do not output DOC: sections.
81  -enable-lineno        Enable output of #define LINENO lines. Only works with
82                        reStructuredText format.
83  -export-file FILE     Specify an additional FILE in which to look for
84                        EXPORT_SYMBOL() and EXPORT_SYMBOL_GPL(). To be used with
85                        -export or -internal. May be specified multiple times.
86
87Other parameters:
88  -v			Verbose output, more warnings and other information.
89  -h			Print this help.
90  -Werror		Treat warnings as errors.
91
92EOF
93    print $message;
94    exit 1;
95}
96
97#
98# format of comments.
99# In the following table, (...)? signifies optional structure.
100#                         (...)* signifies 0 or more structure elements
101# /**
102#  * function_name(:)? (- short description)?
103# (* @parameterx: (description of parameter x)?)*
104# (* a blank line)?
105#  * (Description:)? (Description of function)?
106#  * (section header: (section description)? )*
107#  (*)?*/
108#
109# So .. the trivial example would be:
110#
111# /**
112#  * my_function
113#  */
114#
115# If the Description: header tag is omitted, then there must be a blank line
116# after the last parameter specification.
117# e.g.
118# /**
119#  * my_function - does my stuff
120#  * @my_arg: its mine damnit
121#  *
122#  * Does my stuff explained.
123#  */
124#
125#  or, could also use:
126# /**
127#  * my_function - does my stuff
128#  * @my_arg: its mine damnit
129#  * Description: Does my stuff explained.
130#  */
131# etc.
132#
133# Besides functions you can also write documentation for structs, unions,
134# enums and typedefs. Instead of the function name you must write the name
135# of the declaration;  the struct/union/enum/typedef must always precede
136# the name. Nesting of declarations is not supported.
137# Use the argument mechanism to document members or constants.
138# e.g.
139# /**
140#  * struct my_struct - short description
141#  * @a: first member
142#  * @b: second member
143#  *
144#  * Longer description
145#  */
146# struct my_struct {
147#     int a;
148#     int b;
149# /* private: */
150#     int c;
151# };
152#
153# All descriptions can be multiline, except the short function description.
154#
155# For really longs structs, you can also describe arguments inside the
156# body of the struct.
157# eg.
158# /**
159#  * struct my_struct - short description
160#  * @a: first member
161#  * @b: second member
162#  *
163#  * Longer description
164#  */
165# struct my_struct {
166#     int a;
167#     int b;
168#     /**
169#      * @c: This is longer description of C
170#      *
171#      * You can use paragraphs to describe arguments
172#      * using this method.
173#      */
174#     int c;
175# };
176#
177# This should be use only for struct/enum members.
178#
179# You can also add additional sections. When documenting kernel functions you
180# should document the "Context:" of the function, e.g. whether the functions
181# can be called form interrupts. Unlike other sections you can end it with an
182# empty line.
183# A non-void function should have a "Return:" section describing the return
184# value(s).
185# Example-sections should contain the string EXAMPLE so that they are marked
186# appropriately in DocBook.
187#
188# Example:
189# /**
190#  * user_function - function that can only be called in user context
191#  * @a: some argument
192#  * Context: !in_interrupt()
193#  *
194#  * Some description
195#  * Example:
196#  *    user_function(22);
197#  */
198# ...
199#
200#
201# All descriptive text is further processed, scanning for the following special
202# patterns, which are highlighted appropriately.
203#
204# 'funcname()' - function
205# '$ENVVAR' - environmental variable
206# '&struct_name' - name of a structure (up to two words including 'struct')
207# '&struct_name.member' - name of a structure member
208# '@parameter' - name of a parameter
209# '%CONST' - name of a constant.
210# '``LITERAL``' - literal string without any spaces on it.
211
212## init lots of data
213
214my $errors = 0;
215my $warnings = 0;
216my $anon_struct_union = 0;
217
218# match expressions used to find embedded type information
219my $type_constant = '\b``([^\`]+)``\b';
220my $type_constant2 = '\%([-_\w]+)';
221my $type_func = '(\w+)\(\)';
222my $type_param = '\@(\w*((\.\w+)|(->\w+))*(\.\.\.)?)';
223my $type_param_ref = '([\!]?)\@(\w*((\.\w+)|(->\w+))*(\.\.\.)?)';
224my $type_fp_param = '\@(\w+)\(\)';  # Special RST handling for func ptr params
225my $type_fp_param2 = '\@(\w+->\S+)\(\)';  # Special RST handling for structs with func ptr params
226my $type_env = '(\$\w+)';
227my $type_enum = '\&(enum\s*([_\w]+))';
228my $type_struct = '\&(struct\s*([_\w]+))';
229my $type_typedef = '\&(typedef\s*([_\w]+))';
230my $type_union = '\&(union\s*([_\w]+))';
231my $type_member = '\&([_\w]+)(\.|->)([_\w]+)';
232my $type_fallback = '\&([_\w]+)';
233my $type_member_func = $type_member . '\(\)';
234
235# Output conversion substitutions.
236#  One for each output format
237
238# these are pretty rough
239my @highlights_man = (
240                      [$type_constant, "\$1"],
241                      [$type_constant2, "\$1"],
242                      [$type_func, "\\\\fB\$1\\\\fP"],
243                      [$type_enum, "\\\\fI\$1\\\\fP"],
244                      [$type_struct, "\\\\fI\$1\\\\fP"],
245                      [$type_typedef, "\\\\fI\$1\\\\fP"],
246                      [$type_union, "\\\\fI\$1\\\\fP"],
247                      [$type_param, "\\\\fI\$1\\\\fP"],
248                      [$type_param_ref, "\\\\fI\$1\$2\\\\fP"],
249                      [$type_member, "\\\\fI\$1\$2\$3\\\\fP"],
250                      [$type_fallback, "\\\\fI\$1\\\\fP"]
251		     );
252my $blankline_man = "";
253
254# rst-mode
255my @highlights_rst = (
256                       [$type_constant, "``\$1``"],
257                       [$type_constant2, "``\$1``"],
258                       # Note: need to escape () to avoid func matching later
259                       [$type_member_func, "\\:c\\:type\\:`\$1\$2\$3\\\\(\\\\) <\$1>`"],
260                       [$type_member, "\\:c\\:type\\:`\$1\$2\$3 <\$1>`"],
261		       [$type_fp_param, "**\$1\\\\(\\\\)**"],
262		       [$type_fp_param2, "**\$1\\\\(\\\\)**"],
263                       [$type_func, "\$1()"],
264                       [$type_enum, "\\:c\\:type\\:`\$1 <\$2>`"],
265                       [$type_struct, "\\:c\\:type\\:`\$1 <\$2>`"],
266                       [$type_typedef, "\\:c\\:type\\:`\$1 <\$2>`"],
267                       [$type_union, "\\:c\\:type\\:`\$1 <\$2>`"],
268                       # in rst this can refer to any type
269                       [$type_fallback, "\\:c\\:type\\:`\$1`"],
270                       [$type_param_ref, "**\$1\$2**"]
271		      );
272my $blankline_rst = "\n";
273
274# read arguments
275if ($#ARGV == -1) {
276    usage();
277}
278
279my $kernelversion;
280my ($sphinx_major, $sphinx_minor, $sphinx_patch);
281
282my $dohighlight = "";
283
284my $verbose = 0;
285my $Werror = 0;
286my $output_mode = "rst";
287my $output_preformatted = 0;
288my $no_doc_sections = 0;
289my $enable_lineno = 0;
290my @highlights = @highlights_rst;
291my $blankline = $blankline_rst;
292my $modulename = "Kernel API";
293
294use constant {
295    OUTPUT_ALL          => 0, # output all symbols and doc sections
296    OUTPUT_INCLUDE      => 1, # output only specified symbols
297    OUTPUT_EXPORTED     => 2, # output exported symbols
298    OUTPUT_INTERNAL     => 3, # output non-exported symbols
299};
300my $output_selection = OUTPUT_ALL;
301my $show_not_found = 0;	# No longer used
302
303my @export_file_list;
304
305my @build_time;
306if (defined($ENV{'KBUILD_BUILD_TIMESTAMP'}) &&
307    (my $seconds = `date -d"${ENV{'KBUILD_BUILD_TIMESTAMP'}}" +%s`) ne '') {
308    @build_time = gmtime($seconds);
309} else {
310    @build_time = localtime;
311}
312
313my $man_date = ('January', 'February', 'March', 'April', 'May', 'June',
314		'July', 'August', 'September', 'October',
315		'November', 'December')[$build_time[4]] .
316  " " . ($build_time[5]+1900);
317
318# Essentially these are globals.
319# They probably want to be tidied up, made more localised or something.
320# CAVEAT EMPTOR!  Some of the others I localised may not want to be, which
321# could cause "use of undefined value" or other bugs.
322my ($function, %function_table, %parametertypes, $declaration_purpose);
323my %nosymbol_table = ();
324my $declaration_start_line;
325my ($type, $declaration_name, $return_type);
326my ($newsection, $newcontents, $prototype, $brcount, %source_map);
327
328if (defined($ENV{'KBUILD_VERBOSE'})) {
329	$verbose = "$ENV{'KBUILD_VERBOSE'}";
330}
331
332if (defined($ENV{'KDOC_WERROR'})) {
333	$Werror = "$ENV{'KDOC_WERROR'}";
334}
335
336if (defined($ENV{'KCFLAGS'})) {
337	my $kcflags = "$ENV{'KCFLAGS'}";
338
339	if ($kcflags =~ /Werror/) {
340		$Werror = 1;
341	}
342}
343
344# Generated docbook code is inserted in a template at a point where
345# docbook v3.1 requires a non-zero sequence of RefEntry's; see:
346# https://www.oasis-open.org/docbook/documentation/reference/html/refentry.html
347# We keep track of number of generated entries and generate a dummy
348# if needs be to ensure the expanded template can be postprocessed
349# into html.
350my $section_counter = 0;
351
352my $lineprefix="";
353
354# Parser states
355use constant {
356    STATE_NORMAL        => 0,        # normal code
357    STATE_NAME          => 1,        # looking for function name
358    STATE_BODY_MAYBE    => 2,        # body - or maybe more description
359    STATE_BODY          => 3,        # the body of the comment
360    STATE_BODY_WITH_BLANK_LINE => 4, # the body, which has a blank line
361    STATE_PROTO         => 5,        # scanning prototype
362    STATE_DOCBLOCK      => 6,        # documentation block
363    STATE_INLINE        => 7,        # gathering doc outside main block
364};
365my $state;
366my $in_doc_sect;
367my $leading_space;
368
369# Inline documentation state
370use constant {
371    STATE_INLINE_NA     => 0, # not applicable ($state != STATE_INLINE)
372    STATE_INLINE_NAME   => 1, # looking for member name (@foo:)
373    STATE_INLINE_TEXT   => 2, # looking for member documentation
374    STATE_INLINE_END    => 3, # done
375    STATE_INLINE_ERROR  => 4, # error - Comment without header was found.
376                              # Spit a warning as it's not
377                              # proper kernel-doc and ignore the rest.
378};
379my $inline_doc_state;
380
381#declaration types: can be
382# 'function', 'struct', 'union', 'enum', 'typedef'
383my $decl_type;
384
385my $doc_start = '^/\*\*\s*$'; # Allow whitespace at end of comment start.
386my $doc_end = '\*/';
387my $doc_com = '\s*\*\s*';
388my $doc_com_body = '\s*\* ?';
389my $doc_decl = $doc_com . '(\w+)';
390# @params and a strictly limited set of supported section names
391my $doc_sect = $doc_com .
392    '\s*(\@[.\w]+|\@\.\.\.|description|context|returns?|notes?|examples?)\s*:(.*)';
393my $doc_content = $doc_com_body . '(.*)';
394my $doc_block = $doc_com . 'DOC:\s*(.*)?';
395my $doc_inline_start = '^\s*/\*\*\s*$';
396my $doc_inline_sect = '\s*\*\s*(@\s*[\w][\w\.]*\s*):(.*)';
397my $doc_inline_end = '^\s*\*/\s*$';
398my $doc_inline_oneline = '^\s*/\*\*\s*(@[\w\s]+):\s*(.*)\s*\*/\s*$';
399my $export_symbol = '^\s*EXPORT_SYMBOL(_GPL)?\s*\(\s*(\w+)\s*\)\s*;';
400
401my %parameterdescs;
402my %parameterdesc_start_lines;
403my @parameterlist;
404my %sections;
405my @sectionlist;
406my %section_start_lines;
407my $sectcheck;
408my $struct_actual;
409
410my $contents = "";
411my $new_start_line = 0;
412
413# the canonical section names. see also $doc_sect above.
414my $section_default = "Description";	# default section
415my $section_intro = "Introduction";
416my $section = $section_default;
417my $section_context = "Context";
418my $section_return = "Return";
419
420my $undescribed = "-- undescribed --";
421
422reset_state();
423
424while ($ARGV[0] =~ m/^--?(.*)/) {
425    my $cmd = $1;
426    shift @ARGV;
427    if ($cmd eq "man") {
428	$output_mode = "man";
429	@highlights = @highlights_man;
430	$blankline = $blankline_man;
431    } elsif ($cmd eq "rst") {
432	$output_mode = "rst";
433	@highlights = @highlights_rst;
434	$blankline = $blankline_rst;
435    } elsif ($cmd eq "none") {
436	$output_mode = "none";
437    } elsif ($cmd eq "module") { # not needed for XML, inherits from calling document
438	$modulename = shift @ARGV;
439    } elsif ($cmd eq "function") { # to only output specific functions
440	$output_selection = OUTPUT_INCLUDE;
441	$function = shift @ARGV;
442	$function_table{$function} = 1;
443    } elsif ($cmd eq "nosymbol") { # Exclude specific symbols
444	my $symbol = shift @ARGV;
445	$nosymbol_table{$symbol} = 1;
446    } elsif ($cmd eq "export") { # only exported symbols
447	$output_selection = OUTPUT_EXPORTED;
448	%function_table = ();
449    } elsif ($cmd eq "internal") { # only non-exported symbols
450	$output_selection = OUTPUT_INTERNAL;
451	%function_table = ();
452    } elsif ($cmd eq "export-file") {
453	my $file = shift @ARGV;
454	push(@export_file_list, $file);
455    } elsif ($cmd eq "v") {
456	$verbose = 1;
457    } elsif ($cmd eq "Werror") {
458	$Werror = 1;
459    } elsif (($cmd eq "h") || ($cmd eq "help")) {
460	usage();
461    } elsif ($cmd eq 'no-doc-sections') {
462	    $no_doc_sections = 1;
463    } elsif ($cmd eq 'enable-lineno') {
464	    $enable_lineno = 1;
465    } elsif ($cmd eq 'show-not-found') {
466	$show_not_found = 1;  # A no-op but don't fail
467    } elsif ($cmd eq "sphinx-version") {
468	my $ver_string = shift @ARGV;
469	if ($ver_string =~ m/^(\d+)(\.\d+)?(\.\d+)?/) {
470	    $sphinx_major = $1;
471	    if (defined($2)) {
472		$sphinx_minor = substr($2,1);
473	    } else {
474		$sphinx_minor = 0;
475	    }
476	    if (defined($3)) {
477		$sphinx_patch = substr($3,1)
478	    } else {
479		$sphinx_patch = 0;
480	    }
481	} else {
482	    die "Sphinx version should either major.minor or major.minor.patch format\n";
483	}
484    } else {
485	# Unknown argument
486        usage();
487    }
488}
489
490# continue execution near EOF;
491
492# The C domain dialect changed on Sphinx 3. So, we need to check the
493# version in order to produce the right tags.
494sub findprog($)
495{
496	foreach(split(/:/, $ENV{PATH})) {
497		return "$_/$_[0]" if(-x "$_/$_[0]");
498	}
499}
500
501sub get_sphinx_version()
502{
503	my $ver;
504
505	my $cmd = "sphinx-build";
506	if (!findprog($cmd)) {
507		my $cmd = "sphinx-build3";
508		if (!findprog($cmd)) {
509			$sphinx_major = 1;
510			$sphinx_minor = 2;
511			$sphinx_patch = 0;
512			printf STDERR "Warning: Sphinx version not found. Using default (Sphinx version %d.%d.%d)\n",
513			       $sphinx_major, $sphinx_minor, $sphinx_patch;
514			return;
515		}
516	}
517
518	open IN, "$cmd --version 2>&1 |";
519	while (<IN>) {
520		if (m/^\s*sphinx-build\s+([\d]+)\.([\d\.]+)(\+\/[\da-f]+)?$/) {
521			$sphinx_major = $1;
522			$sphinx_minor = $2;
523			$sphinx_patch = $3;
524			last;
525		}
526		# Sphinx 1.2.x uses a different format
527		if (m/^\s*Sphinx.*\s+([\d]+)\.([\d\.]+)$/) {
528			$sphinx_major = $1;
529			$sphinx_minor = $2;
530			$sphinx_patch = $3;
531			last;
532		}
533	}
534	close IN;
535}
536
537# get kernel version from env
538sub get_kernel_version() {
539    my $version = 'unknown kernel version';
540
541    if (defined($ENV{'KERNELVERSION'})) {
542	$version = $ENV{'KERNELVERSION'};
543    }
544    return $version;
545}
546
547#
548sub print_lineno {
549    my $lineno = shift;
550    if ($enable_lineno && defined($lineno)) {
551        print "#define LINENO " . $lineno . "\n";
552    }
553}
554##
555# dumps section contents to arrays/hashes intended for that purpose.
556#
557sub dump_section {
558    my $file = shift;
559    my $name = shift;
560    my $contents = join "\n", @_;
561
562    if ($name =~ m/$type_param/) {
563	$name = $1;
564	$parameterdescs{$name} = $contents;
565	$sectcheck = $sectcheck . $name . " ";
566        $parameterdesc_start_lines{$name} = $new_start_line;
567        $new_start_line = 0;
568    } elsif ($name eq "@\.\.\.") {
569	$name = "...";
570	$parameterdescs{$name} = $contents;
571	$sectcheck = $sectcheck . $name . " ";
572        $parameterdesc_start_lines{$name} = $new_start_line;
573        $new_start_line = 0;
574    } else {
575	if (defined($sections{$name}) && ($sections{$name} ne "")) {
576	    # Only warn on user specified duplicate section names.
577	    if ($name ne $section_default) {
578		print STDERR "${file}:$.: warning: duplicate section name '$name'\n";
579		++$warnings;
580	    }
581	    $sections{$name} .= $contents;
582	} else {
583	    $sections{$name} = $contents;
584	    push @sectionlist, $name;
585            $section_start_lines{$name} = $new_start_line;
586            $new_start_line = 0;
587	}
588    }
589}
590
591##
592# dump DOC: section after checking that it should go out
593#
594sub dump_doc_section {
595    my $file = shift;
596    my $name = shift;
597    my $contents = join "\n", @_;
598
599    if ($no_doc_sections) {
600        return;
601    }
602
603    return if (defined($nosymbol_table{$name}));
604
605    if (($output_selection == OUTPUT_ALL) ||
606	(($output_selection == OUTPUT_INCLUDE) &&
607	 defined($function_table{$name})))
608    {
609	dump_section($file, $name, $contents);
610	output_blockhead({'sectionlist' => \@sectionlist,
611			  'sections' => \%sections,
612			  'module' => $modulename,
613			  'content-only' => ($output_selection != OUTPUT_ALL), });
614    }
615}
616
617##
618# output function
619#
620# parameterdescs, a hash.
621#  function => "function name"
622#  parameterlist => @list of parameters
623#  parameterdescs => %parameter descriptions
624#  sectionlist => @list of sections
625#  sections => %section descriptions
626#
627
628sub output_highlight {
629    my $contents = join "\n",@_;
630    my $line;
631
632#   DEBUG
633#   if (!defined $contents) {
634#	use Carp;
635#	confess "output_highlight got called with no args?\n";
636#   }
637
638#   print STDERR "contents b4:$contents\n";
639    eval $dohighlight;
640    die $@ if $@;
641#   print STDERR "contents af:$contents\n";
642
643    foreach $line (split "\n", $contents) {
644	if (! $output_preformatted) {
645	    $line =~ s/^\s*//;
646	}
647	if ($line eq ""){
648	    if (! $output_preformatted) {
649		print $lineprefix, $blankline;
650	    }
651	} else {
652	    if ($output_mode eq "man" && substr($line, 0, 1) eq ".") {
653		print "\\&$line";
654	    } else {
655		print $lineprefix, $line;
656	    }
657	}
658	print "\n";
659    }
660}
661
662##
663# output function in man
664sub output_function_man(%) {
665    my %args = %{$_[0]};
666    my ($parameter, $section);
667    my $count;
668
669    print ".TH \"$args{'function'}\" 9 \"$args{'function'}\" \"$man_date\" \"Kernel Hacker's Manual\" LINUX\n";
670
671    print ".SH NAME\n";
672    print $args{'function'} . " \\- " . $args{'purpose'} . "\n";
673
674    print ".SH SYNOPSIS\n";
675    if ($args{'functiontype'} ne "") {
676	print ".B \"" . $args{'functiontype'} . "\" " . $args{'function'} . "\n";
677    } else {
678	print ".B \"" . $args{'function'} . "\n";
679    }
680    $count = 0;
681    my $parenth = "(";
682    my $post = ",";
683    foreach my $parameter (@{$args{'parameterlist'}}) {
684	if ($count == $#{$args{'parameterlist'}}) {
685	    $post = ");";
686	}
687	$type = $args{'parametertypes'}{$parameter};
688	if ($type =~ m/([^\(]*\(\*)\s*\)\s*\(([^\)]*)\)/) {
689	    # pointer-to-function
690	    print ".BI \"" . $parenth . $1 . "\" " . " \") (" . $2 . ")" . $post . "\"\n";
691	} else {
692	    $type =~ s/([^\*])$/$1 /;
693	    print ".BI \"" . $parenth . $type . "\" " . " \"" . $post . "\"\n";
694	}
695	$count++;
696	$parenth = "";
697    }
698
699    print ".SH ARGUMENTS\n";
700    foreach $parameter (@{$args{'parameterlist'}}) {
701	my $parameter_name = $parameter;
702	$parameter_name =~ s/\[.*//;
703
704	print ".IP \"" . $parameter . "\" 12\n";
705	output_highlight($args{'parameterdescs'}{$parameter_name});
706    }
707    foreach $section (@{$args{'sectionlist'}}) {
708	print ".SH \"", uc $section, "\"\n";
709	output_highlight($args{'sections'}{$section});
710    }
711}
712
713##
714# output enum in man
715sub output_enum_man(%) {
716    my %args = %{$_[0]};
717    my ($parameter, $section);
718    my $count;
719
720    print ".TH \"$args{'module'}\" 9 \"enum $args{'enum'}\" \"$man_date\" \"API Manual\" LINUX\n";
721
722    print ".SH NAME\n";
723    print "enum " . $args{'enum'} . " \\- " . $args{'purpose'} . "\n";
724
725    print ".SH SYNOPSIS\n";
726    print "enum " . $args{'enum'} . " {\n";
727    $count = 0;
728    foreach my $parameter (@{$args{'parameterlist'}}) {
729	print ".br\n.BI \"    $parameter\"\n";
730	if ($count == $#{$args{'parameterlist'}}) {
731	    print "\n};\n";
732	    last;
733	}
734	else {
735	    print ", \n.br\n";
736	}
737	$count++;
738    }
739
740    print ".SH Constants\n";
741    foreach $parameter (@{$args{'parameterlist'}}) {
742	my $parameter_name = $parameter;
743	$parameter_name =~ s/\[.*//;
744
745	print ".IP \"" . $parameter . "\" 12\n";
746	output_highlight($args{'parameterdescs'}{$parameter_name});
747    }
748    foreach $section (@{$args{'sectionlist'}}) {
749	print ".SH \"$section\"\n";
750	output_highlight($args{'sections'}{$section});
751    }
752}
753
754##
755# output struct in man
756sub output_struct_man(%) {
757    my %args = %{$_[0]};
758    my ($parameter, $section);
759
760    print ".TH \"$args{'module'}\" 9 \"" . $args{'type'} . " " . $args{'struct'} . "\" \"$man_date\" \"API Manual\" LINUX\n";
761
762    print ".SH NAME\n";
763    print $args{'type'} . " " . $args{'struct'} . " \\- " . $args{'purpose'} . "\n";
764
765    my $declaration = $args{'definition'};
766    $declaration =~ s/\t/  /g;
767    $declaration =~ s/\n/"\n.br\n.BI \"/g;
768    print ".SH SYNOPSIS\n";
769    print $args{'type'} . " " . $args{'struct'} . " {\n.br\n";
770    print ".BI \"$declaration\n};\n.br\n\n";
771
772    print ".SH Members\n";
773    foreach $parameter (@{$args{'parameterlist'}}) {
774	($parameter =~ /^#/) && next;
775
776	my $parameter_name = $parameter;
777	$parameter_name =~ s/\[.*//;
778
779	($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
780	print ".IP \"" . $parameter . "\" 12\n";
781	output_highlight($args{'parameterdescs'}{$parameter_name});
782    }
783    foreach $section (@{$args{'sectionlist'}}) {
784	print ".SH \"$section\"\n";
785	output_highlight($args{'sections'}{$section});
786    }
787}
788
789##
790# output typedef in man
791sub output_typedef_man(%) {
792    my %args = %{$_[0]};
793    my ($parameter, $section);
794
795    print ".TH \"$args{'module'}\" 9 \"$args{'typedef'}\" \"$man_date\" \"API Manual\" LINUX\n";
796
797    print ".SH NAME\n";
798    print "typedef " . $args{'typedef'} . " \\- " . $args{'purpose'} . "\n";
799
800    foreach $section (@{$args{'sectionlist'}}) {
801	print ".SH \"$section\"\n";
802	output_highlight($args{'sections'}{$section});
803    }
804}
805
806sub output_blockhead_man(%) {
807    my %args = %{$_[0]};
808    my ($parameter, $section);
809    my $count;
810
811    print ".TH \"$args{'module'}\" 9 \"$args{'module'}\" \"$man_date\" \"API Manual\" LINUX\n";
812
813    foreach $section (@{$args{'sectionlist'}}) {
814	print ".SH \"$section\"\n";
815	output_highlight($args{'sections'}{$section});
816    }
817}
818
819##
820# output in restructured text
821#
822
823#
824# This could use some work; it's used to output the DOC: sections, and
825# starts by putting out the name of the doc section itself, but that tends
826# to duplicate a header already in the template file.
827#
828sub output_blockhead_rst(%) {
829    my %args = %{$_[0]};
830    my ($parameter, $section);
831
832    foreach $section (@{$args{'sectionlist'}}) {
833	next if (defined($nosymbol_table{$section}));
834
835	if ($output_selection != OUTPUT_INCLUDE) {
836	    print "**$section**\n\n";
837	}
838        print_lineno($section_start_lines{$section});
839	output_highlight_rst($args{'sections'}{$section});
840	print "\n";
841    }
842}
843
844#
845# Apply the RST highlights to a sub-block of text.
846#
847sub highlight_block($) {
848    # The dohighlight kludge requires the text be called $contents
849    my $contents = shift;
850    eval $dohighlight;
851    die $@ if $@;
852    return $contents;
853}
854
855#
856# Regexes used only here.
857#
858my $sphinx_literal = '^[^.].*::$';
859my $sphinx_cblock = '^\.\.\ +code-block::';
860
861sub output_highlight_rst {
862    my $input = join "\n",@_;
863    my $output = "";
864    my $line;
865    my $in_literal = 0;
866    my $litprefix;
867    my $block = "";
868
869    foreach $line (split "\n",$input) {
870	#
871	# If we're in a literal block, see if we should drop out
872	# of it.  Otherwise pass the line straight through unmunged.
873	#
874	if ($in_literal) {
875	    if (! ($line =~ /^\s*$/)) {
876		#
877		# If this is the first non-blank line in a literal
878		# block we need to figure out what the proper indent is.
879		#
880		if ($litprefix eq "") {
881		    $line =~ /^(\s*)/;
882		    $litprefix = '^' . $1;
883		    $output .= $line . "\n";
884		} elsif (! ($line =~ /$litprefix/)) {
885		    $in_literal = 0;
886		} else {
887		    $output .= $line . "\n";
888		}
889	    } else {
890		$output .= $line . "\n";
891	    }
892	}
893	#
894	# Not in a literal block (or just dropped out)
895	#
896	if (! $in_literal) {
897	    $block .= $line . "\n";
898	    if (($line =~ /$sphinx_literal/) || ($line =~ /$sphinx_cblock/)) {
899		$in_literal = 1;
900		$litprefix = "";
901		$output .= highlight_block($block);
902		$block = ""
903	    }
904	}
905    }
906
907    if ($block) {
908	$output .= highlight_block($block);
909    }
910    foreach $line (split "\n", $output) {
911	print $lineprefix . $line . "\n";
912    }
913}
914
915sub output_function_rst(%) {
916    my %args = %{$_[0]};
917    my ($parameter, $section);
918    my $oldprefix = $lineprefix;
919    my $start = "";
920    my $is_macro = 0;
921
922    if ($sphinx_major < 3) {
923	if ($args{'typedef'}) {
924	    print ".. c:type:: ". $args{'function'} . "\n\n";
925	    print_lineno($declaration_start_line);
926	    print "   **Typedef**: ";
927	    $lineprefix = "";
928	    output_highlight_rst($args{'purpose'});
929	    $start = "\n\n**Syntax**\n\n  ``";
930	    $is_macro = 1;
931	} else {
932	    print ".. c:function:: ";
933	}
934    } else {
935	if ($args{'typedef'} || $args{'functiontype'} eq "") {
936	    $is_macro = 1;
937	    print ".. c:macro:: ". $args{'function'} . "\n\n";
938	} else {
939	    print ".. c:function:: ";
940	}
941
942	if ($args{'typedef'}) {
943	    print_lineno($declaration_start_line);
944	    print "   **Typedef**: ";
945	    $lineprefix = "";
946	    output_highlight_rst($args{'purpose'});
947	    $start = "\n\n**Syntax**\n\n  ``";
948	} else {
949	    print "``" if ($is_macro);
950	}
951    }
952    if ($args{'functiontype'} ne "") {
953	$start .= $args{'functiontype'} . " " . $args{'function'} . " (";
954    } else {
955	$start .= $args{'function'} . " (";
956    }
957    print $start;
958
959    my $count = 0;
960    foreach my $parameter (@{$args{'parameterlist'}}) {
961	if ($count ne 0) {
962	    print ", ";
963	}
964	$count++;
965	$type = $args{'parametertypes'}{$parameter};
966
967	if ($type =~ m/([^\(]*\(\*)\s*\)\s*\(([^\)]*)\)/) {
968	    # pointer-to-function
969	    print $1 . $parameter . ") (" . $2 . ")";
970	} else {
971	    print $type;
972	}
973    }
974    if ($is_macro) {
975	print ")``\n\n";
976    } else {
977	print ")\n\n";
978    }
979    if (!$args{'typedef'}) {
980	print_lineno($declaration_start_line);
981	$lineprefix = "   ";
982	output_highlight_rst($args{'purpose'});
983	print "\n";
984    }
985
986    print "**Parameters**\n\n";
987    $lineprefix = "  ";
988    foreach $parameter (@{$args{'parameterlist'}}) {
989	my $parameter_name = $parameter;
990	$parameter_name =~ s/\[.*//;
991	$type = $args{'parametertypes'}{$parameter};
992
993	if ($type ne "") {
994	    print "``$type``\n";
995	} else {
996	    print "``$parameter``\n";
997	}
998
999        print_lineno($parameterdesc_start_lines{$parameter_name});
1000
1001	if (defined($args{'parameterdescs'}{$parameter_name}) &&
1002	    $args{'parameterdescs'}{$parameter_name} ne $undescribed) {
1003	    output_highlight_rst($args{'parameterdescs'}{$parameter_name});
1004	} else {
1005	    print "  *undescribed*\n";
1006	}
1007	print "\n";
1008    }
1009
1010    $lineprefix = $oldprefix;
1011    output_section_rst(@_);
1012}
1013
1014sub output_section_rst(%) {
1015    my %args = %{$_[0]};
1016    my $section;
1017    my $oldprefix = $lineprefix;
1018    $lineprefix = "";
1019
1020    foreach $section (@{$args{'sectionlist'}}) {
1021	print "**$section**\n\n";
1022        print_lineno($section_start_lines{$section});
1023	output_highlight_rst($args{'sections'}{$section});
1024	print "\n";
1025    }
1026    print "\n";
1027    $lineprefix = $oldprefix;
1028}
1029
1030sub output_enum_rst(%) {
1031    my %args = %{$_[0]};
1032    my ($parameter);
1033    my $oldprefix = $lineprefix;
1034    my $count;
1035
1036    if ($sphinx_major < 3) {
1037	my $name = "enum " . $args{'enum'};
1038	print "\n\n.. c:type:: " . $name . "\n\n";
1039    } else {
1040	my $name = $args{'enum'};
1041	print "\n\n.. c:enum:: " . $name . "\n\n";
1042    }
1043    print_lineno($declaration_start_line);
1044    $lineprefix = "   ";
1045    output_highlight_rst($args{'purpose'});
1046    print "\n";
1047
1048    print "**Constants**\n\n";
1049    $lineprefix = "  ";
1050    foreach $parameter (@{$args{'parameterlist'}}) {
1051	print "``$parameter``\n";
1052	if ($args{'parameterdescs'}{$parameter} ne $undescribed) {
1053	    output_highlight_rst($args{'parameterdescs'}{$parameter});
1054	} else {
1055	    print "  *undescribed*\n";
1056	}
1057	print "\n";
1058    }
1059
1060    $lineprefix = $oldprefix;
1061    output_section_rst(@_);
1062}
1063
1064sub output_typedef_rst(%) {
1065    my %args = %{$_[0]};
1066    my ($parameter);
1067    my $oldprefix = $lineprefix;
1068    my $name;
1069
1070    if ($sphinx_major < 3) {
1071	$name = "typedef " . $args{'typedef'};
1072    } else {
1073	$name = $args{'typedef'};
1074    }
1075    print "\n\n.. c:type:: " . $name . "\n\n";
1076    print_lineno($declaration_start_line);
1077    $lineprefix = "   ";
1078    output_highlight_rst($args{'purpose'});
1079    print "\n";
1080
1081    $lineprefix = $oldprefix;
1082    output_section_rst(@_);
1083}
1084
1085sub output_struct_rst(%) {
1086    my %args = %{$_[0]};
1087    my ($parameter);
1088    my $oldprefix = $lineprefix;
1089
1090    if ($sphinx_major < 3) {
1091	my $name = $args{'type'} . " " . $args{'struct'};
1092	print "\n\n.. c:type:: " . $name . "\n\n";
1093    } else {
1094	my $name = $args{'struct'};
1095	if ($args{'type'} eq 'union') {
1096	    print "\n\n.. c:union:: " . $name . "\n\n";
1097	} else {
1098	    print "\n\n.. c:struct:: " . $name . "\n\n";
1099	}
1100    }
1101    print_lineno($declaration_start_line);
1102    $lineprefix = "   ";
1103    output_highlight_rst($args{'purpose'});
1104    print "\n";
1105
1106    print "**Definition**\n\n";
1107    print "::\n\n";
1108    my $declaration = $args{'definition'};
1109    $declaration =~ s/\t/  /g;
1110    print "  " . $args{'type'} . " " . $args{'struct'} . " {\n$declaration  };\n\n";
1111
1112    print "**Members**\n\n";
1113    $lineprefix = "  ";
1114    foreach $parameter (@{$args{'parameterlist'}}) {
1115	($parameter =~ /^#/) && next;
1116
1117	my $parameter_name = $parameter;
1118	$parameter_name =~ s/\[.*//;
1119
1120	($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
1121	$type = $args{'parametertypes'}{$parameter};
1122        print_lineno($parameterdesc_start_lines{$parameter_name});
1123	print "``" . $parameter . "``\n";
1124	output_highlight_rst($args{'parameterdescs'}{$parameter_name});
1125	print "\n";
1126    }
1127    print "\n";
1128
1129    $lineprefix = $oldprefix;
1130    output_section_rst(@_);
1131}
1132
1133## none mode output functions
1134
1135sub output_function_none(%) {
1136}
1137
1138sub output_enum_none(%) {
1139}
1140
1141sub output_typedef_none(%) {
1142}
1143
1144sub output_struct_none(%) {
1145}
1146
1147sub output_blockhead_none(%) {
1148}
1149
1150##
1151# generic output function for all types (function, struct/union, typedef, enum);
1152# calls the generated, variable output_ function name based on
1153# functype and output_mode
1154sub output_declaration {
1155    no strict 'refs';
1156    my $name = shift;
1157    my $functype = shift;
1158    my $func = "output_${functype}_$output_mode";
1159
1160    return if (defined($nosymbol_table{$name}));
1161
1162    if (($output_selection == OUTPUT_ALL) ||
1163	(($output_selection == OUTPUT_INCLUDE ||
1164	  $output_selection == OUTPUT_EXPORTED) &&
1165	 defined($function_table{$name})) ||
1166	($output_selection == OUTPUT_INTERNAL &&
1167	 !($functype eq "function" && defined($function_table{$name}))))
1168    {
1169	&$func(@_);
1170	$section_counter++;
1171    }
1172}
1173
1174##
1175# generic output function - calls the right one based on current output mode.
1176sub output_blockhead {
1177    no strict 'refs';
1178    my $func = "output_blockhead_" . $output_mode;
1179    &$func(@_);
1180    $section_counter++;
1181}
1182
1183##
1184# takes a declaration (struct, union, enum, typedef) and
1185# invokes the right handler. NOT called for functions.
1186sub dump_declaration($$) {
1187    no strict 'refs';
1188    my ($prototype, $file) = @_;
1189    my $func = "dump_" . $decl_type;
1190    &$func(@_);
1191}
1192
1193sub dump_union($$) {
1194    dump_struct(@_);
1195}
1196
1197sub dump_struct($$) {
1198    my $x = shift;
1199    my $file = shift;
1200
1201    if ($x =~ /(struct|union)\s+(\w+)\s*\{(.*)\}(\s*(__packed|__aligned|____cacheline_aligned_in_smp|____cacheline_aligned|__attribute__\s*\(\([a-z0-9,_\s\(\)]*\)\)))*/) {
1202	my $decl_type = $1;
1203	$declaration_name = $2;
1204	my $members = $3;
1205
1206	# ignore members marked private:
1207	$members =~ s/\/\*\s*private:.*?\/\*\s*public:.*?\*\///gosi;
1208	$members =~ s/\/\*\s*private:.*//gosi;
1209	# strip comments:
1210	$members =~ s/\/\*.*?\*\///gos;
1211	# strip attributes
1212	$members =~ s/\s*__attribute__\s*\(\([a-z0-9,_\*\s\(\)]*\)\)/ /gi;
1213	$members =~ s/\s*__aligned\s*\([^;]*\)/ /gos;
1214	$members =~ s/\s*__packed\s*/ /gos;
1215	$members =~ s/\s*CRYPTO_MINALIGN_ATTR/ /gos;
1216	$members =~ s/\s*____cacheline_aligned_in_smp/ /gos;
1217	$members =~ s/\s*____cacheline_aligned/ /gos;
1218	# unwrap struct_group():
1219	# - first eat non-declaration parameters and rewrite for final match
1220	# - then remove macro, outer parens, and trailing semicolon
1221	$members =~ s/\bstruct_group\s*\(([^,]*,)/STRUCT_GROUP(/gos;
1222	$members =~ s/\bstruct_group_(attr|tagged)\s*\(([^,]*,){2}/STRUCT_GROUP(/gos;
1223	$members =~ s/\b__struct_group\s*\(([^,]*,){3}/STRUCT_GROUP(/gos;
1224	$members =~ s/\bSTRUCT_GROUP(\(((?:(?>[^)(]+)|(?1))*)\))[^;]*;/$2/gos;
1225
1226	# replace DECLARE_BITMAP
1227	$members =~ s/__ETHTOOL_DECLARE_LINK_MODE_MASK\s*\(([^\)]+)\)/DECLARE_BITMAP($1, __ETHTOOL_LINK_MODE_MASK_NBITS)/gos;
1228	$members =~ s/DECLARE_BITMAP\s*\(([^,)]+),\s*([^,)]+)\)/unsigned long $1\[BITS_TO_LONGS($2)\]/gos;
1229	# replace DECLARE_HASHTABLE
1230	$members =~ s/DECLARE_HASHTABLE\s*\(([^,)]+),\s*([^,)]+)\)/unsigned long $1\[1 << (($2) - 1)\]/gos;
1231	# replace DECLARE_KFIFO
1232	$members =~ s/DECLARE_KFIFO\s*\(([^,)]+),\s*([^,)]+),\s*([^,)]+)\)/$2 \*$1/gos;
1233	# replace DECLARE_KFIFO_PTR
1234	$members =~ s/DECLARE_KFIFO_PTR\s*\(([^,)]+),\s*([^,)]+)\)/$2 \*$1/gos;
1235	# replace DECLARE_FLEX_ARRAY
1236	$members =~ s/(?:__)?DECLARE_FLEX_ARRAY\s*\($args,\s*$args\)/$1 $2\[\]/gos;
1237	my $declaration = $members;
1238
1239	# Split nested struct/union elements as newer ones
1240	while ($members =~ m/(struct|union)([^\{\};]+)\{([^\{\}]*)\}([^\{\}\;]*)\;/) {
1241		my $newmember;
1242		my $maintype = $1;
1243		my $ids = $4;
1244		my $content = $3;
1245		foreach my $id(split /,/, $ids) {
1246			$newmember .= "$maintype $id; ";
1247
1248			$id =~ s/[:\[].*//;
1249			$id =~ s/^\s*\**(\S+)\s*/$1/;
1250			foreach my $arg (split /;/, $content) {
1251				next if ($arg =~ m/^\s*$/);
1252				if ($arg =~ m/^([^\(]+\(\*?\s*)([\w\.]*)(\s*\).*)/) {
1253					# pointer-to-function
1254					my $type = $1;
1255					my $name = $2;
1256					my $extra = $3;
1257					next if (!$name);
1258					if ($id =~ m/^\s*$/) {
1259						# anonymous struct/union
1260						$newmember .= "$type$name$extra; ";
1261					} else {
1262						$newmember .= "$type$id.$name$extra; ";
1263					}
1264				} else {
1265					my $type;
1266					my $names;
1267					$arg =~ s/^\s+//;
1268					$arg =~ s/\s+$//;
1269					# Handle bitmaps
1270					$arg =~ s/:\s*\d+\s*//g;
1271					# Handle arrays
1272					$arg =~ s/\[.*\]//g;
1273					# The type may have multiple words,
1274					# and multiple IDs can be defined, like:
1275					#	const struct foo, *bar, foobar
1276					# So, we remove spaces when parsing the
1277					# names, in order to match just names
1278					# and commas for the names
1279					$arg =~ s/\s*,\s*/,/g;
1280					if ($arg =~ m/(.*)\s+([\S+,]+)/) {
1281						$type = $1;
1282						$names = $2;
1283					} else {
1284						$newmember .= "$arg; ";
1285						next;
1286					}
1287					foreach my $name (split /,/, $names) {
1288						$name =~ s/^\s*\**(\S+)\s*/$1/;
1289						next if (($name =~ m/^\s*$/));
1290						if ($id =~ m/^\s*$/) {
1291							# anonymous struct/union
1292							$newmember .= "$type $name; ";
1293						} else {
1294							$newmember .= "$type $id.$name; ";
1295						}
1296					}
1297				}
1298			}
1299		}
1300		$members =~ s/(struct|union)([^\{\};]+)\{([^\{\}]*)\}([^\{\}\;]*)\;/$newmember/;
1301	}
1302
1303	# Ignore other nested elements, like enums
1304	$members =~ s/(\{[^\{\}]*\})//g;
1305
1306	create_parameterlist($members, ';', $file, $declaration_name);
1307	check_sections($file, $declaration_name, $decl_type, $sectcheck, $struct_actual);
1308
1309	# Adjust declaration for better display
1310	$declaration =~ s/([\{;])/$1\n/g;
1311	$declaration =~ s/\}\s+;/};/g;
1312	# Better handle inlined enums
1313	do {} while ($declaration =~ s/(enum\s+\{[^\}]+),([^\n])/$1,\n$2/);
1314
1315	my @def_args = split /\n/, $declaration;
1316	my $level = 1;
1317	$declaration = "";
1318	foreach my $clause (@def_args) {
1319		$clause =~ s/^\s+//;
1320		$clause =~ s/\s+$//;
1321		$clause =~ s/\s+/ /;
1322		next if (!$clause);
1323		$level-- if ($clause =~ m/(\})/ && $level > 1);
1324		if (!($clause =~ m/^\s*#/)) {
1325			$declaration .= "\t" x $level;
1326		}
1327		$declaration .= "\t" . $clause . "\n";
1328		$level++ if ($clause =~ m/(\{)/ && !($clause =~m/\}/));
1329	}
1330	output_declaration($declaration_name,
1331			   'struct',
1332			   {'struct' => $declaration_name,
1333			    'module' => $modulename,
1334			    'definition' => $declaration,
1335			    'parameterlist' => \@parameterlist,
1336			    'parameterdescs' => \%parameterdescs,
1337			    'parametertypes' => \%parametertypes,
1338			    'sectionlist' => \@sectionlist,
1339			    'sections' => \%sections,
1340			    'purpose' => $declaration_purpose,
1341			    'type' => $decl_type
1342			   });
1343    }
1344    else {
1345	print STDERR "${file}:$.: error: Cannot parse struct or union!\n";
1346	++$errors;
1347    }
1348}
1349
1350
1351sub show_warnings($$) {
1352	my $functype = shift;
1353	my $name = shift;
1354
1355	return 0 if (defined($nosymbol_table{$name}));
1356
1357	return 1 if ($output_selection == OUTPUT_ALL);
1358
1359	if ($output_selection == OUTPUT_EXPORTED) {
1360		if (defined($function_table{$name})) {
1361			return 1;
1362		} else {
1363			return 0;
1364		}
1365	}
1366        if ($output_selection == OUTPUT_INTERNAL) {
1367		if (!($functype eq "function" && defined($function_table{$name}))) {
1368			return 1;
1369		} else {
1370			return 0;
1371		}
1372	}
1373	if ($output_selection == OUTPUT_INCLUDE) {
1374		if (defined($function_table{$name})) {
1375			return 1;
1376		} else {
1377			return 0;
1378		}
1379	}
1380	die("Please add the new output type at show_warnings()");
1381}
1382
1383sub dump_enum($$) {
1384    my $x = shift;
1385    my $file = shift;
1386    my $members;
1387
1388
1389    $x =~ s@/\*.*?\*/@@gos;	# strip comments.
1390    # strip #define macros inside enums
1391    $x =~ s@#\s*((define|ifdef)\s+|endif)[^;]*;@@gos;
1392
1393    if ($x =~ /typedef\s+enum\s*\{(.*)\}\s*(\w*)\s*;/) {
1394	$declaration_name = $2;
1395	$members = $1;
1396    } elsif ($x =~ /enum\s+(\w*)\s*\{(.*)\}/) {
1397	$declaration_name = $1;
1398	$members = $2;
1399    }
1400
1401    if ($members) {
1402	my %_members;
1403
1404	$members =~ s/\s+$//;
1405
1406	foreach my $arg (split ',', $members) {
1407	    $arg =~ s/^\s*(\w+).*/$1/;
1408	    push @parameterlist, $arg;
1409	    if (!$parameterdescs{$arg}) {
1410		$parameterdescs{$arg} = $undescribed;
1411	        if (show_warnings("enum", $declaration_name)) {
1412			print STDERR "${file}:$.: warning: Enum value '$arg' not described in enum '$declaration_name'\n";
1413		}
1414	    }
1415	    $_members{$arg} = 1;
1416	}
1417
1418	while (my ($k, $v) = each %parameterdescs) {
1419	    if (!exists($_members{$k})) {
1420	        if (show_warnings("enum", $declaration_name)) {
1421		     print STDERR "${file}:$.: warning: Excess enum value '$k' description in '$declaration_name'\n";
1422		}
1423	    }
1424        }
1425
1426	output_declaration($declaration_name,
1427			   'enum',
1428			   {'enum' => $declaration_name,
1429			    'module' => $modulename,
1430			    'parameterlist' => \@parameterlist,
1431			    'parameterdescs' => \%parameterdescs,
1432			    'sectionlist' => \@sectionlist,
1433			    'sections' => \%sections,
1434			    'purpose' => $declaration_purpose
1435			   });
1436    } else {
1437	print STDERR "${file}:$.: error: Cannot parse enum!\n";
1438	++$errors;
1439    }
1440}
1441
1442my $typedef_type = qr { ((?:\s+[\w\*]+\b){1,8})\s* }x;
1443my $typedef_ident = qr { \*?\s*(\w\S+)\s* }x;
1444my $typedef_args = qr { \s*\((.*)\); }x;
1445
1446my $typedef1 = qr { typedef$typedef_type\($typedef_ident\)$typedef_args }x;
1447my $typedef2 = qr { typedef$typedef_type$typedef_ident$typedef_args }x;
1448
1449sub dump_typedef($$) {
1450    my $x = shift;
1451    my $file = shift;
1452
1453    $x =~ s@/\*.*?\*/@@gos;	# strip comments.
1454
1455    # Parse function typedef prototypes
1456    if ($x =~ $typedef1 || $x =~ $typedef2) {
1457	$return_type = $1;
1458	$declaration_name = $2;
1459	my $args = $3;
1460	$return_type =~ s/^\s+//;
1461
1462	create_parameterlist($args, ',', $file, $declaration_name);
1463
1464	output_declaration($declaration_name,
1465			   'function',
1466			   {'function' => $declaration_name,
1467			    'typedef' => 1,
1468			    'module' => $modulename,
1469			    'functiontype' => $return_type,
1470			    'parameterlist' => \@parameterlist,
1471			    'parameterdescs' => \%parameterdescs,
1472			    'parametertypes' => \%parametertypes,
1473			    'sectionlist' => \@sectionlist,
1474			    'sections' => \%sections,
1475			    'purpose' => $declaration_purpose
1476			   });
1477	return;
1478    }
1479
1480    while (($x =~ /\(*.\)\s*;$/) || ($x =~ /\[*.\]\s*;$/)) {
1481	$x =~ s/\(*.\)\s*;$/;/;
1482	$x =~ s/\[*.\]\s*;$/;/;
1483    }
1484
1485    if ($x =~ /typedef.*\s+(\w+)\s*;/) {
1486	$declaration_name = $1;
1487
1488	output_declaration($declaration_name,
1489			   'typedef',
1490			   {'typedef' => $declaration_name,
1491			    'module' => $modulename,
1492			    'sectionlist' => \@sectionlist,
1493			    'sections' => \%sections,
1494			    'purpose' => $declaration_purpose
1495			   });
1496    }
1497    else {
1498	print STDERR "${file}:$.: error: Cannot parse typedef!\n";
1499	++$errors;
1500    }
1501}
1502
1503sub save_struct_actual($) {
1504    my $actual = shift;
1505
1506    # strip all spaces from the actual param so that it looks like one string item
1507    $actual =~ s/\s*//g;
1508    $struct_actual = $struct_actual . $actual . " ";
1509}
1510
1511sub create_parameterlist($$$$) {
1512    my $args = shift;
1513    my $splitter = shift;
1514    my $file = shift;
1515    my $declaration_name = shift;
1516    my $type;
1517    my $param;
1518
1519    # temporarily replace commas inside function pointer definition
1520    while ($args =~ /(\([^\),]+),/) {
1521	$args =~ s/(\([^\),]+),/$1#/g;
1522    }
1523
1524    foreach my $arg (split($splitter, $args)) {
1525	# strip comments
1526	$arg =~ s/\/\*.*\*\///;
1527	# strip leading/trailing spaces
1528	$arg =~ s/^\s*//;
1529	$arg =~ s/\s*$//;
1530	$arg =~ s/\s+/ /;
1531
1532	if ($arg =~ /^#/) {
1533	    # Treat preprocessor directive as a typeless variable just to fill
1534	    # corresponding data structures "correctly". Catch it later in
1535	    # output_* subs.
1536	    push_parameter($arg, "", "", $file);
1537	} elsif ($arg =~ m/\(.+\)\s*\(/) {
1538	    # pointer-to-function
1539	    $arg =~ tr/#/,/;
1540	    $arg =~ m/[^\(]+\(\*?\s*([\w\.]*)\s*\)/;
1541	    $param = $1;
1542	    $type = $arg;
1543	    $type =~ s/([^\(]+\(\*?)\s*$param/$1/;
1544	    save_struct_actual($param);
1545	    push_parameter($param, $type, $arg, $file, $declaration_name);
1546	} elsif ($arg) {
1547	    $arg =~ s/\s*:\s*/:/g;
1548	    $arg =~ s/\s*\[/\[/g;
1549
1550	    my @args = split('\s*,\s*', $arg);
1551	    if ($args[0] =~ m/\*/) {
1552		$args[0] =~ s/(\*+)\s*/ $1/;
1553	    }
1554
1555	    my @first_arg;
1556	    if ($args[0] =~ /^(.*\s+)(.*?\[.*\].*)$/) {
1557		    shift @args;
1558		    push(@first_arg, split('\s+', $1));
1559		    push(@first_arg, $2);
1560	    } else {
1561		    @first_arg = split('\s+', shift @args);
1562	    }
1563
1564	    unshift(@args, pop @first_arg);
1565	    $type = join " ", @first_arg;
1566
1567	    foreach $param (@args) {
1568		if ($param =~ m/^(\*+)\s*(.*)/) {
1569		    save_struct_actual($2);
1570
1571		    push_parameter($2, "$type $1", $arg, $file, $declaration_name);
1572		}
1573		elsif ($param =~ m/(.*?):(\d+)/) {
1574		    if ($type ne "") { # skip unnamed bit-fields
1575			save_struct_actual($1);
1576			push_parameter($1, "$type:$2", $arg, $file, $declaration_name)
1577		    }
1578		}
1579		else {
1580		    save_struct_actual($param);
1581		    push_parameter($param, $type, $arg, $file, $declaration_name);
1582		}
1583	    }
1584	}
1585    }
1586}
1587
1588sub push_parameter($$$$$) {
1589	my $param = shift;
1590	my $type = shift;
1591	my $org_arg = shift;
1592	my $file = shift;
1593	my $declaration_name = shift;
1594
1595	if (($anon_struct_union == 1) && ($type eq "") &&
1596	    ($param eq "}")) {
1597		return;		# ignore the ending }; from anon. struct/union
1598	}
1599
1600	$anon_struct_union = 0;
1601	$param =~ s/[\[\)].*//;
1602
1603	if ($type eq "" && $param =~ /\.\.\.$/)
1604	{
1605	    if (!$param =~ /\w\.\.\.$/) {
1606	      # handles unnamed variable parameters
1607	      $param = "...";
1608	    }
1609	    elsif ($param =~ /\w\.\.\.$/) {
1610	      # for named variable parameters of the form `x...`, remove the dots
1611	      $param =~ s/\.\.\.$//;
1612	    }
1613	    if (!defined $parameterdescs{$param} || $parameterdescs{$param} eq "") {
1614		$parameterdescs{$param} = "variable arguments";
1615	    }
1616	}
1617	elsif ($type eq "" && ($param eq "" or $param eq "void"))
1618	{
1619	    $param="void";
1620	    $parameterdescs{void} = "no arguments";
1621	}
1622	elsif ($type eq "" && ($param eq "struct" or $param eq "union"))
1623	# handle unnamed (anonymous) union or struct:
1624	{
1625		$type = $param;
1626		$param = "{unnamed_" . $param . "}";
1627		$parameterdescs{$param} = "anonymous\n";
1628		$anon_struct_union = 1;
1629	}
1630
1631	# warn if parameter has no description
1632	# (but ignore ones starting with # as these are not parameters
1633	# but inline preprocessor statements);
1634	# Note: It will also ignore void params and unnamed structs/unions
1635	if (!defined $parameterdescs{$param} && $param !~ /^#/) {
1636		$parameterdescs{$param} = $undescribed;
1637
1638	        if (show_warnings($type, $declaration_name) && $param !~ /\./) {
1639			print STDERR
1640			      "${file}:$.: warning: Function parameter or member '$param' not described in '$declaration_name'\n";
1641			++$warnings;
1642		}
1643	}
1644
1645	# strip spaces from $param so that it is one continuous string
1646	# on @parameterlist;
1647	# this fixes a problem where check_sections() cannot find
1648	# a parameter like "addr[6 + 2]" because it actually appears
1649	# as "addr[6", "+", "2]" on the parameter list;
1650	# but it's better to maintain the param string unchanged for output,
1651	# so just weaken the string compare in check_sections() to ignore
1652	# "[blah" in a parameter string;
1653	###$param =~ s/\s*//g;
1654	push @parameterlist, $param;
1655	$org_arg =~ s/\s\s+/ /g;
1656	$parametertypes{$param} = $org_arg;
1657}
1658
1659sub check_sections($$$$$) {
1660	my ($file, $decl_name, $decl_type, $sectcheck, $prmscheck) = @_;
1661	my @sects = split ' ', $sectcheck;
1662	my @prms = split ' ', $prmscheck;
1663	my $err;
1664	my ($px, $sx);
1665	my $prm_clean;		# strip trailing "[array size]" and/or beginning "*"
1666
1667	foreach $sx (0 .. $#sects) {
1668		$err = 1;
1669		foreach $px (0 .. $#prms) {
1670			$prm_clean = $prms[$px];
1671			$prm_clean =~ s/\[.*\]//;
1672			$prm_clean =~ s/__attribute__\s*\(\([a-z,_\*\s\(\)]*\)\)//i;
1673			# ignore array size in a parameter string;
1674			# however, the original param string may contain
1675			# spaces, e.g.:  addr[6 + 2]
1676			# and this appears in @prms as "addr[6" since the
1677			# parameter list is split at spaces;
1678			# hence just ignore "[..." for the sections check;
1679			$prm_clean =~ s/\[.*//;
1680
1681			##$prm_clean =~ s/^\**//;
1682			if ($prm_clean eq $sects[$sx]) {
1683				$err = 0;
1684				last;
1685			}
1686		}
1687		if ($err) {
1688			if ($decl_type eq "function") {
1689				print STDERR "${file}:$.: warning: " .
1690					"Excess function parameter " .
1691					"'$sects[$sx]' " .
1692					"description in '$decl_name'\n";
1693				++$warnings;
1694			}
1695		}
1696	}
1697}
1698
1699##
1700# Checks the section describing the return value of a function.
1701sub check_return_section {
1702        my $file = shift;
1703        my $declaration_name = shift;
1704        my $return_type = shift;
1705
1706        # Ignore an empty return type (It's a macro)
1707        # Ignore functions with a "void" return type. (But don't ignore "void *")
1708        if (($return_type eq "") || ($return_type =~ /void\s*\w*\s*$/)) {
1709                return;
1710        }
1711
1712        if (!defined($sections{$section_return}) ||
1713            $sections{$section_return} eq "") {
1714                print STDERR "${file}:$.: warning: " .
1715                        "No description found for return value of " .
1716                        "'$declaration_name'\n";
1717                ++$warnings;
1718        }
1719}
1720
1721##
1722# takes a function prototype and the name of the current file being
1723# processed and spits out all the details stored in the global
1724# arrays/hashes.
1725sub dump_function($$) {
1726    my $prototype = shift;
1727    my $file = shift;
1728    my $noret = 0;
1729
1730    print_lineno($new_start_line);
1731
1732    $prototype =~ s/^static +//;
1733    $prototype =~ s/^extern +//;
1734    $prototype =~ s/^asmlinkage +//;
1735    $prototype =~ s/^inline +//;
1736    $prototype =~ s/^__inline__ +//;
1737    $prototype =~ s/^__inline +//;
1738    $prototype =~ s/^__always_inline +//;
1739    $prototype =~ s/^noinline +//;
1740    $prototype =~ s/__init +//;
1741    $prototype =~ s/__init_or_module +//;
1742    $prototype =~ s/__meminit +//;
1743    $prototype =~ s/__must_check +//;
1744    $prototype =~ s/__weak +//;
1745    $prototype =~ s/__sched +//;
1746    $prototype =~ s/__printf\s*\(\s*\d*\s*,\s*\d*\s*\) +//;
1747    my $define = $prototype =~ s/^#\s*define\s+//; #ak added
1748    $prototype =~ s/__attribute__\s*\(\(
1749            (?:
1750                 [\w\s]++          # attribute name
1751                 (?:\([^)]*+\))?   # attribute arguments
1752                 \s*+,?            # optional comma at the end
1753            )+
1754          \)\)\s+//x;
1755
1756    # Yes, this truly is vile.  We are looking for:
1757    # 1. Return type (may be nothing if we're looking at a macro)
1758    # 2. Function name
1759    # 3. Function parameters.
1760    #
1761    # All the while we have to watch out for function pointer parameters
1762    # (which IIRC is what the two sections are for), C types (these
1763    # regexps don't even start to express all the possibilities), and
1764    # so on.
1765    #
1766    # If you mess with these regexps, it's a good idea to check that
1767    # the following functions' documentation still comes out right:
1768    # - parport_register_device (function pointer parameters)
1769    # - atomic_set (macro)
1770    # - pci_match_device, __copy_to_user (long return type)
1771
1772    if ($define && $prototype =~ m/^()([a-zA-Z0-9_~:]+)\s+/) {
1773        # This is an object-like macro, it has no return type and no parameter
1774        # list.
1775        # Function-like macros are not allowed to have spaces between
1776        # declaration_name and opening parenthesis (notice the \s+).
1777        $return_type = $1;
1778        $declaration_name = $2;
1779        $noret = 1;
1780    } elsif ($prototype =~ m/^()([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1781	$prototype =~ m/^(\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1782	$prototype =~ m/^(\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1783	$prototype =~ m/^(\w+\s+\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1784	$prototype =~ m/^(\w+\s+\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1785	$prototype =~ m/^(\w+\s+\w+\s+\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1786	$prototype =~ m/^(\w+\s+\w+\s+\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1787	$prototype =~ m/^()([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1788	$prototype =~ m/^(\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1789	$prototype =~ m/^(\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1790	$prototype =~ m/^(\w+\s+\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1791	$prototype =~ m/^(\w+\s+\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1792	$prototype =~ m/^(\w+\s+\w+\s+\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1793	$prototype =~ m/^(\w+\s+\w+\s+\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1794	$prototype =~ m/^(\w+\s+\w+\s+\w+\s+\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1795	$prototype =~ m/^(\w+\s+\w+\s+\w+\s+\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1796	$prototype =~ m/^(\w+\s+\w+\s*\*+\s*\w+\s*\*+\s*)\s*([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/)  {
1797	$return_type = $1;
1798	$declaration_name = $2;
1799	my $args = $3;
1800
1801	create_parameterlist($args, ',', $file, $declaration_name);
1802    } else {
1803	print STDERR "${file}:$.: warning: cannot understand function prototype: '$prototype'\n";
1804	return;
1805    }
1806
1807    my $prms = join " ", @parameterlist;
1808    check_sections($file, $declaration_name, "function", $sectcheck, $prms);
1809
1810    # This check emits a lot of warnings at the moment, because many
1811    # functions don't have a 'Return' doc section. So until the number
1812    # of warnings goes sufficiently down, the check is only performed in
1813    # verbose mode.
1814    # TODO: always perform the check.
1815    if ($verbose && !$noret) {
1816	    check_return_section($file, $declaration_name, $return_type);
1817    }
1818
1819    # The function parser can be called with a typedef parameter.
1820    # Handle it.
1821    if ($return_type =~ /typedef/) {
1822	output_declaration($declaration_name,
1823			   'function',
1824			   {'function' => $declaration_name,
1825			    'typedef' => 1,
1826			    'module' => $modulename,
1827			    'functiontype' => $return_type,
1828			    'parameterlist' => \@parameterlist,
1829			    'parameterdescs' => \%parameterdescs,
1830			    'parametertypes' => \%parametertypes,
1831			    'sectionlist' => \@sectionlist,
1832			    'sections' => \%sections,
1833			    'purpose' => $declaration_purpose
1834			   });
1835    } else {
1836	output_declaration($declaration_name,
1837			   'function',
1838			   {'function' => $declaration_name,
1839			    'module' => $modulename,
1840			    'functiontype' => $return_type,
1841			    'parameterlist' => \@parameterlist,
1842			    'parameterdescs' => \%parameterdescs,
1843			    'parametertypes' => \%parametertypes,
1844			    'sectionlist' => \@sectionlist,
1845			    'sections' => \%sections,
1846			    'purpose' => $declaration_purpose
1847			   });
1848    }
1849}
1850
1851sub reset_state {
1852    $function = "";
1853    %parameterdescs = ();
1854    %parametertypes = ();
1855    @parameterlist = ();
1856    %sections = ();
1857    @sectionlist = ();
1858    $sectcheck = "";
1859    $struct_actual = "";
1860    $prototype = "";
1861
1862    $state = STATE_NORMAL;
1863    $inline_doc_state = STATE_INLINE_NA;
1864}
1865
1866sub tracepoint_munge($) {
1867	my $file = shift;
1868	my $tracepointname = 0;
1869	my $tracepointargs = 0;
1870
1871	if ($prototype =~ m/TRACE_EVENT\((.*?),/) {
1872		$tracepointname = $1;
1873	}
1874	if ($prototype =~ m/DEFINE_SINGLE_EVENT\((.*?),/) {
1875		$tracepointname = $1;
1876	}
1877	if ($prototype =~ m/DEFINE_EVENT\((.*?),(.*?),/) {
1878		$tracepointname = $2;
1879	}
1880	$tracepointname =~ s/^\s+//; #strip leading whitespace
1881	if ($prototype =~ m/TP_PROTO\((.*?)\)/) {
1882		$tracepointargs = $1;
1883	}
1884	if (($tracepointname eq 0) || ($tracepointargs eq 0)) {
1885		print STDERR "${file}:$.: warning: Unrecognized tracepoint format: \n".
1886			     "$prototype\n";
1887	} else {
1888		$prototype = "static inline void trace_$tracepointname($tracepointargs)";
1889	}
1890}
1891
1892sub syscall_munge() {
1893	my $void = 0;
1894
1895	$prototype =~ s@[\r\n]+@ @gos; # strip newlines/CR's
1896##	if ($prototype =~ m/SYSCALL_DEFINE0\s*\(\s*(a-zA-Z0-9_)*\s*\)/) {
1897	if ($prototype =~ m/SYSCALL_DEFINE0/) {
1898		$void = 1;
1899##		$prototype = "long sys_$1(void)";
1900	}
1901
1902	$prototype =~ s/SYSCALL_DEFINE.*\(/long sys_/; # fix return type & func name
1903	if ($prototype =~ m/long (sys_.*?),/) {
1904		$prototype =~ s/,/\(/;
1905	} elsif ($void) {
1906		$prototype =~ s/\)/\(void\)/;
1907	}
1908
1909	# now delete all of the odd-number commas in $prototype
1910	# so that arg types & arg names don't have a comma between them
1911	my $count = 0;
1912	my $len = length($prototype);
1913	if ($void) {
1914		$len = 0;	# skip the for-loop
1915	}
1916	for (my $ix = 0; $ix < $len; $ix++) {
1917		if (substr($prototype, $ix, 1) eq ',') {
1918			$count++;
1919			if ($count % 2 == 1) {
1920				substr($prototype, $ix, 1) = ' ';
1921			}
1922		}
1923	}
1924}
1925
1926sub process_proto_function($$) {
1927    my $x = shift;
1928    my $file = shift;
1929
1930    $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1931
1932    if ($x =~ m#\s*/\*\s+MACDOC\s*#io || ($x =~ /^#/ && $x !~ /^#\s*define/)) {
1933	# do nothing
1934    }
1935    elsif ($x =~ /([^\{]*)/) {
1936	$prototype .= $1;
1937    }
1938
1939    if (($x =~ /\{/) || ($x =~ /\#\s*define/) || ($x =~ /;/)) {
1940	$prototype =~ s@/\*.*?\*/@@gos;	# strip comments.
1941	$prototype =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1942	$prototype =~ s@^\s+@@gos; # strip leading spaces
1943
1944	 # Handle prototypes for function pointers like:
1945	 # int (*pcs_config)(struct foo)
1946	$prototype =~ s@^(\S+\s+)\(\s*\*(\S+)\)@$1$2@gos;
1947
1948	if ($prototype =~ /SYSCALL_DEFINE/) {
1949		syscall_munge();
1950	}
1951	if ($prototype =~ /TRACE_EVENT/ || $prototype =~ /DEFINE_EVENT/ ||
1952	    $prototype =~ /DEFINE_SINGLE_EVENT/)
1953	{
1954		tracepoint_munge($file);
1955	}
1956	dump_function($prototype, $file);
1957	reset_state();
1958    }
1959}
1960
1961sub process_proto_type($$) {
1962    my $x = shift;
1963    my $file = shift;
1964
1965    $x =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1966    $x =~ s@^\s+@@gos; # strip leading spaces
1967    $x =~ s@\s+$@@gos; # strip trailing spaces
1968    $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1969
1970    if ($x =~ /^#/) {
1971	# To distinguish preprocessor directive from regular declaration later.
1972	$x .= ";";
1973    }
1974
1975    while (1) {
1976	if ( $x =~ /([^\{\};]*)([\{\};])(.*)/ ) {
1977            if( length $prototype ) {
1978                $prototype .= " "
1979            }
1980	    $prototype .= $1 . $2;
1981	    ($2 eq '{') && $brcount++;
1982	    ($2 eq '}') && $brcount--;
1983	    if (($2 eq ';') && ($brcount == 0)) {
1984		dump_declaration($prototype, $file);
1985		reset_state();
1986		last;
1987	    }
1988	    $x = $3;
1989	} else {
1990	    $prototype .= $x;
1991	    last;
1992	}
1993    }
1994}
1995
1996
1997sub map_filename($) {
1998    my $file;
1999    my ($orig_file) = @_;
2000
2001    if (defined($ENV{'SRCTREE'})) {
2002	$file = "$ENV{'SRCTREE'}" . "/" . $orig_file;
2003    } else {
2004	$file = $orig_file;
2005    }
2006
2007    if (defined($source_map{$file})) {
2008	$file = $source_map{$file};
2009    }
2010
2011    return $file;
2012}
2013
2014sub process_export_file($) {
2015    my ($orig_file) = @_;
2016    my $file = map_filename($orig_file);
2017
2018    if (!open(IN,"<$file")) {
2019	print STDERR "Error: Cannot open file $file\n";
2020	++$errors;
2021	return;
2022    }
2023
2024    while (<IN>) {
2025	if (/$export_symbol/) {
2026	    next if (defined($nosymbol_table{$2}));
2027	    $function_table{$2} = 1;
2028	}
2029    }
2030
2031    close(IN);
2032}
2033
2034#
2035# Parsers for the various processing states.
2036#
2037# STATE_NORMAL: looking for the /** to begin everything.
2038#
2039sub process_normal() {
2040    if (/$doc_start/o) {
2041	$state = STATE_NAME;	# next line is always the function name
2042	$in_doc_sect = 0;
2043	$declaration_start_line = $. + 1;
2044    }
2045}
2046
2047#
2048# STATE_NAME: Looking for the "name - description" line
2049#
2050sub process_name($$) {
2051    my $file = shift;
2052    my $identifier;
2053    my $descr;
2054
2055    if (/$doc_block/o) {
2056	$state = STATE_DOCBLOCK;
2057	$contents = "";
2058	$new_start_line = $.;
2059
2060	if ( $1 eq "" ) {
2061	    $section = $section_intro;
2062	} else {
2063	    $section = $1;
2064	}
2065    }
2066    elsif (/$doc_decl/o) {
2067	$identifier = $1;
2068	if (/\s*([\w\s]+?)(\(\))?\s*-/) {
2069	    $identifier = $1;
2070	}
2071
2072	$state = STATE_BODY;
2073	# if there's no @param blocks need to set up default section
2074	# here
2075	$contents = "";
2076	$section = $section_default;
2077	$new_start_line = $. + 1;
2078	if (/-(.*)/) {
2079	    # strip leading/trailing/multiple spaces
2080	    $descr= $1;
2081	    $descr =~ s/^\s*//;
2082	    $descr =~ s/\s*$//;
2083	    $descr =~ s/\s+/ /g;
2084	    $declaration_purpose = $descr;
2085	    $state = STATE_BODY_MAYBE;
2086	} else {
2087	    $declaration_purpose = "";
2088	}
2089
2090	if (($declaration_purpose eq "") && $verbose) {
2091	    print STDERR "${file}:$.: warning: missing initial short description on line:\n";
2092	    print STDERR $_;
2093	    ++$warnings;
2094	}
2095
2096	if ($identifier =~ m/^struct\b/) {
2097	    $decl_type = 'struct';
2098	} elsif ($identifier =~ m/^union\b/) {
2099	    $decl_type = 'union';
2100	} elsif ($identifier =~ m/^enum\b/) {
2101	    $decl_type = 'enum';
2102	} elsif ($identifier =~ m/^typedef\b/) {
2103	    $decl_type = 'typedef';
2104	} else {
2105	    $decl_type = 'function';
2106	}
2107
2108	if ($verbose) {
2109	    print STDERR "${file}:$.: info: Scanning doc for $identifier\n";
2110	}
2111    } else {
2112	print STDERR "${file}:$.: warning: Cannot understand $_ on line $.",
2113	    " - I thought it was a doc line\n";
2114	++$warnings;
2115	$state = STATE_NORMAL;
2116    }
2117}
2118
2119
2120#
2121# STATE_BODY and STATE_BODY_MAYBE: the bulk of a kerneldoc comment.
2122#
2123sub process_body($$) {
2124    my $file = shift;
2125
2126    # Until all named variable macro parameters are
2127    # documented using the bare name (`x`) rather than with
2128    # dots (`x...`), strip the dots:
2129    if ($section =~ /\w\.\.\.$/) {
2130	$section =~ s/\.\.\.$//;
2131
2132	if ($verbose) {
2133	    print STDERR "${file}:$.: warning: Variable macro arguments should be documented without dots\n";
2134	    ++$warnings;
2135	}
2136    }
2137
2138    if ($state == STATE_BODY_WITH_BLANK_LINE && /^\s*\*\s?\S/) {
2139	dump_section($file, $section, $contents);
2140	$section = $section_default;
2141	$new_start_line = $.;
2142	$contents = "";
2143    }
2144
2145    if (/$doc_sect/i) { # case insensitive for supported section names
2146	$newsection = $1;
2147	$newcontents = $2;
2148
2149	# map the supported section names to the canonical names
2150	if ($newsection =~ m/^description$/i) {
2151	    $newsection = $section_default;
2152	} elsif ($newsection =~ m/^context$/i) {
2153	    $newsection = $section_context;
2154	} elsif ($newsection =~ m/^returns?$/i) {
2155	    $newsection = $section_return;
2156	} elsif ($newsection =~ m/^\@return$/) {
2157	    # special: @return is a section, not a param description
2158	    $newsection = $section_return;
2159	}
2160
2161	if (($contents ne "") && ($contents ne "\n")) {
2162	    if (!$in_doc_sect && $verbose) {
2163		print STDERR "${file}:$.: warning: contents before sections\n";
2164		++$warnings;
2165	    }
2166	    dump_section($file, $section, $contents);
2167	    $section = $section_default;
2168	}
2169
2170	$in_doc_sect = 1;
2171	$state = STATE_BODY;
2172	$contents = $newcontents;
2173	$new_start_line = $.;
2174	while (substr($contents, 0, 1) eq " ") {
2175	    $contents = substr($contents, 1);
2176	}
2177	if ($contents ne "") {
2178	    $contents .= "\n";
2179	}
2180	$section = $newsection;
2181	$leading_space = undef;
2182    } elsif (/$doc_end/) {
2183	if (($contents ne "") && ($contents ne "\n")) {
2184	    dump_section($file, $section, $contents);
2185	    $section = $section_default;
2186	    $contents = "";
2187	}
2188	# look for doc_com + <text> + doc_end:
2189	if ($_ =~ m'\s*\*\s*[a-zA-Z_0-9:\.]+\*/') {
2190	    print STDERR "${file}:$.: warning: suspicious ending line: $_";
2191	    ++$warnings;
2192	}
2193
2194	$prototype = "";
2195	$state = STATE_PROTO;
2196	$brcount = 0;
2197        $new_start_line = $. + 1;
2198    } elsif (/$doc_content/) {
2199	if ($1 eq "") {
2200	    if ($section eq $section_context) {
2201		dump_section($file, $section, $contents);
2202		$section = $section_default;
2203		$contents = "";
2204		$new_start_line = $.;
2205		$state = STATE_BODY;
2206	    } else {
2207		if ($section ne $section_default) {
2208		    $state = STATE_BODY_WITH_BLANK_LINE;
2209		} else {
2210		    $state = STATE_BODY;
2211		}
2212		$contents .= "\n";
2213	    }
2214	} elsif ($state == STATE_BODY_MAYBE) {
2215	    # Continued declaration purpose
2216	    chomp($declaration_purpose);
2217	    $declaration_purpose .= " " . $1;
2218	    $declaration_purpose =~ s/\s+/ /g;
2219	} else {
2220	    my $cont = $1;
2221	    if ($section =~ m/^@/ || $section eq $section_context) {
2222		if (!defined $leading_space) {
2223		    if ($cont =~ m/^(\s+)/) {
2224			$leading_space = $1;
2225		    } else {
2226			$leading_space = "";
2227		    }
2228		}
2229		$cont =~ s/^$leading_space//;
2230	    }
2231	    $contents .= $cont . "\n";
2232	}
2233    } else {
2234	# i dont know - bad line?  ignore.
2235	print STDERR "${file}:$.: warning: bad line: $_";
2236	++$warnings;
2237    }
2238}
2239
2240
2241#
2242# STATE_PROTO: reading a function/whatever prototype.
2243#
2244sub process_proto($$) {
2245    my $file = shift;
2246
2247    if (/$doc_inline_oneline/) {
2248	$section = $1;
2249	$contents = $2;
2250	if ($contents ne "") {
2251	    $contents .= "\n";
2252	    dump_section($file, $section, $contents);
2253	    $section = $section_default;
2254	    $contents = "";
2255	}
2256    } elsif (/$doc_inline_start/) {
2257	$state = STATE_INLINE;
2258	$inline_doc_state = STATE_INLINE_NAME;
2259    } elsif ($decl_type eq 'function') {
2260	process_proto_function($_, $file);
2261    } else {
2262	process_proto_type($_, $file);
2263    }
2264}
2265
2266#
2267# STATE_DOCBLOCK: within a DOC: block.
2268#
2269sub process_docblock($$) {
2270    my $file = shift;
2271
2272    if (/$doc_end/) {
2273	dump_doc_section($file, $section, $contents);
2274	$section = $section_default;
2275	$contents = "";
2276	$function = "";
2277	%parameterdescs = ();
2278	%parametertypes = ();
2279	@parameterlist = ();
2280	%sections = ();
2281	@sectionlist = ();
2282	$prototype = "";
2283	$state = STATE_NORMAL;
2284    } elsif (/$doc_content/) {
2285	if ( $1 eq "" )	{
2286	    $contents .= $blankline;
2287	} else {
2288	    $contents .= $1 . "\n";
2289	}
2290    }
2291}
2292
2293#
2294# STATE_INLINE: docbook comments within a prototype.
2295#
2296sub process_inline($$) {
2297    my $file = shift;
2298
2299    # First line (state 1) needs to be a @parameter
2300    if ($inline_doc_state == STATE_INLINE_NAME && /$doc_inline_sect/o) {
2301	$section = $1;
2302	$contents = $2;
2303	$new_start_line = $.;
2304	if ($contents ne "") {
2305	    while (substr($contents, 0, 1) eq " ") {
2306		$contents = substr($contents, 1);
2307	    }
2308	    $contents .= "\n";
2309	}
2310	$inline_doc_state = STATE_INLINE_TEXT;
2311	# Documentation block end */
2312    } elsif (/$doc_inline_end/) {
2313	if (($contents ne "") && ($contents ne "\n")) {
2314	    dump_section($file, $section, $contents);
2315	    $section = $section_default;
2316	    $contents = "";
2317	}
2318	$state = STATE_PROTO;
2319	$inline_doc_state = STATE_INLINE_NA;
2320	# Regular text
2321    } elsif (/$doc_content/) {
2322	if ($inline_doc_state == STATE_INLINE_TEXT) {
2323	    $contents .= $1 . "\n";
2324	    # nuke leading blank lines
2325	    if ($contents =~ /^\s*$/) {
2326		$contents = "";
2327	    }
2328	} elsif ($inline_doc_state == STATE_INLINE_NAME) {
2329	    $inline_doc_state = STATE_INLINE_ERROR;
2330	    print STDERR "${file}:$.: warning: ";
2331	    print STDERR "Incorrect use of kernel-doc format: $_";
2332	    ++$warnings;
2333	}
2334    }
2335}
2336
2337
2338sub process_file($) {
2339    my $file;
2340    my $initial_section_counter = $section_counter;
2341    my ($orig_file) = @_;
2342
2343    $file = map_filename($orig_file);
2344
2345    if (!open(IN_FILE,"<$file")) {
2346	print STDERR "Error: Cannot open file $file\n";
2347	++$errors;
2348	return;
2349    }
2350
2351    $. = 1;
2352
2353    $section_counter = 0;
2354    while (<IN_FILE>) {
2355	while (s/\\\s*$//) {
2356	    $_ .= <IN_FILE>;
2357	}
2358	# Replace tabs by spaces
2359        while ($_ =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e) {};
2360	# Hand this line to the appropriate state handler
2361	if ($state == STATE_NORMAL) {
2362	    process_normal();
2363	} elsif ($state == STATE_NAME) {
2364	    process_name($file, $_);
2365	} elsif ($state == STATE_BODY || $state == STATE_BODY_MAYBE ||
2366		 $state == STATE_BODY_WITH_BLANK_LINE) {
2367	    process_body($file, $_);
2368	} elsif ($state == STATE_INLINE) { # scanning for inline parameters
2369	    process_inline($file, $_);
2370	} elsif ($state == STATE_PROTO) {
2371	    process_proto($file, $_);
2372	} elsif ($state == STATE_DOCBLOCK) {
2373	    process_docblock($file, $_);
2374	}
2375    }
2376
2377    # Make sure we got something interesting.
2378    if ($initial_section_counter == $section_counter && $
2379	output_mode ne "none") {
2380	if ($output_selection == OUTPUT_INCLUDE) {
2381	    print STDERR "${file}:1: warning: '$_' not found\n"
2382		for keys %function_table;
2383	}
2384	else {
2385	    print STDERR "${file}:1: warning: no structured comments found\n";
2386	}
2387    }
2388    close IN_FILE;
2389}
2390
2391
2392if ($output_mode eq "rst") {
2393	get_sphinx_version() if (!$sphinx_major);
2394}
2395
2396$kernelversion = get_kernel_version();
2397
2398# generate a sequence of code that will splice in highlighting information
2399# using the s// operator.
2400for (my $k = 0; $k < @highlights; $k++) {
2401    my $pattern = $highlights[$k][0];
2402    my $result = $highlights[$k][1];
2403#   print STDERR "scanning pattern:$pattern, highlight:($result)\n";
2404    $dohighlight .=  "\$contents =~ s:$pattern:$result:gs;\n";
2405}
2406
2407# Read the file that maps relative names to absolute names for
2408# separate source and object directories and for shadow trees.
2409if (open(SOURCE_MAP, "<.tmp_filelist.txt")) {
2410	my ($relname, $absname);
2411	while(<SOURCE_MAP>) {
2412		chop();
2413		($relname, $absname) = (split())[0..1];
2414		$relname =~ s:^/+::;
2415		$source_map{$relname} = $absname;
2416	}
2417	close(SOURCE_MAP);
2418}
2419
2420if ($output_selection == OUTPUT_EXPORTED ||
2421    $output_selection == OUTPUT_INTERNAL) {
2422
2423    push(@export_file_list, @ARGV);
2424
2425    foreach (@export_file_list) {
2426	chomp;
2427	process_export_file($_);
2428    }
2429}
2430
2431foreach (@ARGV) {
2432    chomp;
2433    process_file($_);
2434}
2435if ($verbose && $errors) {
2436  print STDERR "$errors errors\n";
2437}
2438if ($verbose && $warnings) {
2439  print STDERR "$warnings warnings\n";
2440}
2441
2442if ($Werror && $warnings) {
2443    print STDERR "$warnings warnings as Errors\n";
2444    exit($warnings);
2445} else {
2446    exit($output_mode eq "none" ? 0 : $errors)
2447}
2448